РеквизитФормыВЗначение () и ДанныеФормыВзначение (). Описание и примеры использования.

В Синтаксис-Помощнике очень скупо написано о процедуре ДанныеФормыВЗначение(), чуть побольше — о РеквизитФормыВЗначение(). И совсем нет примеров использования. Попробуем с этим разобраться.

РеквизитФормыВЗначение() является методом управляемой формы, компилируется только &НаСервере, контекст формы является для него необходимым, поэтому компиляция &НаСервереБезКонтекста недоступна. На клиенте не работает, поскольку в результате получаем прикладной объект.

Где и когда его нужно использовать?
Метод РеквизитФормыВЗначение() необходим, если требуется из модуля формы вызвать стандартный метод объекта или метод (процедуру, функцию) из модуля объекта, из общего модуля.
Этот метод будет отрабатывать с данными, взятыми из формы, т.е. еще не записанными в базу.

Для того, чтобы измененные данные вернуть на форму, используется метод ЗначениеВРеквизитФормы().

Вторым параметром метода РеквизитФормыВЗначение является тип значения. Это необязательный параметр. Если обрабатываемый реквизит не является составным типом, то тип будет автоматически получен из реквизита формы. Иначе генерируется исключение времени выполнения.

Примеры:
1)

&НаСервере
Процедура ЗаполнитьТЧПоДаннымПоследнегоДокумента(Контрагент)

ДокОбъект = РеквизитФормыВЗначение(«Объект»);
ДокОбъект.ЗаполнитьТЧПоДаннымПоследнегоДокумента(Контрагент);
ЗначениеВРеквизитФормы(ДокОбъект, «Объект»);

КонецПроцедуры

&НаСервере
Процедура ОчиститьСтрокиСПустойЦенойНаСервере()

ДокОбъект = РеквизитФормыВЗначение(«Объект»);
ДокОбъект.ОчиститьСтрокиСПустойЦеной();
ЗначениеВРеквизитФормы(ДокОбъект, «Объект»);

КонецПроцедуры

&НаСервере
Функция ОбъектЗаполнен()
Возврат РеквизитФормыВЗначение(«Объект»).ПроверитьЗаполнение();
КонецФункции

В указанных выше случаях метод РеквизитФормыВЗначение() похож на метод ПолучитьОбъект(). Разница в том, что первый получает объект, заполненный данными формы, а второй — объект с данными из базы.

ДанныеФормыВзначение()

В отличие от метода управляемой формы РеквизитФормыВЗначение(), процедура глобального контекста ДанныеФормыВЗначение() может работать без контекста формы, но именно поэтому, в частности, ей необходимо указывать тип конвертируемых данных.

Обратной процедурой является ЗначениеВДанныеФормы().

Примеры:
1) &НаСервере

// Инициализация набора констант
НаборКонстантОбъект = ДанныеФормыВЗначение(НаборКонстант, Тип(«КонстантыНабор»));
НаборКонстантОбъект.Прочитать();
ЗначениеВДанныеФормы(НаборКонстантОбъект, НаборКонстант);

2) &НаСервере

НаборФорма = Объект.Движения.РегистрУправленческий;

Набор = ДанныеФормыВЗначение(НаборФорма, Тип(«РегистрБухгалтерииНаборЗаписей.РегистрУправленческий»));
Если Набор.Количество()=0 Тогда
Возврат;
КонецЕсли;
Набор.УстановитьАктивность(НЕ Набор[0].Активность);
ЗначениеВДанныеФормы(Набор, НаборФорма);

В этом примере на форме отображен набор записей регистра бухгалтерии. При отработке процедуры, активность набора меняется только на форме, в базе при этом ничего не происходит. Активность у набора записей регистра в базе поменяется только после выполнения операции Записать.

3)
&НаКлиенте
Процедура Заполнить(Команда)

ОснРеквизит = Объект;
ВыполнитьНаСервереБезКонтекста(ОснРеквизит);
КопироватьДанныеФормы(ОснРеквизит,Объект)

КонецПроцедуры

&НаСервереБезКонтекста
Процедура ВыполнитьНаСервереБезКонтекста(ОснРеквизит)

ОбъектЗначение = ДанныеФормыВЗначение(ОснРеквизит, Тип(«ДокументОбъект.АктСверкиВзаиморасчетов»));

//…Выполнение операций с Объектом «ОбъектЗначение»

