Обработка отчетов Моспаркинга в КА 1.1 с учетом путевых листов из УАТ 1.0

Загрузка и обработка отчетов Моспаркинг.png

В статье описан вариант автоматизации учета парковок водителей в 1С Комплексная автоматизация (релиз 1.1.90.1) с использованием 1С Управление Авто Транспортом (релиз 1.0.12.1). Данные о парковках приходят на эл. почту организации, обрабатываются в 1С КА и сверяются с 1С УАТ.

Вводная часть.

Организация занимается курьерской доставкой по Москве. Есть свой автопарк и водители. С появлением в нашей жизни Моспаркинга, понадобилось автоматизировать учет трат на парковки. Каждому водителю в начале месяца перечисляется некая сумма денег под отчет на зарплатную карту, из этих денег он должен пополнить свой лицевой счет в Моспаркинге. В конце месяца водитель присылает отчет из приложения по рабочим машинам в формате *.XLS. Бухгалтер заносит сведения из отчета в 1С в документ "Авансовый отчет", рассчитывает остаток неизрасходованных денег, и планирует перечисление водителю на следующий месяц.

Сложности.

Расход в отчете Моспаркинга приходит в виде "-80.00 руб", что на порядок усложняет получение общей суммы расхода по файлу. Бухгалтер должна зайти в каждый файл, сделать автозамену спец символов, преобразовать ячейки в число, и только после этого просуммировать ячейки.
В самом файле указывается только номер автомобиля. Бухгалтер должна запросить в транспортном отделе с какого водителя списывать сумму в авансовом отчете.
Водители могут прислать отчеты, в которых неверно указаны автомобили (например в фильтре попался личный авто) или период. В этом случае бухгалтеру необходимо запросить новый отчет, затем по новой преобразовать ячейки расхода, проверить файл и т.д

Реализация. Этап 1.

Для начала было решено облегчить бухгалтеру создание авансовых отчетов. Процесс стал выглядеть так:

Водитель присылает отчет руководителю транспортного отдел. Руководитель открывает файл, видит номер автомобиля (далее ТС — транспортное средство), закрывает файл. После чего в названии файла указывает ФИО водителя и отсылает результат бухгалтеру.
Бухгалтер, видя в файле ФИО водителя, добавляет в начало имени файла пятизначный внутренний код сотрудника в организации (ID). *ID — добавленный реквизит справочника "Физические лица" используется для обменов между учетными системами организации. Можно заменить на код справочника, главное чтобы соблюдалась уникальность кодов.
Бухгалтер запускает обработку в 1С, указывает каталог со всеми файлами за период, нажимает кнопку "Прочитать файлы". Авансовые отчеты создаются по кнопке "Создать авансовые отчеты" в по данным из табличной части обработки. Поиск водителя идёт по ID, указанному в начале имени файла.

Чтение файлов

Процедура ОбработатьДанныеФайла(мФайл)

//1.Из имени файла получаем ID (Символы до первого пробела)
ИмяФайла = СокрЛП(мФайл.Имя);
номПервыйПробел = Найти(ИмяФайла," ");
IDСтрокой = СокрЛП(Лев(ИмяФайла,номПервыйПробел));

//2. Пытаемся преобразовать ID из строки в число. Если не получается, то файл не обрабатываем.
Попытка
IDЧисло = Число(IDСтрокой);
Исключение
IDЧисло = 0;
СтрокаОшибка = "Неверно указано имя файла '"+ИмяФайла+"'. Файл загружен не будет."+Символы.ПС+"Первыми символами имени файла должен быть ID затем пробел";
Сообщить(СтрокаОшибка,СтатусСообщения.ОченьВажное);
Возврат;
КонецПопытки;

//3. Открываем файл на чтение
Попытка
КОМОбъект = ПолучитьCOMОбъект(мФайл.ПолноеИмя);
Исключение
Сообщить(ИнформацияОбОшибке().Описание + ?(ИнформацияОбОшибке().Причина = Неопределено, "", " по причине: " + ИнформацияОбОшибке().Причина.Описание + " (возможно, не установлен MS Excel!)"), СтатусСообщения.Внимание);
Возврат;
КонецПопытки;

