Отладка/доработка модуля менеджера "на лету"

Данный прием позволяет отлаживать и дорабатывать модуль менеджера во внешней обработке без необходимости пересохранять конфигурацию и перезапускать базу

Постановка задачи

Предположим, что мы дорабатываем базу с очень тяжелой конфигурацией. Сохранение и/или перезапуск после сохранения выполняются продолжительное время.
Пусть есть модуль менеджера некоторого объекта в нашей конфигурации. В этом модуле менеджера есть экспортный метод, из которого вызываются остальные процедуры.
Необходимо доработать этот модуль менеджера. При этом требуется минимизировать количество перезапусков базы после каждого внесения изменения в код в процессе отладки.

Суть решения

— Скопируем весь код модуля менеджера во внешнюю обработку
— Добавим возможность переадресовывать вызовы экспортных методов модуля менеджера во внешнюю обработку (максимально простым способом)
— Переадресацию будем включать/отключать из отладчика с помощью механизма остановки по условию

Шаг 1.
Предлагаю добавить в начало метода, который является точкой входа, следующий код:

// Модуль менеджера некоторого объекта конфигурации

Процедура Печать(Параметры) Экспорт

// ++ отладка
Перем Отладчик;

Если Отладчик <> Неопределено Тогда
Отладчик.Печать(Параметры);
Возврат;
КонецЕсли;
// -- отладка

Сообщить("Это вызов из модуля менеджера");

КонецПроцедуры

Шаг 2.
Далее создаем служебную универсальную внешнюю обработку, например, в какой-нибудь папке на сервере. Назовем ее Отладчик.epf.
В этой обработке опишем короткую универсальную экспортную функцию примерно следующего содержания:

// Модуль обработки Отладчик.epf

Функция УстановитьМодульОтладки(Отладчик, ИмяМодуля) Экспорт

Отладчик = ВнешниеОбработки.Создать(ПутьКВнешнейОбработке(ИмяМодуля), Ложь);

Возврат Ложь;

КонецФункции

Функция ПутьКВнешнейОбработке(ИмяМодуля)

Возврат ТекущийКаталог() + ИмяМодуля+ ".epf";

КонецФункции

Функция ТекущийКаталог() Экспорт

Файл = Новый Файл(ЭтотОбъект.ИспользуемоеИмяФайла);
Возврат Файл.Путь;

КонецФункции

Шаг 3.
Создадим внешнюю обработку, в которой будем писать наш код. Копируем в модуль объекта этой обработки код из модуля менеджера полностью.
Сохраним ее в той же папке, что и Отладчик.epf. Зададим для этой обработки имя, например, такое Обработки.ПечатьСчета.МодульМенеджера.epf.

// модуль объекта внешней обработки Обработки.ПечатьСчета.МодульМенеджера.epf

Процедура Печать(Параметры) Экспорт

// ++ отладка
Перем Отладчик;

Если Отладчик <> Неопределено Тогда
Отладчик.Печать(Параметры);
Возврат;
КонецЕсли;
// -- отладка


// ++ исправили
//Сообщить("Это вызов из модуля менеджера");
Сообщить("Это вызов из внешней обработки");
// -- исправили

КонецПроцедуры

Шаг 4.
В модуле менеджера ставим точку останова по условию. В условие прописываем следующий код:

ВнешниеОбработки.Создать("C:ОтладкаОтладчик.epf", Ложь).УстановитьМодульОтладки(Отладчик, "Обработки.ПечатьСчета.МодульМенеджера")

Шаг 5.
Запускаем тестовый пример. В точке останова будет вызвана проверка условия. При этом в переменную Отладчик присвоится объект созданной внешней обработки Обработки.ПечатьСчета.МодульМенеджера.epf. Это приведет к тому, что условие Если Отладчик <> Неопределено Тогда выполнится, и вызов будет переадресован во внешнюю обработку.

Шаг 6.

Дорабатываем и отлаживаем код во внешней обработке, при этом не тратим время на перезапуск после каждого сохранения.

После окончания доработок — заменяем код в модуле менеджера на код из внешней обработки (полностью).

Не забываем отключить точки останова по условию.

Перед помещением в хранилище можно удалить отладочную часть в модуле менеджера.

Область применения

Таким способом можно отлаживать и дорабатывать модули менеджеров любых объектов и общие модули (серверные).
Для отладки модулей объектов используется похожая технология, но при этом имеется ряд нюансов и ограничений.

Файлы