ЗначениеВДанныеФормы(ОбъектЗначение, ОснРеквизит);

КонецПроцедуры

В этом примере на клиент возвращается ОснРеквизит, содержащий измененные данные. Но его еще нужно «запихать» в отображаемую форму. Для этого используем процедуру глобального контекста КопироватьДанныеФормы().

В большинстве случаев процедуры ДанныеФормыВзначение() и РеквизитФормыВЗначение() взаимозаменяемы. При этом РеквизитФормыВЗначение проще в использовании. Но если требуется использование &НаСервереБезКонтекста — тогда только ДанныеФормыВЗначение.

В качестве иллюстрации взаимозаменяемости Пример 2 еще в двух вариантах:

ВАРИАНТ 1
&НаКлиенте
Процедура Активность(Команда)

ОснРеквизитДвижения = Объект.Движения.РегистрУправленческий;
АктивностьНаСервереБезКонтекста(ОснРеквизитДвижения);
КопироватьДанныеФормы(ОснРеквизитДвижения,Объект.Движения.РегистрУправленческий);

КонецПроцедуры // Активность()

&НаСервереБезКонтекста
Процедура АктивностьНаСервереБезКонтекста(ОснРеквизитДвижения)

Набор = ДанныеФормыВЗначение(ОснРеквизитДвижения, Тип(«РегистрБухгалтерииНаборЗаписей.РегистрУправленческий»));
Если Набор.Количество()=0 Тогда
Возврат;
КонецЕсли;
Набор.УстановитьАктивность(НЕ Набор[0].Активность);
ЗначениеВДанныеФормы(Набор, ОснРеквизитДвижения);

КонецПроцедуры // АктивностьНаСервереБезКонтекста()

ВАРИАНТ 2

&НаСервере
Процедура АктивностьНаСервере()

НаборФорма = РеквизитФормыВЗначение(«Объект»);
Набор = НаборФорма.Движения.РегистрУправленческий;

Если Набор.Количество()=0 Тогда
Возврат;
КонецЕсли;

Набор.УстановитьАктивность(НЕ Набор[0].Активность);
ЗначениеВРеквизитФормы(НаборФорма, «Объект»);

КонецПроцедуры // АктивностьНаСервере()

40 Comments

Поручик 26.09.2012 at 13:06

Щас набегут местные умники и начнут ~~грабить корованы~~ размахивать Хрусталёвой с Радченко.

Reply ↓
no_registration 26.09.2012 at 14:30

Спасибо. Полезная статья.

Reply ↓
Daddysb 02.10.2012 at 10:39

Спасибо! Полезно!

Reply ↓
FedorovEvg 05.10.2012 at 16:54

полезно+100

Reply ↓
plastilin 07.10.2012 at 00:25

Отличная статья!!

Reply ↓
ZeroDM 08.10.2012 at 08:37

Тема хорошая, но раскрыта не до конца.

Во второй части, где описываются методы ДанныеФормыВзначение() и ЗначениеВДанныеФормы() не достаточно содержательно, описано:

— назначение процедур;

— почему или в каких случаях нужно использовать ДанныеФормыВзначение(), а не РеквизитФормыВЗначение() и в каких наоборот.

Reply ↓
vladir 10.10.2012 at 14:16

(0) Спасибо, полезная информация.

Reply ↓
FractonKireyev 11.10.2012 at 19:10

Согласен с ZeroDM — тема раскрыта не полностью. Кроме того описание скомкано: то-ли автору лень писать, то-ли не до конца понял о чём пишет…

Reply ↓
klel 11.10.2012 at 20:28

Полезно и наглядно =) ОГРОМНЫЙ +

Reply ↓
LexSeIch 21.03.2013 at 05:47

Мир этому дому.

Полезная статья для тех кто начинает программировать управляемые формы. Автору спасибо!

Reply ↓
AVK_Alex 24.10.2013 at 11:18
Здравствуйте, коллеги!

Сначала немного лирики: у клиента (УТ11) скачет интернет (меняется IP / отключается). Пользователи дубасят документы (пусть будет РТУ). Кнопку «Записать» нажимать забывают (наверное, только на уровне Господа Бога этот вопрос еще не обсуждался). Работают тонким клиентом через веб-сервер (RDP нет). При отключении интернет клиент отваливается с потерей всего, что нажито непосильным трудом.