//4. Читаем файл. Преобразовываем сумму из строки в число
//Сумма в файле имеет вид "200.00 руб" (зачисление на счет) или "-100.00 руб" (списание со счета)
//Нас интересует только списание
ВсегоПотрачено = 0;
ЕстьОшибкиПриОбработке = Ложь;
ТекстОшибки = "При обработке файла '"+ИмяФайла+"' произошли ошибки: "+ Символы.ПС;
НашЛист = КОМОбъект.WorkSheets.Item(1);
ПослСтр = НашЛист.Cells(1,1).SpecialCells(11).Row;

Для НомСтр = фСтрока По ПослСтр Цикл
СуммаСтрокой = СокрЛП(Строка(НашЛист.Cells(НомСтр, фКолонка).Text));
Если ПустаяСтрока(СуммаСтрокой) Тогда
Продолжить;
КонецЕсли;
Если Лев(СуммаСтрокой,1) <> "-" Тогда
Продолжить;
КонецЕсли;
номПервыйПробел = Найти(СуммаСтрокой," ");
времСтрока = СокрЛП(Сред(СуммаСтрокой,2,номПервыйПробел-1));
времСтрока = СтрЗаменить(времСтрока, " ", "");
времСтрока = СтрЗаменить(времСтрока, Символы.НПП, "");
Попытка
СуммаЧислом = Число(времСтрока);
Исключение
СуммаЧислом = 0;
ЕстьОшибкиПриОбработке = Истина;
ТекстОшибки = ТекстОшибки + "В строке файла № "+НомСтр+ " ошибка преобразования суммы "+СуммаСтрокой + " ("+времСтрока+")"+Символы.ПС;
КонецПопытки;
ВсегоПотрачено = ВсегоПотрачено + СуммаЧислом;
КонецЦикла;

Если ЕстьОшибкиПриОбработке Тогда
Сообщить(ТекстОшибки,СтатусСообщения.Внимание);
КонецЕсли;

//5. Добавляем строку в ТЧ Данные файлов
новСтр      = ДанныеФайлов.Добавить();
новСтр.ID    = IDЧисло;
новСтр.ИмяФайла   = ИмяФайла;
новСтр.СуммаПотрачено   = ВсегоПотрачено;
новСтр.ЕстьОшибка  = ЕстьОшибкиПриОбработке;
КонецПроцедуры

Заполнение табличной части и поиск водителей по ID

Процедура КоманднаяПанельФайлыПрочитатьФайлы(Кнопка)

//1. Получаем список файлов (xls, xlsx) из каталога
Если НЕ ПроверитьЗаполнение() Тогда
Возврат;
КонецЕсли;

Если ДанныеФайлов.Количество()>0 Тогда
ТекстВопроса = "В табличной части уже есть заполненные данные.
|Очистить и перезаполнить?";

Ответ = Вопрос(ТекстВопроса, РежимДиалогаВопрос.ДаНет, , КодВозвратаДиалога.Да,);
Если Ответ = КодВозвратаДиалога.Да Тогда
ДанныеФайлов.Очистить();
Иначе
Возврат;
КонецЕсли;
КонецЕсли;

Если ПустаяСтрока(фКаталог) Тогда
Сообщить("Не указан каталог хранения файлов");
Возврат;
КонецЕсли;
МассивФайлов = НайтиФайлы(фКаталог,"*.xls?");
Если МассивФайлов.Количество() = 0 Тогда
Сообщить("В указанном каталоге '" +фКаталог +"' не найдено файлов *.XLS или *.XLSX");
Возврат;
КонецЕсли;

//2. Читаем файл, производим первичное заполнение ТЧ "Данные файлов"
Для каждого элФайл из МассивФайлов Цикл
ОбработатьДанныеФайла(элФайл);
КонецЦикла;

//3. Проверяем задвоение ID
МассивДублей = новый Массив;
Для Каждого стрФайл из ДанныеФайлов Цикл
НомСтроки     = стрФайл.НомерСтроки;
врID      = стрФайл.ID;
ТекстОшибки = "Для ID '"+ врID +"' найдено несколько строк: " + НомСтроки;
ЕстьОшибка     = Ложь;
Если МассивДублей.Найти(врID) <> Неопределено Тогда
Продолжить;
КонецЕсли;
Для каждого Дубль из ДанныеФайлов Цикл
Если Дубль.ID = врID и Дубль.НомерСтроки <> НомСтроки Тогда
ЕстьОшибка     = Истина;
ТекстОшибки = ТекстОшибки + ", "+ Дубль.НомерСтроки;
Дубль.ЕстьОшибка = Истина;
КонецЕсли;
КонецЦикла;
Если ЕстьОшибка Тогда
стрФайл.ЕстьОшибка = Истина;
МассивДублей.Добавить(врID);
Сообщить(ТекстОшибки, СтатусСообщения.Внимание);
КонецЕсли;
КонецЦикла;