Прикладываю внешнюю обработку Отладчик.epf, которая кроме описанной выше функции имеет еще несколько полезных возможностей. В том числе умеет создавать пустую обработку-шаблон с именем, соответствующим дорабатываемому объекту

Обработка открывается в режиме управляемого и обычного приложения в любой конфигурации.
Тестировалась на платформе 8.3 в режиме совместимости с 8.2.13. То есть должна работать под 8.2 и 8.3

22 Comments

dj_serega 23.10.2016 at 19:56

+ за идею

Reply ↓
Swetlana 23.10.2016 at 20:36

не вижу идею((

Reply ↓
Alister 23.10.2016 at 21:06

Как бы и всем остальным идею оценить.)))

Reply ↓
json 23.10.2016 at 21:28

(2) Swetlana, а я вижу 😉

Reply ↓
json 23.10.2016 at 21:43

(3) Alister, нет ничего проще.

1. Просто попробуйте доработать проведение документа в ерпи на среднестатистическом тестовом сервере.

Посчитайте количество перезапусков, которое вы делаете на этапе отладки и умножьте это количество на время перезапуска.

2. А после этого попробуйте проделать все то же самое по описанной выше технологии.

3. Почувствуйте разницу.

ps. ВСЕМ не оценить, т.к. с тяжелыми конфигурациями [к счастью] работают не ВСЕ.

Reply ↓
citicat 24.10.2016 at 08:57

Спасибо большое! При работе с УПП и шести одновременно работающих пользователях (или КА и двенадцати одновременно работающих пользователях) полезный инструмент.

Reply ↓
jaroslav.h 24.10.2016 at 09:41

ай бомбец, какой бомбец, не знал, попробовал, шик, дякую!

Reply ↓
Alister 24.10.2016 at 12:27

(5) первые посты были не от того, что идея какая-то не такая, а потому что из-за нового интерфейса пропала кнопка перехода к самой публикации из коментов, вот и не понятно было в чем состоит идея — просто не знали, как в публикацию перейти, а в лучших из новых она еще не появилась.

Reply ↓
Alister 24.10.2016 at 12:30

(0) вот, когда появился нулевой комент, то и кнопка перехода к публикации появилась.)))

Reply ↓
json 24.10.2016 at 12:38

(8) Alister, теперь ясно)

А я то с форума не перехожу, поэтому и не понял в чем фишка

Reply ↓
herfis 24.10.2016 at 12:50

Использование условной точки останова в т.ч. в качестве переключателя developer/production — остроумный ход, упрощающий использование идеи.

Но с другой стороны — выполнение подмены на сервере требует сервера в режиме отладки.

Возможно, имеет смысл усложнить идею, чтобы обойти это ограничение.

Reply ↓
json 24.10.2016 at 13:30

(11) herfis, думал использовать для этого хранилище настроек.

Но схема при этом сильно усложняется. Нужно больше кода писать для переадресации и инструмент запуска делать более навороченный.

Пока этот вариант устраивал, не стал заморачиваться.

У вас уже есть наработки или идеи по этому поводу?

Reply ↓
herfis 24.10.2016 at 15:12

(12) Наработок и идей нет. Идея использования хранилища настроек вполне нравится.

Да, удобный инструмент (обработку) для администрирования отладки придется делать навороченным. Чем удобнее его делать, тем более навороченным он будет.

Основной код переадресации для минимизации самой заглушки можно запихнуть в хранилище настроек тоже и вызывать через Выполнить().

Главный минус, который вижу — после отладки отладочный код будет очень желательно удалить (в отличие от сабжевого решения, где можно его «бесплатно» оставить).

Reply ↓
vec435 26.10.2016 at 08:43

использование 1 внешней обработки с кучей доп модулей существенно упрощает отладку и разработку. Например поменять значение переменной «на лету».

Но почему нельзя напрямую из конфигуратора в нужной точке останова вызвать ВнешниеОбработки.Создать(«C:ОтладкаОтладчик.epf», Ложь).печать(параметры, допПараметры)? Плюс в том что исходный код не переписывается.

Reply ↓
json 26.10.2016 at 09:15

(14) vec435, я вижу несколько причин, почему неудобно делать, как вы предлагаете:

— так можно вызвать только функцию. Если Печать была бы процедурой, то через вычислить выражение её было бы не вызвать

— часто бывает, что дорабатываемый модуль является промежуточным звеном и после него вызываются другие, например при проведении в типовых

— бывает, что за экспортной процедурой тянется куча других. У меня так было, когда я дорабатывал модуль ПартионныйУчет в ерпи 2.1