Задача: обеспечить минимальные потери данных при скачках интернета.

Решение выбрано такое:

1. При изменении ТЧ «Товары» сохранять объект целиком (документ РТУ) в регистре сведений. Записывать документ не подойдет, т.к. пользователь может отказаться от создания документа.

2. При записи / проведении / закрытии формы документа — удалять записи из регистра.

3. При старте 1С проверять, есть ли записи в регистре и восстанавливать их.

Трудности:

Сделано все, за исключением заполнения данных формы данными объекта при восстановлении.

— На клиенте есть восстановленный объект, есть форма этого объекта, могу её открыть, но не могу её заполнить.

— На сервере есть восстановленный объект, есть форма этого объекта, могу её заполнить, но не могу открыть или передать на клиент.

Варианты решения:

1. Заполнять на клиенте в цикле по одному реквизиту — как-то несерьезно.

2. Дорабатывать форму документа, чтобы при открытии она сама проверяла наличие записи в регистре — дополнительное изменение конфигурации (а такую практику восстановления планируется распространить и на прочие документы).

3. Сохранять непосредственно ТЧ «Товары» — проще восстанавливать, но шапка будет пустая…

Что посоветуете? Должен же быть какой-то встроенный заполнятор?

P.S. Кусок кода:
```
&НаКлиенте
Процедура ВосстановитьОбъект (СсылкаНаОбъект, ИмяФормы) //Ссылка на объект — измерение в регистре
ВосстановленныйОбъект = ВосстановитьОбъектНаСервере (СсылкаНаОбъект); //Это восстановленный объект
ПараметрыФормы = Новый Структура («Объект», ВосстановленныйОбъект);   //Передавать через параметры не работает…
Фрм = ПолучитьФорму(ИмяФормы, ПараметрыФормы);
Фрм.Открыть();
КонецПроцедуры
```
Показать
Reply ↓
gvk2009 25.10.2013 at 10:18

(11) AVK_Alex, в качестве «заполнятора» используйте процедуру глобального контекста КопироватьДанныеФормы. В вашем коде будет примерно так (при условии, что структуры «ВосстановленныйОбъект» и «Фрм.Объект» совпадают):

…

КопироватьДанныеФормы(ВосстановленныйОбъект, Фрм.Объект);

Фрм.Открыть();

Reply ↓
AVK_Alex 25.10.2013 at 12:41

(12) gvk2009, так уже пробовал:

{ОбщаяФорма.ПУРУМ_НесохраненныеОбъекты.Форма(37)}: Ошибка при вызове метода контекста (КопироватьДанныеФормы)

КопированиеВыполнено = КопироватьДанныеФормы(ВосстановленныйОбъект, Фрм.Объект);

по причине:

Несоответствие типов (параметр номер ‘1’)

Тут должен быть не ДокументОбъект, а ДанныеФормыСтруктураСКоллекцией; ДанныеФормыКоллекция; ДанныеФормыСтруктура

Но все равно спасибо за участие. Посмотрю версионирование в БСП (но там-то все в контексте формы объекта) — может, натолкнет на какую мысль…

Reply ↓
gvk2009 25.10.2013 at 13:01

(13) AVK_Alex, а какой тип данных у ВосстановленныйОбъект?

Делаете ли в процедуре ВосстановитьОбъектНаСервере() перед передачей на Клиента преобразование объекта с помощью

ЗначениеВДанныеФормы?

Reply ↓
eeeio 25.10.2013 at 14:17

Вызов процедуры &НаСервереБезКонтекста

Обработать(КакаятоТаблицаФормы)…

вываливается с ошибкой.

Нормально отрабатывается вот так: Обработать(ЗНАЧ КакаятоТаблицаФормы)

Reply ↓

AVK_Alex 25.10.2013 at 14:49

(14) gvk2009, тип данных ДокументОбъект

Код теперь выглядит так:

&НаКлиенте
Процедура ВосстановитьОбъект (СсылкаНаОбъект, ИмяФормы)
ВосстановленныйОбъект = ВосстановитьОбъектНаСервере (СсылкаНаОбъект);
Фрм = ПолучитьФорму(ИмяФормы);
ЗначениеВРеквизитФормыНаСервере(ВосстановленныйОбъект, Фрм.Объект);
Фрм.Открыть();
КонецПроцедуры