//4. Находим сотрудника по ID, смотрим есть ли у него уже авансовый отчет за этот период
Запрос = новый Запрос;
Запрос.МенеджерВременныхТаблиц = новый МенеджерВременныхТаблиц;
Запрос.Текст =    "ВЫБРАТЬ
|    табДанныеФайлов.НомерСтроки,
|    табДанныеФайлов.Обрабатывать,
|    табДанныеФайлов.ID,
|    табДанныеФайлов.ИмяФайла,
|    табДанныеФайлов.ФизЛицо,
|    табДанныеФайлов.СуммаПотрачено,
|    табДанныеФайлов.АвансовыйОтчет,
|    табДанныеФайлов.ЕстьОшибка
|ПОМЕСТИТЬ втДанныеФайлов
|ИЗ
|    &табДанныеФайлов КАК табДанныеФайлов
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|    втДанныеФайлов.НомерСтроки,
|    втДанныеФайлов.ИмяФайла,
|    втДанныеФайлов.Обрабатывать,
|    втДанныеФайлов.ID,
|    ЕСТЬNULL(ФизическиеЛица.Ссылка, ЗНАЧЕНИЕ(Справочник.ФизическиеЛица.ПустаяСсылка)) КАК ФизЛицо,
|    втДанныеФайлов.СуммаПотрачено,
|    втДанныеФайлов.АвансовыйОтчет,
|    втДанныеФайлов.ЕстьОшибка
|ПОМЕСТИТЬ втДанныеФайловФизлица
|ИЗ
|    втДанныеФайлов КАК втДанныеФайлов
|        ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ФизическиеЛица КАК ФизическиеЛица
|        ПО втДанныеФайлов.ID = ФизическиеЛица.ID
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
|    втДанныеФайловФизлица.НомерСтроки КАК НомерСтроки,
|    втДанныеФайловФизлица.ИмяФайла,
|    втДанныеФайловФизлица.Обрабатывать,
|    втДанныеФайловФизлица.ID,
|    втДанныеФайловФизлица.ФизЛицо,
|    втДанныеФайловФизлица.СуммаПотрачено,
|    втДанныеФайловФизлица.ЕстьОшибка,
|    ЕСТЬNULL(СозданныеАвансовыеОтчеты.Ссылка, ЗНАЧЕНИЕ(Документ.АвансовыйОтчет.ПустаяСсылка)) КАК АвансовыйОтчет,
|    ЕСТЬNULL(ОстаткиАвансовВыданных.СуммаВыдано, 0) КАК СуммаВыдано
|ИЗ
|    втДанныеФайловФизлица КАК втДанныеФайловФизлица
|        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
|            МАКСИМУМ(АвансовыйОтчет.Ссылка) КАК Ссылка,
|            АвансовыйОтчет.ФизЛицо КАК ФизЛицо
|        ИЗ
|            Документ.АвансовыйОтчет КАК АвансовыйОтчет
|        ГДЕ
|            АвансовыйОтчет.Проведен
|            И АвансовыйОтчет.ФизЛицо В
|                    (ВЫБРАТЬ
|                        втДанныеФайловФизлица.ФизЛицо
|                    ИЗ
|                        втДанныеФайловФизлица КАК втДанныеФайловФизлица
|                    ГДЕ
|                        НЕ втДанныеФайловФизлица.ЕстьОшибка)
|            И АвансовыйОтчет.Дата МЕЖДУ &НачалоПериода И &КонецПериода
|            И АвансовыйОтчет.Организация = &Организация
|
|        СГРУППИРОВАТЬ ПО
|            АвансовыйОтчет.ФизЛицо) КАК СозданныеАвансовыеОтчеты
|        ПО втДанныеФайловФизлица.ФизЛицо = СозданныеАвансовыеОтчеты.ФизЛицо
|        ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
|            ВзаиморасчетыСПодотчетнымиЛицамиОстатки.ФизЛицо КАК ФизЛицо,
|            ВзаиморасчетыСПодотчетнымиЛицамиОстатки.СуммаВзаиморасчетовОстаток КАК СуммаВыдано
|        ИЗ
|            РегистрНакопления.ВзаиморасчетыСПодотчетнымиЛицами.Остатки(
|                    &ГраницаКонецПериода,
|                    ФизЛицо В
|                            (ВЫБРАТЬ
|                                втДанныеФайловФизлица.ФизЛицо
|                            ИЗ
|                                втДанныеФайловФизлица КАК втДанныеФайловФизлица)
|                        И Организация = &Организация) КАК ВзаиморасчетыСПодотчетнымиЛицамиОстатки) КАК ОстаткиАвансовВыданных
|        ПО втДанныеФайловФизлица.ФизЛицо = ОстаткиАвансовВыданных.ФизЛицо
|
|УПОРЯДОЧИТЬ ПО
|    НомерСтроки";

