Работу некоторых циклов с большим количеством проходов разумно сопровождать индикацией прогресса. Но зачастую сама эта индикация и становится главным тормозом процесса. Так как частенько на практике встречаю подобные огрехи, решил опубликовать пример правильной индикации. Речь идет про выполнение кода на клиенте.
Так как индикатор представляет собой элемент графического интерфейса пользователя, то любая операция с ним выполняется относительно долго, будь то строка состояния, индикатор или даже надпись. Поэтому в случае большого количества проходов цикла обновление индикатора на каждом проходе может стать главным потребителем вычислительных ресурсов компьютера. Хотя такие ситуации легко обнаруживаются с помощью замера производительности, все же лучше сразу предусматривать подобные проблемы.
Привожу 2 вспомогательных метода, которые позволят просто и эффективно реализовать индикацию любого цикла.
// Получает структуру для индикации прогресса цикла.
//
// Параметры:
// КоличествоПроходов – Число - максимальное значение счетчика;
// ПредставлениеПроцесса – Строка, "Выполнено" – отображаемое название процесса;
// ВнутреннийСчетчик - Булево, *Истина - использовать внутренний счетчик с начальным значением 1,
// иначе нужно будет передавать значение счетчика при каждом вызове обновления индикатора;
// КоличествоОбновлений - Число, *100 - всего количество обновлений индикатора;
// ЛиВыводитьВремя - Булево, *Истина - выводить приблизительное время до окончания процесса;
// РазрешитьПрерывание - Булево, *Истина - разрешает пользователю прерывать процесс.
// МинимальныйПериодОбновления - Число, *1 - с, обновлять не чаще чем этот период, 0 - по количеству обновлений,
// эта реализация не поддерживает дробные значения;
//
// Возвращаемое значение:
// Структура - которую потом нужно будет передавать в метод ЛксОбработатьИндикатор.
//
Функция ЛксПолучитьИндикаторПроцесса(Знач КоличествоПроходов = 0, ПредставлениеПроцесса = "Выполнение", ВнутреннийСчетчик = Истина, Знач КоличествоОбновлений = 100, ЛиВыводитьВремя = Истина, РазрешитьПрерывание = Истина, МинимальныйПериодОбновления = 1) Экспорт
Индикатор = Новый Структура;
Если КоличествоПроходов = 0 Тогда
Состояние(ПредставлениеПроцесса + "...");
КоличествоПроходов = 1;
КонецЕсли;
Индикатор.Вставить("КоличествоПроходов", КоличествоПроходов);
Индикатор.Вставить("ПредставлениеПроцесса", ПредставлениеПроцесса);
Индикатор.Вставить("ЛиВыводитьВремя", ЛиВыводитьВремя);
Индикатор.Вставить("РазрешитьПрерывание", РазрешитьПрерывание);
Индикатор.Вставить("ДатаНачалаПроцесса", ТекущаяДата());
Индикатор.Вставить("МинимальныйПериодОбновления", МинимальныйПериодОбновления);
Индикатор.Вставить("ДатаСледующегоОбновления", Дата('00010101'));
Индикатор.Вставить("ВнутреннийСчетчик", ВнутреннийСчетчик);
Если КоличествоОбновлений > 0 Тогда
Шаг = КоличествоПроходов / КоличествоОбновлений;
Иначе
Шаг = 0;
КонецЕсли;
Индикатор.Вставить("Шаг", Шаг);
Индикатор.Вставить("СледующийСчетчик", 0);
Индикатор.Вставить("Счетчик", 0);
Возврат Индикатор;
КонецФункции
// Проверяет и обновляет индикатор. Нужно вызывать на каждом проходе индицируемого цикла.
//
// Параметры:
// Индикатор – Структура – индикатора, полученная методом ЛксПолучитьИндикаторПроцесса;
// Счетчик – Число – внешний счетчик цикла, используется при ВнутреннийСчетчик = Ложь.
//
Процедура ЛксОбработатьИндикатор(Индикатор, Счетчик = 0) Экспорт
Если Индикатор.ВнутреннийСчетчик Тогда
Счетчик = Индикатор.Счетчик + 1;
Индикатор.Счетчик = Счетчик;
КонецЕсли;
Если Индикатор.РазрешитьПрерывание Тогда
ОбработкаПрерыванияПользователя();
КонецЕсли;
ОбновитьИндикатор = Истина;
ТекущаяДата = ТекущаяДата();
Если Индикатор.МинимальныйПериодОбновления > 0 Тогда
Если ТекущаяДата < Индикатор.ДатаСледующегоОбновления Тогда
ОбновитьИндикатор = Ложь;
КонецЕсли;
КонецЕсли;
Если ОбновитьИндикатор Тогда
Если Индикатор.Шаг > 0 Тогда
Если Счетчик >= Индикатор.СледующийСчетчик Тогда
Индикатор.СледующийСчетчик = Цел(Счетчик + Индикатор.Шаг);
Иначе
ОбновитьИндикатор = Ложь;
КонецЕсли;
КонецЕсли;
КонецЕсли;
Если ОбновитьИндикатор Тогда
Индикатор.СледующийСчетчик = Цел(Счетчик + Индикатор.Шаг);
Если Индикатор.ЛиВыводитьВремя Тогда
ПрошлоВремени = ТекущаяДата - Индикатор.ДатаНачалаПроцесса;
Осталось = ПрошлоВремени * (Индикатор.КоличествоПроходов / Счетчик - 1);
ОсталосьДней = Цел(Осталось / (24*60*60));
ТекстОсталось = ", Осталось: ";
Если ОсталосьДней > 0 Тогда
ТекстОсталось = ТекстОсталось + ОсталосьДней + "д";
КонецЕсли;
ТекстОсталось = ТекстОсталось + Формат(Дата(1,1,1) + Осталось, "ДЛФ=T");
ТекстОсталось = "Осталось: " + ТекстОсталось + ?(Индикатор.РазрешитьПрерывание, ". Прервать: Ctrl+Break", "");
Иначе
ТекстОсталось = "";
КонецЕсли;
ТекстСостояния = Индикатор.ПредставлениеПроцесса + " " + Формат(Счетчик / Индикатор.КоличествоПроходов * 100, "ЧЦ=3; ЧДЦ=0") + "% " + ТекстОсталось;
Состояние(ТекстСостояния);
КонецЕсли;
Если Счетчик = Индикатор.КоличествоПроходов Тогда
Состояние("");
КонецЕсли;
КонецПроцедуры
Ключевым моментом в ЛксОбработатьИндикатор() для обновления состояния является требование выполнения
в общем случае двух (любое можно отключить) условий:
— прошло минимальное время с момента последнего обновления
— не превысить заданное общее число обновлений
Вот пример их использования.
КоличествоДанных = 100000;
Индикатор = ЛксПолучитьИндикаторПроцесса(КоличествоДанных, "Проверка данных");
Для Счетчик = 1 По КоличествоДанных Цикл
ЛксОбработатьИндикатор(Индикатор, Счетчик);
КонецЦикла;
КоличествоДанных = 100000;
Индикатор = ЛксПолучитьИндикаторПроцесса(КоличествоДанных, "Проверка данных", Истина);
Для Счетчик = 1 По КоличествоДанных Цикл
ЛксОбработатьИндикатор(Индикатор);
КонецЦикла;
Related Posts
Получение логина и пароля техподдержки 1С из базы
Класс для вывода отчета в Excel
Счет-фактура для УПП
Библиотека классов для создания внешней компоненты 1С на C#- Акт об оказании услуг (со скидками) — внешняя печатная форма для Управление торговлей 11.1.10.86
Прайс-лист с артикулом в отдельной колонке
Все хорошо, только умножение-деление на каждом шаге — тоже затратная операция. Конечно, не настолько как перерисовка, но всеж можно еще чуть-чуть убыстрить:
Счетчик=0; СледСчетчик=0; ОдинПроцент=КвоЭлементов/100; Пока ..... цикл Счетчик=Счетчик+1; Если Счетчик>СледСчетчик Тогда СледСчетчик=Цел(Счетчик+ОдинПроцент); Состояние("Выполнено "+Цел(Счетчик/ОдинПроцент)+"%"); КонецЕсли; КонецЦикла;Показать полностью
А вообще, ИМХО, лучше считать не по 1%, а по 5%-10%. Или блоками по 50-10-5 записей (в зависимости от того сколько осталось). А то наблюдать проценты, бегущие по одному — тоже невесело.
(1) Спасибо. Твой вариант конечно же более красивый и эффективный. Берем на вооружение.
Оптимизировал и немного расширил возможности
Если выжимать "соки", тогда уж так, наверное…
Счетчик=0; СледСчетчик=0; ОдинПроцент = КвоЭлементов * 0.01; // --- Коэффициент = 100 / КвоЭлементов; // --- Пока ..... цикл Счетчик=Счетчик+1; Если Счетчик>СледСчетчик Тогда СледСчетчик=Цел(Счетчик+ОдинПроцент); Состояние("Выполнено "+Цел(Счетчик * Коэффициент)+"%"); // --- КонецЕсли; КонецЦикла;Показать полностью
Просмотрел… Не понравился момент Счетчик/Шаг. А вообще, алгоритм не оптимальный. В (4) мне нравится больше. Зачетно было бы вообще освободиться от умножения и деления в цикле.
Шаг = Количество / 100; ТекШаг=Шаг; К=1; Процент=0; Пока ... Цикл К=К+1; Если К>=ТекШаг Тогда Процент=Процент+1; ТекШаг=ТекШаг+Шаг; Сообщить("Выполнено "+Процент+" % ..."); КонецЕсли; ... КонецЦикла;Показать полностью
(5) Каждому свое. Для меня например немаловажную роль играет количество строк в конструкции. Разница в производительности между нашими вариантами будет незначительной даже при холостом прогоне, а уж при нагрузочном прогоне она почти исчезент. А вот у меня на 2 строки меньше получается конструкция. Вообще, на ассме я тоже писал и тоже могу оптимизировать код, но кажется здесь не тот случай.
Основная идея публикации от тебя видимо ускользнула через призму (4) =)
(5) У меня тоже был такой «очевидный» вариант. Но как оказалось — работает медленнее… Думаю это проблема интерпретаторов, когда две «сложные» команды обрабатываются быстрее, чем три простые…
(7) А может быть это не проблема, а благо?)
Можно проще и нагляднее. Есть операция остаток от деления «%». Пример 10%3=1. Пример кода:
ПредставлениеПроцесса = «Обработка строк таблицы»;
Счетчик = 0;// СледующийСчетчик = 0;
Шаг = Таблица.Количество() / 100;
Для Каждого Строка Из Таблица Цикл
ОбработкаПрерыванияПользователя();
Счетчик = Счетчик + 1;
//Если Счетчик > СледующийСчетчик Тогда
Если Счетчик % Шаг=0 Тогда
//СледующийСчетчик = Цел(Счетчик + Шаг);
Состояние(ПредставлениеПроцесса + » » + Формат(Счетчик / Шаг, «ЧЦ=3; ЧДЦ=0») + «%»);
КонецЕсли;
КонецЦикла;
Обновил. Теперь все стало намного красивее и удобнее.
(13) Если плясать от плотности по времени, то это совсем другой подход. Мой подход в большинстве случаев ест заранее известное количество вычислительных ресурсов.
(11) Формы обычно не нужны. Это красиво, но надо объект метаданных задействовать.
Я про фиксированную плотность по времени раньше тебя придумал))))) Но делать не стал, т.к. пока нет необходимости. Не отрицаю, что это будет полезно.
(4) согласен (хотя лично я не люблю обратных величин). А вобще, жалко что в 1С нету _целочисленного_ умножения/деления.
На самом деле, оптимизнуть можно в СледСчетчик=Цел(Счетчик+ОдинПроцент) от Цел() избавившись. Т.к. Счетчик у нас итак целый, значит дробь м.б. только от ОдинПроцент. Потому мы спокойно можем сделать ему Цел() вне цикла.
(5) Что ж там неоптимально??? деление выполнется не более 100 раз, это много?
И выполняется оно исключительно в целях более точной индикации.
Ваш же код неверен — для примера, представьте индикацию, когда кол-во шагов будет меньше 100.
(9) А тут код действительно неоптимальный. Мы выполняем «%» (что есть эквивалент «/» ) на _каждом_ шаге — как раз то, от чего пытались уйти.
(17) Решается простой проверкой
(17) по поводу ответа на (9). Я честно не пробовал, но думаю что на интерпретаторе деление будет еще и быстрее чем замена или разница не ощутима (да еще и минус одна переменная и наглядность). Я там кстати забыл функцию Цел() Цел(Счетчик % Шаг)=0
На мой взгляд лучше индикация раз в секунду:
там где проверка выводить индикацию проверяем сменилась ли секунда.
Сделал так когда столкнулся с необходимости выводить время прошедшее и оставшееся. Некрасиво получается когда процесс выполняется очень быстро меньше 5 секунд. Зато влияние индикации стало минимальным.
(17) провирил скорость на примере
1. 55,4% времени
Для Сч=1 По 10000 Цикл
А=Сч %100;
КонецЦикла;
2.45,4 % времени
Для Сч=1 По 10000 Цикл
А=Сч + 212;
КонецЦикла;
разница мала
(21) Люди там старались убрать операцию деления т.к. она вроде как долго.
Расчет времени выполнения и все такое эт канечно красиво… Но я для своих обработок сделал такое и особо не парюсь…
Процедура глОбработкаИндикатора(ТекСчетчик,ТекИндикатор,ЧастотаОбновления) Экспорт
// ТекСчетчик — перемнная счетчика цикла (в теле цикла увеличивать ее не надо)
// ТекИндикатор — Переменная связанная с элементом формы Индикатор
// ЧастотаОбновления — частота обновления индикатора в количестве раз обхода цикла
// Увеличим индикатор цикла
ТекСчетчик = ТекСчетчик + 1;
Если ТекСчетчик >= ЧастотаОбновления Тогда
ТекИндикатор = ТекИндикатор + ТекСчетчик;
ТекСчетчик = 0;
КонецЕсли;
КонецПроцедуры
В цикле вызывается эта процедура и индикатор изменяется столько сколько мне надо.
Например так
Сч = 0;
Индикатор = 0;
ЧастотаОбновления = ТЗ.Количество() * 0.1; // т.е. каждые 10% данных
Для каждого Стр из ТЗ Цикл
<что там надо нам сделать>
глОбработкаИндикатора(Сч,Индикатор,ЧастотаОбновления);
КонецЦикла;
Мелкие погрешности канечно есть, но это абсолютно не важно
забыл написать еще, что перед циклом:
ЭлементыФормы.Индикатор.МаксимальноеЗначение = ТЗ.Количество();
еще можно добавить что-то типа
тогда индикатор вложенного цикла будет
Добавил поддержку минимального периода обновления
А как вывести индикатор для процесса, который идет на сервере и «каждую секунду» показывает на экране состояние, не возвращаясь в вызвавшую процедуру? Или это тоже, как фоновое задание?
Имеет смысл уточнить, что ЛксОбработатьИндикатор вставлять нужно перед концом цикла
Все хорошо, только умножение-деление на каждом шаге — тоже затратная операция. Конечно, не настолько как перерисовка, но всеж можно еще чуть-чуть убыстрить:
Занятно очень пригодиться
Тоже использовал что-то похожее у себя (по проще конечно), раньше не замечал (на 13 платформе), но сейчас при выполнении какого-нибудь большого цикла, вывод прогресса зависает, хотя сам цикл выполняется 100%. Пробовал и с данными функциями — тоже самое. Платформа 8.2.15.301.
(33) Скорее всего проблема в твоем коде.
(34) Использовал и ваши функции:
Показать
При потере фокуса, и обратном переключении индикация не обновляется
(35) Есть ряд особенностей платформы, которые заставляют считать такое поведение нормой. Например, выполнение этого кода в обработчике ожидания. Только что проверил на 8.2.15.301 обычное приложение файловая СУБД — описанная тобой проблема не воспроизводится при обычном выполнении кода.
(36) Вроде разобрался. Косяк с остановкой индикации возникает при вызове функции(содержащей индикацию прогресса цикла)в модуле объекта внешней обработки. Если эту функцию вызывать в модуле формы, то все норм
(37) Можешь выложить пример, демонстрирующий проблему?
При открытии обработки запускается процедура из модуля объекта (при потере фокуса индикация зависает), а при нажатии на Выполнить вызывается та же процедура, но прогресс не виснет при потере фокуса
(39) Действительно, при долгом выполнении кода в разделе инициализации модуля окно перестает перерисовываться. Я постоянно сражаюсь за исправление подобного рода неудобств в платформе, но иногда ошибкой такой поведение 1С признавать не хотят. Кажется с разделом инициализации модуля так и было. Попробую еще разок им написать для верности.
Вот как! Со времен семерки такое искал, а тут сделали на новой платформе — молодцы!
За идею +. А код нужно оптимизировать, всетаки хочется чтоб второстепенный код потреблял минимум ресурсов.
(42) Сколько то заметные операции по умолчанию выполняются 1 раз в секудну. При остальных вызовах там оптимизировать вроде бы нечего. Можете показать замер где видна неоптимальность? Какие есть идеи по оптимизации?
(43) использовать возврат вместо флага «ОбновитьИндикатор» вычисление времени через дата(1,1,1)+осталось и форматный вывод,ускорило в 2-3 раза, + сокращение строк кода, не замерял но тоже даст прирост
(44) Спасибо. Формирование строки состояния через Формат действительно лучше выполнять. Остальное считаю неразумной экономией («на спичках»).
Возьму на вооружение!!
Спасибо, очень пригодиться!
Отличная вещь, сам делал да терпения не хватило вылизать, так что к себе в ГОСиД вставил
но чуток поправил:
1. вместо:
упростил:
2. вместо:
уточнил (а то не все в курсе особенно 7-ки, да и в любом случае полезно):
3. и добавил для визуализации в ЛксПолучитьИндикаторПроцесса переменную Прогресс, куда передаю элемент формы чтобы видеть ползунок если он есть на форме
4. не совсем понял зачем ВнутреннийСчетчик, можно расшифровать?
5. совсем не понял зачем в конце ЛксОбработатьИндикатор() проверка
ведь в описании это Структура, и в начале процедуры к ней обращаются как к структуре и если передать строку то получим ошибку:
Я так понимаю что строку нужно либо передавать отдельным параметром (завести новый) либо вообще это отдельный случай (аппендикс походу 🙂
Я такое как-то делал но проверку на любую коллекцию Массив, Структура, и остальные
(48)
1. Действительно твой вариант будет несколько быстрее, но я не люблю экономить на копейках, снижая отлаживаемость кода.
2. Тоже пару раз хотел добавить, но пересиливал себя =)
— много лишнего текста будет отвлекать от главного
— текст справа от переменного фрагмента будет прыгать (смещаться) вправо-влево, что привлекает лишнее внимание
— усложнится многоуровневый индикатор (здесь не представлен)
3. У строки состояния перед формой весомое приемущество — ее практически не нужно очищать/убирать/закрывать в случае прерывания процесса исключением или пользователем.
4. Не понял вопроса, можешь пояснить?
5. Индикатор типа СтрокаТаблицыЗначений используется в многоуровневом индикаторе (здесь не представлен)
(49)1. Странно как он влияет на отладку, вроде очевидная вещь, чего ее отлаживать? Получается конструкцией ?(,,) вообще не пользуешся?
2.
— Ну кому как, мне так наоборот красивше, к тому же реально полезно, а не просто так
— Ну смещение то будет незначительное, только на 1 символ и только 9 раз, смотри:
Выполнено 1% Осталось: 00:01:00 Прервать: Ctrl+Pause/Break (от 1 до 9)
и
Выполнено 10% Осталось: 00:01:00 Прервать: Ctrl+Pause/Break ( а тут все остальное)
— вот насчет многоуровневого не в курсе, если его тут нет то что на него равнятся то?
3. Естественно, однако я часто запускаю процесс и ухожу еще куда-нибудь по делам, издалека хорошо видно статус, а вот текст в строке состояния, так что мне и подходить не нужно чтобы понять сколько выполнилось, а чтобы уточнить можно и приглядеться
4. Ну переменная у тебя есть такая
Это наверно когда делается несколько итераций прежде чем вызывается твоя функция? Но мне сложно представить такую потребность
5. Опять же — если его нет то зачем код от него тут? На него же тратится время и вообще он мусорный или как?
1-3 Это все довольно очевидно. Дело вкуса.
4. Приведи пример использования индикатора для этого вопроса. Похоже я все еще не понимаю.
Про многоуровневый индикатор я пишу потому, что у меня он есть и я не хочу держать по несколько версий одной функции. Вношу исправление в одну и сразу можно публиковать ее сюда без дополнительных телодвижений.
Как раз хотел «стырить» это с ИР, а тут оказывается, уже давно все выложено:)
Спасибо.
ЗЫ: Сергей, а правда, что отображение индикатора на текущей форме или общей форме хода выполнения заметно затратнее, чем состояние()?
Сергей, а можете привести пример, когда тип начения индикатора «СтрокаТаблицыЗначений»?
(54) Нет. Его можно увидеть в подсистеме «Инструменты разработчика». В этой статье представлена обрезанная версия для демонстрации основных принципов.
(55) Можно хотя бы пояснить, для чего вам таблица состояний индикаторов? Для многопоточных обработок?
(56) Нет. Для многоуровненых циклов.
Оптимизировал код по замечаниям из комментариев. Но эффект от этой оптимизации будет незначительный.
Добрый день.
Попробовал использовать, но при проверке модуля ругается: Переменная не определена (ОсталосьВремени)
Что за переменная, она нигде не инициализируется?
(59) Внес эту ошибку во время последней правки. Исправил.
(60), спасибо.
Подскажите пожалуйста, проверил если выводить индикацию, то по времени получается раз в 10 дольше (прыгать клиент-сервер-клиент), если совсем не выводить (выполнять все на сервере)
Это из-за прыганья, т.е. выодить индикацию наверное не рекомендуется и тогда в каких случаях можно оправдать вывод индикации?
(61) Эта статья написана для выполнения кода на клиенте. Для случая выполнения кода на сервере есть масса других публикаций и способов. Я не планирую расширять статью на этот случай.
Сергей, подскажите пож-та, что означает «Лкс» в названии процедуры/функции (например: ЛксПолучитьИндикаторПроцесса)?
(63) Это — префикс. Другого значения у этой строки нет.
(64) Этот префикс — он ведь не во всех методах присутствует (речь про ИР)? Подскажите пож-та, при изучении кода ИР мне следует придавать этому префиксу какое-либо значение?
(65) Нет