&НаСервере
Процедура ЗначениеВРеквизитФормыНаСервере (ВосстановленныйОбъект, ФормаОбъект)
ЗначениеВДанныеФормы(ВосстановленныйОбъект, ФормаОбъект);
КонецПроцедуры //Прикольно, сюда дохожу отладчиком. Дальше F10 и ошибка

Показать

{ОбщаяФорма.ПУРУМ_НесохраненныеОбъекты.Форма(37)}: Ошибка при установке значения атрибута контекста (Объект)

ЗначениеВРеквизитФормыНаСервере(ВосстановленныйОбъект, Фрм.Объект);

по причине:

Нельзя изменять поле, содержащее объект данных формы

Reply ↓

AVK_Alex 25.10.2013 at 14:52

(15) eeeio, возможно, не совсем понимаю — а разве в форме после этого что-то поменяется?

Reply ↓
eeeio 25.10.2013 at 16:07

(17) это я в ответ на (0)

Reply ↓
AVK_Alex 25.10.2013 at 17:23

(18) eeeio, понятно 🙂

Reply ↓

gvk2009 26.10.2013 at 18:46

(16) AVK_Alex, вот код для примера. Я создала внешнюю обработку с реквизитом ДокСсылка (тип — ДокументСсылка).

&НаКлиенте
Процедура ОткрытьДокумент(Команда)

Фрм = ПолучитьФорму(«Документ.РеализацияТоваровИУслуг.Форма.ФормаДокумента»);
ФрмОбъект = Фрм.Объект;

ЗаполнитьНаСервереБезКонтекста(ФрмОбъект, ДокСсылка);

КопироватьДанныеФормы(ФрмОбъект,Фрм.Объект);
Фрм.Открыть();

КонецПроцедуры

&НаСервереБезКонтекста
Процедура ЗаполнитьНаСервереБезКонтекста(ФрмОбъект, ДокСсылка)

ВосстановленныйОбъект = ДокСсылка.ПолучитьОбъект();
ЗначениеВДанныеФормы(ВосстановленныйОбъект, ФрмОбъект);

КонецПроцедуры // НаСервереБезКонтекста()

Показать

Reply ↓

AVK_Alex 28.10.2013 at 10:13

(20) gvk2009, Спасибо!

Вот так все работает (только надо имя формы поправить):

&НаКлиенте
Процедура ВосстановитьОбъект (СсылкаНаОбъект)
ВосстановленныйОбъект = ВосстановитьОбъектНаСервере (СсылкаНаОбъект);
Фрм = ПолучитьФорму(ИмяФормы);
ФрмОбъект = Фрм.Объект;
ЗаполнитьНаСервереБезКонтекста(ФрмОбъект, ВосстановленныйОбъект);
КопироватьДанныеФормы(ФрмОбъект,Фрм.Объект);
Фрм.Открыть();
КонецПроцедуры

&НаСервереБезКонтекста
Процедура ЗаполнитьНаСервереБезКонтекста(ФрмОбъект, ВосстановленныйОбъект)
ЗначениеВДанныеФормы(ВосстановленныйОбъект, ФрмОбъект);
КонецПроцедуры // ЗаполнитьНаСервереБезКонтекста()

Показать

Reply ↓

sss999 19.09.2014 at 12:15

(20) gvk2009, че то мне вообще этот код не понравился,как то он не соответствует концепции разделения на сервер и клиент,например как это можно получать объект на клиенте а потом передавать его через параметр,все должно на сервере получаться имхо

Reply ↓
gvk2009 23.09.2014 at 13:21

(22) sss999, если получать объект на сервере по ссылке (реквизит формы Объект.Ссылка), то для этого потребуется контекст формы — это как раз случай использования «РеквизитФормыВЗначение()». А в том коде, на который ссылаетесь вы, контекст формы не используется. С Клиента на Сервер передается форма документа и документ со всеми своими реквизитами, помещенный в переменную. Но его тип — не ДокументОбъект! Именно поэтому его можно использовать на Клиенте. Если обратиться с справке 1С, то читаем:»Важно заметить, что для типов прикладных объектов (таких, как СправочникОбъект, например) форма будет реально использовать не прикладные, а специализированные типы данных, состав которых будет автоматически наполняться из указанных типов».

Предпочтительнее использовать компиляцию НаСервереБезКонтекста, потому что в этом случае объем передаваемых данных между Клиентом и Сервером значительно меньше.