Запрос.УстановитьПараметр("табДанныеФайлов",    ДанныеФайлов);
Запрос.УстановитьПараметр("НачалоПериода",        НачалоДня(Период));
Запрос.УстановитьПараметр("КонецПериода",        КонецДня(Период));
Запрос.УстановитьПараметр("ГраницаКонецПериода",Новый Граница(КонецДня(Период),ВидГраницы.Включая));
Запрос.УстановитьПараметр("Организация",        Организация);
Результат = Запрос.Выполнить().Выгрузить();

ДанныеФайлов.Очистить();

Для Каждого стРезультат из Результат Цикл
новСтр = ДанныеФайлов.Добавить();
ЗаполнитьЗначенияСвойств(новСтр, стРезультат);
Если НЕ ЗначениеЗаполнено(новСтр.ФизЛицо) Тогда
Сообщить("В строке № " + стРезультат.НомерСтроки + " для ID '"+новСтр.ID+"' не найден сотрудник");
новСтр.ЕстьОшибка = Истина;
КонецЕсли;

Если новСтр.ЕстьОшибка Тогда
новСтр.Обрабатывать = ложь;
Иначе
новСтр.Обрабатывать = Истина;
КонецЕсли;

КонецЦикла;

КонецПроцедуры

Создание/Обновление авансового отчета

Процедура КоманднаяПанельФайлыСоздатьАвансовыеОтчеты(Кнопка)
Если НЕ ПроверитьЗаполнение() Тогда
Возврат;
КонецЕсли;

Для каждого стДанные из ДанныеФайлов Цикл
Если не стДанные.Обрабатывать или стДанные.ЕстьОшибка Тогда
Продолжить;
КонецЕсли;

Если не ЗначениеЗаполнено(стДанные.ФизЛицо) Тогда
стДанные.Обрабатывать  = Ложь;
стДанные.ЕстьОшибка  = Истина;
Сообщить("В строке № " + стДанные.НомерСтроки + " для ID '"+стДанные.ID+"' не найден сотрудник");
Продолжить;
КонецЕсли;

//Если есть созданный авансовый отчет, то его перезаполняем
Если ЗначениеЗаполнено(стДанные.АвансовыйОтчет) Тогда
ДокОбъект = стДанные.АвансовыйОтчет.ПолучитьОбъект();
ДокОбъект.ОплатаПоставщикам.Очистить();
ДокОбъект.ВыданныеАвансы.Очистить();
ДокОбъект.ВозвратнаяТара.Очистить();
ДокОбъект.Товары.Очистить();
ДокОбъект.СерийныеНомера.Очистить();
ДокОбъект.Прочее.Очистить();
Иначе
ДокОбъект = Документы.АвансовыйОтчет.СоздатьДокумент();
ДокОбъект.Дата     = Период;
ДокОбъект.Организация   = Организация;
ДокОбъект.ФизЛицо   = стДанные.ФизЛицо;
ДокОбъект.Ответственный  = глЗначениеПеременной("глТекущийПользователь");
ДокОбъект.ВалютаДокумента   = мВалютаРеглУчета;
КонецЕсли;
ДокОбъект.ОтражатьВБухгалтерскомУчете  = Истина;
ДокОбъект.ОтражатьВНалоговомУчете   = Истина;
ДокОбъект.ОтражатьВУправленческомУчете  = Истина;
ДокОбъект.ВидПоступления    = Перечисления.ВидыПоступленияТоваров.НаСклад;
ДокОбъект.КратностьДокумента   = 1;
ДокОбъект.КурсДокумента     = 1;
ДокОбъект.НазначениеАванса    = Номенклатура.Наименование;
ДокОбъект.Комментарий     = "Заполнено из файла '"+фКаталог +""+ стДанные.ИмяФайла +"'";
мЗаполнитьВыданныеАвансы(стДанные,ДокОбъект,стДанные.СуммаПотрачено);//Заполняем вкладку выданные авансы