— также считаю неудобным вписывать в точке останова вызываемый метод, т.к. при опечатке трудно увидеть ошибку, а также в случае, если у функции большое число параметров

— функция печать может возвращать параметр отличный от булевского

Но если требуется только изменить значение переменной, то можно использовать ваш метод и не вносить изменения в код вообще

Т.о.считаю описнный в статье подход более универсальным

Reply ↓
vec435 26.10.2016 at 16:33

из функции «ФункПечать» можно вызвать процедуру «печать» во внешней обработки

вызываемый метод в любом случае вписывается в вызов «руками» или копируется из какого-то места

можно передать как допПараметр объект и вызывать другие функции

и мы выполняем отладку дорабатываемого модуля — т.е. отладили, получили необходимый результат — перекинули в исходный модуль и дальше смотришь

и опять -таки «исходный код не переписывается» !!!!

Reply ↓
json 26.10.2016 at 17:06

(16) vec435, признаю, что был не прав, что можно отлаживать только функции.

А как предложите поступить, чтобы прервать процедуру? Например, в примере с печатью мы получим сначала доработанную версию табличного документа, а затем исходную.

Или предположим еще одна ситуация: мы вызываем экспортную функцию, которая возвращает значение. Возникает ряд случаев, когда нельзя просто так взять и подменить результат.

Или еще одна ситуация, пусть в нашу процедуру передается таблица, которую мы должны заполнить в этой процедуре. В этом случае нельзя, чтобы одновременно выполнилась и встроенная и внешняя версии модуля.

Но в общем согласен. Подход, предложенный вами мне нравится. В большинстве случаев можно обойтись вообще без изменения исходного модуля, но только придется проявлять долю изобретательности от раза к разу.

Reply ↓
vec435 27.10.2016 at 12:11

согласен, сложностей хватит и в том и другом случае. Если есть возможность изменить конфигурацию — то возможно ваш и лучше. Но в таком случае можно выставить прерывание выполнения исходного модуля и выполнить только внешнюю процедуру — изменение исходного модуля минимум

Reply ↓
wojwoo 31.10.2016 at 17:32

(0) Спасибо!

Благодаря Вам, написал свою первую статью о своих вариантах борьбы со стоимостью перезапуска 1С при разработке в УПП (http://infostart.ru/public/558702/)

Reply ↓
json 31.10.2016 at 18:38

(19) wojwoo, я пока еще не успел описать отладку форм. Это пока в планах.

При отладке необходимо минимизировать количество отладочного кода, который вам потом придется удалять. Так вот, предлагаю вам подумать, как можно реализовать отладку форм вообще без модификации самой формы. Т.е. чтобы доработать-отладить форму в нее можно не добавлять отладочный код вообще.

Reply ↓
wojwoo 01.11.2016 at 15:25

(20)

В моем примере «Быстрое редактирование и отладка формы документа» в дорабатываемой форме (документа или справочника) отладочного кода нет.

Форма копируется во внешнюю обработку и после внесения доработок возвращается в конфигурацию без дополнительных модификаций.

Для удобной отладки в обработку дополнительно копируется форма списка, в которую вносится дополнительный код, чтобы запускать дорабатываемую форму, а не форму в конфигурации. Этот код фактически без модификаций может быть применен для любой формы списка, т.е. может использоваться как шаблон.

Считаю, что задачу минимизации количества перезапусков базы после каждого внесения изменения в код в процессе отладки мой вариант решает.

Если вариант с дополнительным копированием формы списка представляется громоздким и предполагается отладка на одном объекте в событии «ПередОткрытием» формы прописать всего 1 строчку, которую, естественно, нужно удалить перед возвратом формы в конфигурацию:

ДокументОбъект = Документы.ИмяДокумента.НайтиПоНомеру(«НомерДокумента», ТекущаяДата()).ПолучитьОбъект();

Или

СправочникОбъект = Справочники.ИмяСправочника.НайтиПоКоду(«Код»).ПолучитьОбъект();

PS

Поясните, пожалуйста, причину просьбы удалить Вашу фамилию и имя из текста моей статьи.

Reply ↓
MarSeN 08.10.2019 at 10:31

+1

Увидел принцип перенаправления выполнения кода, который месяц назад заюзал для своей консольки кода на УФ.

Значит не только у изветсных персонажей мысли сходятся.

Возможно скоро выложу свой вариант, только хочу его как опенсо

Reply ↓