Reply ↓
user_2010 10.04.2015 at 12:11

Спасибо — статья полезна!

Решаю такую задачу: на форму программно добавлен реквизит и его элемент.

Почему функция РеквизитФормыВЗначение не видит мой реквизит/элемент?

Reply ↓
arancar 01.07.2015 at 14:39

Тема годная, только мне больше интересно насколько такие вызовы по переупаковке данных из одного типа в другой трудозатратны по времени исполнения?

Стоит ли при наличии двух форм документа (управляемой и обычной) помещать методы вида ПриИзмененииДоговора в модуль объекта и в управляемой форме шаманить во всех удобных и неудобных местах ДанныеФормыВЗначение -> ЗначениеВДанныеФормы? Или лучше продублировать тот де самый код в разных формах или придумать что-то более интересное?

Reply ↓
Afa_fil 14.10.2015 at 17:59

Спасибо, полезная статья.

Я пыталась таким же образом преобразовывать не сам Объект формы, а его реквизиты.

Если у реквизита тип динамический список, то ни одна из этих процедур не срабатывает.

Если у реквизита тип таблица значений, то все хорошо получается.

Reply ↓
progr-2008 18.09.2016 at 23:01

Полезная статья.

Reply ↓
userGJ 26.10.2016 at 17:20

Спасибо за статью, очень помогла.

Reply ↓
pavel_pss 16.12.2016 at 17:51
Всем привет. Помогите. При работе в тонком клиенте.

Есть обработка, на ней табличная часть и ТЧ. реквизит Док.ПоступлениеТовУслуг.

по кнопке наформе:
```
&НаКлиенте
Процедура ВыполнитьЗагрузку(Команда)

Сообщить(«Выполняется загрузка документов, подождите …», СтатусСообщения.Внимание);
ВыполнитьЗагрузкуНаСервере(Элементы.Страницы.ТекущаяСтраница.Имя);
Сообщить(«Загрузка документов, выполнена», СтатусСообщения.Информация);

КонецПроцедуры

&НаСервере
Процедура ВыполнитьЗагрузкуНаСервере(ИмяСтраницы)
ФРМ = РеквизитФормыВЗначение(«Объект»);

Если ИмяСтраницы = «ГруппаВыборТЧ» Тогда

ФРМ.ЗагрузитьПТУ();
КонецЕсли;

ЗначениеВРеквизитФормы(ФРМ,»Объект»);
```
Показать
процедура ЗагрузитьПТУ — объявленна в модуле объекта.

Там идет загрузка внешних данных и создание нового или изменение существующего документа ПоступлениеТоваровУслуг.

Вопрос, если новый док, то все нормально, но если док уже есть и у него например меняется дата и док. записывается док. То пока я на сервере то дата встает правильная,

но когда возвращается в Процедура ВыполнитьЗагрузку(Команда), то в колонке ТЧ, дата остается старая.

Подскажите в чем мой косяк.

Лучше куском кода. Спасибо.

В толстом клиенте такой проблемы нет.

Reply ↓

CratosX 10.07.2017 at 13:35

(21) в процедуре ЗаполнитьНаСервереБезКонтекста заполняшка данных неочевидна

&НаСервереБезКонтекста
Процедура ЗаполнитьНаСервереБезКонтекста(ФрмОбъект, ВосстановленныйОбъект)
ЗначениеВДанныеФормы(ВосстановленныйОбъект, ФрмОбъект);
//   тут куски кода заполнения данных
КонецПроцедуры // ЗаполнитьНаСервереБезКонтекста()

Или пример кода с контекстным вызовом (работает на клиент-сервере, тонкий клиент):

&НаКлиенте
Процедура ОткрытьФормуНового(Команда)

Форма = ПолучитьФорму(«Документ.ПродажаТоваровУслуг.Форма.ФормаДокумента»);
ДанныеФормы = Форма.Объект;

ЗаполнитьНаСервере(ДанныеФормы);

КопироватьДанныеФормы(ДанныеФормы, Форма.Объект);
Форма.Открыть();

КонецПроцедуры

&НаСервере
Процедура ЗаполнитьНаСервере(НовыйОбъект)

НовыйОбъект.Контрагент = Справочники.Контрагенты.НайтиПоКоду(«000000005»);

КонецПроцедуры

Показать

Reply ↓

m_aster 02.12.2017 at 19:39

Спасибо.