//Заполняем ТЧ Прочее
стПрочее = ДокОбъект.Прочее.Добавить();
стПрочее.Номенклатура     = Номенклатура;
стПрочее.Содержание     = Номенклатура.Наименование;
стПрочее.СчетЗатрат     = СчетУчетаЗатрат;
стПрочее.СчетЗатратНУ    = СчетУчетаЗатратНУ;
стПрочее.НоменклатурнаяГруппа   = НоменклатурнаяГруппа;
стПрочее.СтатьяЗатрат            = СтатьяЗатрат;
стПрочее.ПодразделениеОрганизации = Подразделение;
стПрочее.ВидДокВходящий    = "Выписка операций по счету Моспаркинг" ;
стПрочее.СтавкаНДС     = Перечисления.СтавкиНДС.БезНДС;
стПрочее.Количество     = 1;
стПрочее.СуммаНДС     = 0;
стПрочее.Цена      = стДанные.СуммаПотрачено;
стПрочее.Сумма      = стДанные.СуммаПотрачено;
стПрочее.ДатаВходящегоДокумента  = Период;
Попытка
Если НачалоДня(Период) = НачалоДня(ТекущаяДата()) Тогда
ДокОбъект.Записать(РежимЗаписиДокумента.Проведение,РежимПроведенияДокумента.Оперативный);
Иначе
ДокОбъект.Записать(РежимЗаписиДокумента.Проведение);
КонецЕсли;
Отказ = ложь;
Исключение
Инфо = ИнформацияОбОшибке();
Сообщить(ПодробноеПредставлениеОшибки(Инфо));
Отказ = Истина;
КонецПопытки;
Если не Отказ Тогда
стДанные.АвансовыйОтчет = ДокОбъект.Ссылка;
КонецЕсли;
КонецЦикла;

КонецПроцедуры

Реализация. Этап 2.

Казалось бы, всё хорошо. Бухгалтер теперь тратит пару часов своего времени вместо нескольких дней. Но! У руководителя транспортного цеха прибавилось работы по идентификации отчетов. В 1С КА гос. номер ТС не хранится, но он есть в 1С УАТ. Меняем схему работы:

Водитель присылает отчет не на адрес руководителя, а на адрес организации 1C@organization.ru.
Бухгалтер запускает обработку, которая средствами 1С КА читает почту и отбирает письма с адреса моспаркинга. Обработка читает вложения, по COM — соединению подсоединяется к 1С УАТ, находит путевые листы по ТС и возвращает в 1С КА ФИО водителя и дату его рождения. По ФИО и дате рождения в 1С КА ищется ID сотрудника. Файл отчета переименовывается и сохраняется в отдельный каталог.
Используется обработка из первого этапа.

Чтение и обработка файлов вложений электронных писем

//При обработке файлов используем кэш дат и гос. номеров
//ТИП - либо "дата", либо "госномер"
Функция ПолучитьЗначениеИзЭкселяСУчетомКэша(мЗначениеЭксель,Тип,мКэш)
Результат = мКэш.Получить(мЗначениеЭксель);

Если Результат = Неопределено Тогда
//Значения в кэше нет, получим его из строки и записываем в кэш
Если Тип = "дата" Тогда
Если СтрДлина(мЗначениеЭксель) = 10 Тогда
времДата = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(мЗначениеЭксель,".");
Попытка
Если времДата.Количество() = 3 Тогда //строку поделило, так как нам надо
Результат = Дата(времДата[2],времДата[1],времДата[0]);
КонецЕсли;
Исключение
Результат = Неопределено
КонецПопытки;
КонецЕсли;
ИначеЕсли Тип = "госномер" Тогда
Если Найти(мЗначениеЭксель,"Парковка автомобиля ") > 0 Тогда
массивПодстрок = ОбщегоНазначения.РазложитьСтрокуВМассивПодстрок(мЗначениеЭксель," ");
времГосНомер = НРЕГ(массивПодстрок[2]);
//Гос Номер в файле в формате А000АА000, в УАТ нужен в формате а 000 аа 000
Результат = Лев(времГосНомер,1)+ " " + Сред(времГосНомер,2,3) + " " + Сред(времГосНомер,5,2) + " " + Сред(времГосНомер,7,3);
Если Прав(Результат,1) = "." Тогда
Результат = Лев(Результат,11);
КонецЕсли;
КонецЕсли;
Иначе
Результат = Неопределено;
КонецЕсли;

