Распределение НДС косвенных расходов Бух 2.0.43.12. Исправления методики.

Для случая купли продажи алгоритм работает без замечаний. Однако при комиссионной торговле алгоритм совершенно не верен. Все свелось к путанице понятий выручка и стоимость отгруженных товаров, выручка и валовой доход.

Цитируем НК: “ 4. Суммы налога, предъявленные продавцами товаров (работ, услуг), имущественных прав налогоплательщикам, осуществляющим как облагаемые налогом, так и освобождаемые от налогообложения операции:

…

Указанная пропорция определяется исходя из стоимости отгруженных товаров (работ, услуг), имущественных прав, операции по реализации которых подлежат налогообложению (освобождены от налогообложения), в общей стоимости товаров (работ, услуг), имущественных прав, отгруженных за налоговый период. По основным средствам и нематериальным активам, принимаемым к учету в первом или втором месяцах квартала, налогоплательщик имеет право определять указанную пропорцию исходя из стоимости отгруженных в соответствующем месяце товаров (выполненных работ, оказанных услуг), переданных имущественных прав, операции по реализации которых подлежат налогообложению (освобождены от налогообложения), в общей стоимости отгруженных (переданных) за месяц товаров (работ, услуг), имущественных прав.

(в ред. Федеральных законов от 22.07.2005 N 119-ФЗ, от 19.07.2011 N 245-ФЗ)
ст. 170, «Налоговый кодекс Российской Федерации (часть вторая)» от 05.08.2000 N 117-ФЗ (ред. от 30.12.2012, с изм. от 25.12.2012) ”. 

Читаем книгу  С.А.Харитонова и О.В.Шелест «Секреты профессиональной работы  с «1С:БУХГАЛТЕРИЕЙ 8» (редакция 2.0) стр.47: « На основании данных этого документа суммы «входного» НДС по косвенным расходам распределяются по конкретным видам деятельности, исходя из доли суммы выручки конкретного вида деятельности в общей выручке».

Обратите внимание на то, что законодатель не упоминает термин “выручка”, ибо в контексте документа он несет совершенно иной функционал.  Откройте исходные тексты текущей версии и через слово увидите этот термин в названиях процедур.

Чтобы понять в чем проблема, рассмотрим простейший пример. Есть два поставщика товара. Цены продажи и объемы одинаковы. Первый товар НДС не облагается, а второй передан нам как комиссионный под 10% (с комиссии надо платить НДС). Товар продан — надо разделить косвенные расходы.

Объемы продаж одинаковы, значит коэффициент сторнирования НДС должен быть 50,4% (100 и 98,47).  Текущий релиз программы выдаст результат —  92,19% (100 и 8,47).

Самое интересное, что налоговые инспектора пытаются проверять пропорцию по книге продаж или налоговой отчетности. Цитируют выше приведенный текст в акте налоговой проверки, но пропорцию считают по книге продаж.

В версии 7.7 и при переходе на версию 8 мы подходили достаточно просто, вручную исключали из пропорции обороты комиссионные, заменяя их на обороты по счету 004.

В текущей версии для этой цели добавлен регистр «КорректировкаКомиссионныхОбъемов» связанный с документом «ОтчетКомитентуОПродажах». Сумма которую пишем в регистр- Сумма продажи минус комиссионное вознаграждение минус НДС.

Теперь добавим в документ «Распределение НДС косвенных расходов» процедуру суммирования по регистру и указанная сумма увеличит объем реализации с НДС.  Мы уменьшаем суммы сторнирования НДС и тем самым платежи в бюджет.

Текст исправленной процедуры:

Процедура РассчитатьВыручку() Экспорт

    ВыручкаЕНВД   = 0;

    ВыручкаБезНДС = 0;

    ВыручкаНДС0   = 0;

    ВыручкаНДС    = 0;

    Корректировка = 0;   //++



    Отказ = Ложь;

    КонецПериода = УчетНДС.ПолучитьКонецПериодаПоУчетнойПолитике(Организация, НачалоПериода, Отказ);



    Если Не Отказ Тогда

        УчетНДС.РассчитатьВыручкуДляНДС(Организация, НачалоПериода, КонецПериода, ВыручкаЕНВД, ВыручкаБезНДС, ВыручкаНДС0, ВыручкаНДС);

    КонецЕсли;

    //++25.09.2011  Пересчет с дохода на поступление сумм

    Если Организация.КорректироватьКомиссионнуюВыручку Тогда



        ОбщийМодульТур.РассчитатьВыручкуДляНДС(Организация, НачалоПериода, КонецПериода, Корректировка);

        ВыручкаНДС = ВыручкаНДС + Корректировка;

    КонецЕсли;

КонецПроцедуры // РассчитатьВыручку()



Процедура РассчитатьВыручкуДляНДС(Организация, НачалоПериода, КонецПериода, КорректировкаВыручкаНДС) Экспорт

    //Указанная пропорция определяется исходя из стоимости отгруженных товаров (работ, услуг),

    //имущественных прав, операции по реализации которых подлежат налогообложению (освобождены

    //от налогообложения), в общей стоимости товаров (работ, услуг), имущественных прав, отгруженных за налоговый период.

    //(ст. 170, "Налоговый кодекс Российской Федерации (часть вторая)" от 05.08.2000 N 117-ФЗ (ред. от 19.07.2011))



    КорректировкаВыручкаНДС = 0;

    СуммаК                  = 0;

    Запрос = Новый Запрос;

    Запрос.УстановитьПараметр("Организация", Организация);

    Запрос.УстановитьПараметр("НачалоПериода", НачалоМесяца(НачалоПериода));

    Запрос.УстановитьПараметр("КонецПериода", КонецМесяца(КонецПериода));



    Запрос.Текст = "ВЫБРАТЬ

    | СУММА(КорректировкаКомиссионныхОбъемовОбороты.СуммаБезНДСПриход) КАК СуммаБезНДС,

    | СУММА(КорректировкаКомиссионныхОбъемовОбороты.СуммаКорректировкиПриход) КАК СуммаКорректировки

    |ИЗ

    | РегистрНакопления.КорректировкаКомиссионныхОбъемов.Обороты(

    |  НАЧАЛОПЕРИОДА(&НачалоПериода, ДЕНЬ),

    |  КОНЕЦПЕРИОДА(&КонецПериода, ДЕНЬ),

    |  Организация = &Организация

    |      И (СчетФактура.Дата МЕЖДУ НАЧАЛОПЕРИОДА(&НачалоПериода, ДЕНЬ) И КОНЕЦПЕРИОДА(&КонецПериода, ДЕНЬ))

    |       ) КАК КорректировкаКомиссионныхОбъемовОбороты";

    Рез = Запрос.Выполнить().Выгрузить();

    Для Каждого СтрокаРезультата Из Рез Цикл

        КорректировкаВыручкаНДС = СтрокаРезультата.СуммаКорректировки;

        СуммаК=СтрокаРезультата.СуммаБезНДС;

    КонецЦикла;

КонецПроцедуры // РассчитатьВыручкуДляНДС()