Reply ↓
RailMen 09.02.2018 at 09:36

(11) писать в регистр , а потом удалять записи — дичь. Сделай реквизит формы АдресВХранилище и всю структуру данных формы сохраняй во временное хранилище.

Reply ↓
ybatiaev 09.04.2018 at 18:57

Если рассуждать с точки зрения здравого смысла… есть некая таблица на форме, то зачем мне надо что-то куда то преобразовывать? Могу я в цикле обработать всю ДанныеФормыКолекция? Могу! Для удобства могу вывести и ползунок. Это по нормальной логике.

Далее я таки в цикле перебираю друг-за-другом документы из коллекции, делаю что-то на сервере, возвращаю что-то на клиент, как вариант булевый РЕЗУЛЬТАТ, и вставляю его в поле коллекции. Часть вставляется, часть не вставляется.

Пришедшему с нормальных языков программирования тяжело к подобным «находкам» привыкнуть. Жесть, короче!!!

Никогда не понимал идею проводить пустые действия …

Reply ↓
vlasenko_me 15.02.2019 at 15:01

У АВТОРА ЕСТЬ КОД:

&НаСервереБезКонтекста

Процедура ВыполнитьНаСервереБезКонтекста(ОснРеквизит)

ОбъектЗначение = ДанныеФормыВЗначение(ОснРеквизит, Тип(«ДокументОбъект.АктСверкиВзаиморасчетов»));

//…Выполнение операций с Объектом «ОбъектЗначение»

ЗначениеВДанныеФормы(ОбъектЗначение, ОснРеквизит);

КонецПроцедуры

НО:

ОснРеквизит да и вообще любой если передать в &НаСервереБезКонтекста то в результате будет » Ошибка при установке значения атрибута контекста (ОснРеквизит)

по причине:

Нельзя изменять поле, содержащее объект данных формы

Reply ↓
gvk2009 04.04.2019 at 13:01

(34) Ваша ошибка, скорее всего, в том, что вы передаёте на сервер САМ ОБЪЕКТ. А надо объект сохранять в переменную и передавать на сервер эту переменную:

ОснРеквизит = Объект;

ВыполнитьНаСервереБезКонтекста(ОснРеквизит);

Reply ↓
newvideo 26.04.2019 at 16:33

(35) А в чем будет разница если мы передаем Объект на СерверБезКонтекста и в случае если мы будем использовать просто НаСервере(с контекстом)?

Reply ↓
user900973 13.06.2019 at 10:29

Добрый день! Помогите, плиз, новичку. Есть элемент справочника, на форме в качестве реквизита формы есть таблица. Есть регламент, методы исполняются на сервере. Подбираются измененные элементы из плана обмена, данные необходимо передать по АПИ. Не могу добраться из сервера к таблице, которая на форме. http://joxi.ru/823BZZjT9gWGRm

Reply ↓
dreamcreal 30.06.2019 at 14:18

Вот этот кусок статьи не очень читабельный. Я его отформатировала…

«Где и когда его нужно использовать?

Метод РеквизитФормыВЗначение() необходим, если требуется из модуля формы вызвать стандартный метод объекта или метод (процедуру, функцию) из модуля объекта, из общего модуля.

Этот метод будет отрабатывать с данными, взятыми из формы, т.е. еще не записанными в базу.

Для того, чтобы затем измененные данные вернуть на форму, используется метод ЗначениеВРеквизитФормы().»

—>

Где и когда его нужно использовать?

Метод РеквизитФормыВЗначение() необходим, если требуется из модуля формы вызвать стандартный метод объекта или метод/процедуру/функцию из модуля объекта или из общего модуля.

Этот метод будет отрабатывать с данными, взятыми из формы (т.е. еще не записанными в базу).

Для того, чтобы затем измененные данные вернуть на форму, используется метод ЗначениеВРеквизитФормы().

Reply ↓
acanta 30.06.2019 at 14:23

(38) Круто. И почему это не пишут в синтакс помощнике?

Reply ↓
dreamcreal 30.06.2019 at 14:28

(39) Я вообще не понимала что эти два метода делают.

Иногда их встречала.

Вот решила поинтересоваться ими.

Кстати, что в СП о них пишут, не видела….

Reply ↓

РеквизитФормыВЗначение () и ДанныеФормыВзначение (). Описание и примеры использования.

Related Posts

40 Comments

Leave a Comment Отменить ответ