Если Результат <> Неопределено Тогда //найденное значение поместим в кэш
мКэш.Вставить(мЗначениеЭксель,Результат);
КонецЕсли;
КонецЕсли;

Возврат Результат;

КонецФункции

//Каждой строке файла присваиваем вес = 1 для дальнейшей работы по ошибкам в строках файлов
Процедура ОбработатьОтчетОПарковкеЭксель(ИД, ПутьФайла, мТаблица, мКэш)

//Открываем файл на чтение
Попытка
КОМОбъект = ПолучитьCOMОбъект(ПутьФайла);
Исключение
Сообщить(ИнформацияОбОшибке().Описание + ?(ИнформацияОбОшибке().Причина = Неопределено, "", " по причине: " + ИнформацияОбОшибке().Причина.Описание ), СтатусСообщения.Внимание);
Возврат;
КонецПопытки;

//Читаем файл. Преобразовываем дату и госномер в формат 1С
УспешныхПопыток = 0;
НашЛист = КОМОбъект.WorkSheets.Item(1);
ПослСтр = НашЛист.Cells(1,1).SpecialCells(11).Row;
Для НомСтр = фСтрока По ПослСтр Цикл
//Косяки в данных за успешно прочитанные строки не считаем
ДатаЭксель   = СокрЛП(Строка(НашЛист.Cells(НомСтр, фДата).Text));
Если ПустаяСтрока(ДатаЭксель) Тогда
Продолжить;
КонецЕсли;
Дата1С    = ПолучитьЗначениеИзЭкселяСУчетомКэша(ДатаЭксель,"дата",мКэш);
Если Дата1С = Неопределено Тогда
Продолжить;
КонецЕсли;

ГосНомерЭксель  = СокрЛП(Строка(НашЛист.Cells(НомСтр, фГосНомер).Text));
Если ПустаяСтрока(ГосНомерЭксель) Тогда
Продолжить;
КонецЕсли;
ГосНомер1С   = ПолучитьЗначениеИзЭкселяСУчетомКэша(ГосНомерЭксель,"госномер",мКэш);
Если ГосНомер1С = Неопределено Тогда
Продолжить;
КонецЕсли;

новСтрока = мТаблица.Добавить();
новСтрока.ИД    = ИД;
новСтрока.ГосНомер   = ГосНомер1С;
новСтрока.ДатаПутевки  = Дата1С;
новСтрока.Вес    = 1;

//Чтение файла идет до 10 успешно обработанных строк или пока файл не закончится
УспешныхПопыток = УспешныхПопыток + 1;
Если УспешныхПопыток = МаксКоличествоУспешныхПопыток И МаксКоличествоУспешныхПопыток <> 0 Тогда
Прервать;
КонецЕсли;
КонецЦикла;

КОМОбъект.Close();
КонецПроцедуры

Подключение к УАТ, получение данных путевых листов

 //Подключение по КОМ к УАТ, получение данных путевых листов
Попытка
Соединитель = Новый COMObject("V82.COMConnector");
Соединение = Соединитель.Connect("Srvr = ""Server"";Ref = ""UAT_1C"";Usr = ""Admin"";Pwd = ""11111"";");
Исключение
Сообщить("Ошибка при подключении к УАТ");
ИНФО = ИнформацияОбОшибке();
Сообщить(КраткоеПредставлениеОшибки(ИНФО));
Возврат;
КонецПопытки;

//Инициализируем таблицу на стороне УАТ, для передачи в неё гос. номеров и дат
ТабПараметров = Соединение.NewObject("ТаблицаЗначений");
ТабПараметров.Колонки.Добавить("ИД",   Соединение.ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(36));
ТабПараметров.Колонки.Добавить("ГосНомер",  Соединение.ОбщегоНазначения.ПолучитьОписаниеТиповСтроки(15));
ТабПараметров.Колонки.Добавить("ДатаПутевки", Соединение.ОбщегоНазначения.ПолучитьОписаниеТиповДаты(Соединение.ЧастиДаты.Дата));
ТабПараметров.Колонки.Добавить("Вес",   Соединение.ОбщегоНазначения.ПолучитьОписаниеТиповЧисла(5));

Для Каждого стрОтчета из табОтчета Цикл
новПараметр = ТабПараметров.Добавить();
ЗаполнитьЗначенияСвойств(новПараметр,стрОтчета);
КонецЦикла;

ЗапросУАТ = Соединение.NewObject("Запрос");
ЗапросУАТ.Текст =
"ВЫБРАТЬ
| ДанныеОтчетов.ИД,
| ДанныеОтчетов.ГосНомер,
| ДанныеОтчетов.Вес,
| ДанныеОтчетов.ДатаПутевки
|ПОМЕСТИТЬ втДанныеОтчетовМоспаркинг
|ИЗ
| &ДанныеОтчетов КАК ДанныеОтчетов
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| уатТС.Ссылка КАК СсылкаТС,
| уатТС.ГосударственныйНомер КАК уатГосНомер,
| втДанныеОтчетовМоспаркинг.ГосНомер КАК ГосНомер,
| втДанныеОтчетовМоспаркинг.ИД,
| втДанныеОтчетовМоспаркинг.Вес,
| втДанныеОтчетовМоспаркинг.ДатаПутевки
|ПОМЕСТИТЬ втТС
|ИЗ
| Справочник.уатТС КАК уатТС
|  ПРАВОЕ СОЕДИНЕНИЕ втДанныеОтчетовМоспаркинг КАК втДанныеОтчетовМоспаркинг
|  ПО уатТС.ГосударственныйНомер = втДанныеОтчетовМоспаркинг.ГосНомер
|ГДЕ
| НЕ втДанныеОтчетовМоспаркинг.ИД ЕСТЬ NULL
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втТС.ИД,
| втТС.Вес,
| ПутевыеЛисты.ДатаВыезда,
| ПутевыеЛисты.ДатаВозвращения,
| втТС.ДатаПутевки,
| ЕСТЬNULL(втТС.уатГосНомер, втТС.ГосНомер) КАК ГосНомер,
| ПутевыеЛисты.ВодительСсылка КАК ВодительСсылка,
| ЕСТЬNULL(ПутевыеЛисты.ВодительФИО, ""Не найдена путевка"") КАК ВодительФИО,
| ЕСТЬNULL(ПутевыеЛисты.ВодительДР, ДАТАВРЕМЯ(1, 1, 1)) КАК ВодительДР
|ИЗ
| втТС КАК втТС
|  ЛЕВОЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
|   уатПутевойЛист.Ссылка КАК Путевка,
|   НАЧАЛОПЕРИОДА(уатПутевойЛист.ДатаВыезда, ДЕНЬ) КАК ДатаВыезда,
|   КОНЕЦПЕРИОДА(уатПутевойЛист.ДатаВозвращения, ДЕНЬ) КАК ДатаВозвращения,
|   уатПутевойЛист.Водитель1.Физлицо КАК ВодительСсылка,
|   уатПутевойЛист.Водитель1.Физлицо.Наименование КАК ВодительФИО,
|   уатПутевойЛист.Водитель1.Физлицо.ДатаРождения КАК ВодительДР,
|   уатПутевойЛист.ТранспортноеСредство КАК ТранспортноеСредство
|  ИЗ
|   Документ.уатПутевойЛист КАК уатПутевойЛист
|  ГДЕ
|   НЕ уатПутевойЛист.ПометкаУдаления
|   И уатПутевойЛист.ТранспортноеСредство В
|     (ВЫБРАТЬ
|      втТС.СсылкаТС
|     ИЗ
|      втТС КАК втТС)) КАК ПутевыеЛисты
|  ПО втТС.СсылкаТС = ПутевыеЛисты.ТранспортноеСредство
|   И втТС.ДатаПутевки >= ПутевыеЛисты.ДатаВыезда
|   И втТС.ДатаПутевки <= ПутевыеЛисты.ДатаВозвращения
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ втДанныеОтчетовМоспаркинг
|;
|
|////////////////////////////////////////////////////////////////////////////////
|УНИЧТОЖИТЬ втТС"

;
ЗапросУАТ.УстановитьПараметр("ДанныеОтчетов", ТабПараметров);
Результат = ЗапросУАТ.Выполнить();
табРезультатУАТ = Результат.Выгрузить();
Соединитель = Неопределено;//Отключаем ком соединение

//3. Перенесем сведения, полученные из УАТ в ТЗ
табОтчета.Очистить();
табОтчета.Колонки.Добавить("ВодительФИО", Новый ОписаниеТипов("Строка",Новый КвалификаторыСтроки(50)));
табОтчета.Колонки.Добавить("ВодительГУИД", Новый ОписаниеТипов("Строка",Новый КвалификаторыСтроки(36)));
табОтчета.Колонки.Добавить("ВодительДР", Новый ОписаниеТипов("Дата" ,Новый КвалификаторыДаты));

Для каждого строкаУАТ из табРезультатУАТ Цикл
стрОтчета = табОтчета.Добавить();
ЗаполнитьЗначенияСвойств(стрОтчета,строкаУАТ);
Если строкаУАТ.ВодительСсылка = NULL Тогда
стрОтчета.ВодительГУИД = "Не найдена путевка ("+строкаУАТ.ГосНомер+")";
Иначе
стрОтчета.ВодительГУИД = Соединение.String(строкаУАТ.ВодительСсылка.УникальныйИдентификатор());
КонецЕсли;
КонецЦикла;

//4. Найдём сотрудников по ФИО и ДР, подготовим таблицу для финальной обработки

ЗапросФинал = новый Запрос;
ЗапросФинал.Текст = "ВЫБРАТЬ
| ДанныеУАТ.ИД,
| ДанныеУАТ.Вес,
| ДанныеУАТ.ДатаПутевки,
| ДанныеУАТ.ГосНомер,
| ДанныеУАТ.ВодительФИО,
| ДанныеУАТ.ВодительДР,
| ДанныеУАТ.ВодительГУИД
|ПОМЕСТИТЬ втДанныеУАТ
|ИЗ
| &ДанныеУАТ КАК ДанныеУАТ
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| уатВодители.ВодительФИО,
| уатВодители.ВодительДР,
| уатВодители.ВодительГУИД,
| ФизическиеЛица.Ссылка КАК Водитель,
| ФизическиеЛица.ID КАК ID
|ПОМЕСТИТЬ втВодители
|ИЗ
| (ВЫБРАТЬ РАЗЛИЧНЫЕ
|  втДанныеУАТ.ВодительФИО КАК ВодительФИО,
|  втДанныеУАТ.ВодительДР КАК ВодительДР,
|  втДанныеУАТ.ВодительГУИД КАК ВодительГУИД
| ИЗ
|  втДанныеУАТ КАК втДанныеУАТ) КАК уатВодители
|  ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.ФизическиеЛица КАК ФизическиеЛица
|  ПО уатВодители.ВодительФИО = ФизическиеЛица.Наименование
|   И уатВодители.ВодительДР = ФизическиеЛица.ДатаРождения
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| втВодители.Водитель КАК Водитель,
| втВодители.ID,
| втДанныеУАТ.ДатаПутевки КАК ДатаПутевки,
| втДанныеУАТ.ГосНомер,
| втДанныеУАТ.Вес КАК Вес,
| втДанныеУАТ.ВодительФИО,
| втДанныеУАТ.ИД КАК ИД
|ИЗ
| втДанныеУАТ КАК втДанныеУАТ
|  ЛЕВОЕ СОЕДИНЕНИЕ втВодители КАК втВодители
|  ПО втДанныеУАТ.ВодительГУИД = втВодители.ВодительГУИД
|
|УПОРЯДОЧИТЬ ПО
| ДатаПутевки
|ИТОГИ ПО
| ИД
|АВТОУПОРЯДОЧИВАНИЕ"
;
ЗапросФинал.УстановитьПараметр("ДанныеУАТ",   табОтчета);
РезультатФинал = ЗапросФинал.Выполнить();

Итоги.

В итоге все довольны: Бухгалтерия — что сократилось время обработки файлов до двух часов в месяц, Руководитель транспортного отдела — что ему не нужно лопатить 80+ файлов каждый месяц.

Обе обработки прикреплены в ознакомительных целях, с минимумом косметических правок. Для запуска их на ваших базах возможно потребуется доработка по замене ID на код справочника.

Чтобы была возможность работать с почтой в 1С:

у пользователя должна быть установлена роль "ПравоИспользованияЭлектроннойПочты";
должна быть настроена учетная запись эл. почты в справочнике "Учетные записи электронной почты"
пользователю должен быть дан доступ на редактирование эл. писем учетной записи (справочник "Учетные записи электронной почты" — вкладка "Доступ")

Обработка отчетов Моспаркинга в КА 1.1 с учетом путевых листов из УАТ 1.0

Related Posts

Leave a Comment Отменить ответ