Консоль запросов для управляемых форм 8.3

Универсальная внешняя обработка (СДРКонсольЗапросовХ) для создания, редактирования и отладки запросов, с возможностью обработки таблицы результатов произвольными алгоритмами на языке 1С. Выгрузка результатов запроса в таблицу или дерево значений, включая временные таблицы и запросы пакета. Формирование запроса для консоли в отладчике, включая временные таблицы и параметры. Версия 1.1.0.41 от 26.11.2024

СДРКонсольЗапросовХ – инструмент для программиста, позволяющий создавать и отлаживать запросы для баз 1С 8.3, а также обрабатывать результаты запросов (тонкий, толстый, web клиент). Не зависит от конкретной конфигурации, никаких БСП.

Продолжаю публикацию своих инструментов для разработки и отладки СДР (средства для разработчика, первая публикация: Навигатор по конфигурации базы 1С 8.3 ).

В плане интерфейса использована классическая схема: дерево запросов, запрос и результаты запроса.

Особенности

Работает с современными конфигурациями 1С (с запретом на использование модальности и синхронных вызовов)
Заточена на интерфейс «Такси» — мало место для работы по сравнению с неуправляемыми формами (поэтому экономим место: можно погасить дерево запросов, результаты запроса и вообще ничего лишнего стараемся не показывать)
Оптимизирован обмен данными между клиентом и сервером
Не содержит избыточного функционала, редко используемого в практической работе
Для всех форм обработки установлен вариант масштаба "Компактный". Если кому то это не нравится и хочется использовать платформенную кнопку "Изменить масштаб", то надо в конфигураторе для всех форм обработки установить вариант масштаба "Авто".

Работа с деревом запросов

Запросы хранятся в виде дерева (как обычно)
Можно сохранить или загрузить все дерево запросов (в файл или из файла)
Можно сохранить отдельную веточку запросов в файл
Можно подгрузить в отдельную ветку запросов запросы из файла
Можно копировать запросы (вместе с параметрами) или перетаскивать их в другие ветки дерева

Работа с текстом запроса

Поддержка пакета запросов
Можно выполнить весь пакет, либо только выделенную часть пакета
В поля выборки можно вставить специальное поле, чтобы вместо ссылки выводился GUID
В пакет запроса можно вставить специальный разделитель, чтобы выполнение пакета остановилось на этом месте
Выделенную часть запроса можно закомментировать, раскомментировать или преобразовать в строку для вставки в код скрипта 1С

Параметры запроса

В параметрах запроса кроме стандартных, может быть таблица значений, граница, момент времени, уникальный идентификатор
В параметре можно указать битую ссылку (ссылку не несуществующий объект)
В качестве параметру можно указать выражение на языке 1С, которое будет вычисляться перед выполнением запроса
Можно скопировать выбранные параметры из одного запроса в другой
Можно редактировать таблицу значений, являющуюся параметром запроса

Результаты запроса

Результаты запроса оформляются в виде таблицы значений
Временные таблицы пакета запроса также оформляются в виде таблицы значений (по желанию)
Кликнув мышкой по ячейки результирующей таблицы значений можно открыть значение в стандартной форме (если там находится ссылка на объект)
Можно открыть значение ячейки таблицы в специальной форме, предоставляющей доступ ко всем реквизитам объекта (Редактор объектов информационной базы 8.3 – встроен в консоль запросов). Как самостоятельно встроить более новую версию "Редактора объектов" описано здесь.
В специальной форме можно открыть не только ссылочный объект, но и хранилище значения (поддерживаются массив, список значений, структура, соответствие, таблица значений, табличный и текстовый документ)
Можно загрузить таблицу результатов запроса в параметр запроса либо сохранить в файл
Можно выгрузить ссылочные объекты из произвольной колонки результатов запроса в файл в формате XML (для последующей загрузки в базу)

Сохранение запросов из отладчика

Есть возможность остановиться в отладчике и сохранить запрос с параметрами и временными таблицами в файл, который затем можно подгрузить в консоль для отладки.
Есть возможность остановиться в отладчике и сформировать XML-представление запроса с параметрами и временными таблицами, из которго в консоли можно сформировать запрос для отладки (передается через буфер обмена без использования промежуточных файлов)
Функция общего модуля для сохранения запроса из отладчика прилагается, пример вызова: омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос, "D:1Cv8Запросы00") или омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос) — формирует XML-представление запроса
В функцию сохранения запроса в качестве первого параметра можно передать Запрос или МакетКомпоновкиДанных

Функция для перехвата запроса из отладчика (актуальный текст функции приведен на закладке "Настройки" обработки)

// ---------------------------------------------------------------------
// ФУНКЦИЯ ДЛЯ ОТЛАДКИ ЗАПРОСОВ (для использования в отладчике Shift-F9)
// ---------------------------------------------------------------------

// Назначение: сохраняет объект запрос в файл или формирует XML-представление запроса для последующей отладки в консоли запросов
// Версия: 1.1.0.41 от 18.11.2024
// Параметры:
// ЗапросИлиМакетКомпоновки - объект типа Запрос или МакетКомпоновкиДанных, для которого надо сохранить описание
// ИмяФайла - имя файла, куда будет сохранено описание запроса (можно без расширения)
//            этот файл затем можно подгрузить в расширенную консоль запросов
//     ВАЖНО: если ИмяФайла равно Неопределено, то функция возвращает XML-представление запроса, которое можно через буфер обмена передать в консоль запросов
// ВключатьВременныеТаблицы - если истина, то сохраняются временные таблицы из менеджера временных таблиц
// МаксЧислоЗаписей - максимальное число записей, выгружаемых из каждой временной таблицы, при значении -1 выгружаются ВСЕ записи
// ПреобразовыватьНеТипизированныеКолонки - лучше оставить значение истина
//
// Пример вызова:
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос, "D:1Cv8Запросы00") - сохраняет запрос в файл (НА СЕРВЕРЕ)
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос) - возвращает XML-представление запроса
//    _омОтладка.СохранитьЗапросДляСДРКонсолиХ(Запрос,,,200) - возвращает XML-представление запроса (выгружаются не больше 200 записей из каждой временной таблицы)
// Замечания:
// - ВАЖНО: функцию надо вызывать ДО ВЫПОЛНЕНИЯ запроса
// - в управляемом режиме выполняется на сервере, соответственно обращайте внимание на имя файла

Функция СохранитьЗапросДляСДРКонсолиХ(Знач ЗапросИлиМакетКомпоновки, Знач ИмяФайла = Неопределено, Знач ВключатьВременныеТаблицы = истина, Знач МаксЧислоЗаписей = 10000, Знач ПреобразовыватьНеТипизированныеКолонки = истина, Знач СжиматьПараметрыXML = истина) Экспорт
Если ТипЗнч(ЗапросИлиМакетКомпоновки) = Тип("МакетКомпоновкиДанных") Тогда
ВключатьВременныеТаблицы = ложь;

Запрос = новый Запрос(ЗапросИлиМакетКомпоновки.НаборыДанных.Получить(0).Запрос);
Для каждого Элем из ЗапросИлиМакетКомпоновки.ЗначенияПараметров Цикл
Запрос.Параметры.Вставить(Элем.Имя, Элем.Значение);
КонецЦикла;
ИначеЕсли ЗапросИлиМакетКомпоновки = Неопределено Тогда
Запрос = новый Запрос;
Иначе
Запрос = ЗапросИлиМакетКомпоновки;
КонецЕсли;

СтрукЗапрос = новый Структура;
СтрукЗапрос.Вставить("Формат", "СДРКонсольЗапросовХ");
СтрукЗапрос.Вставить("Версия", 1);
СтрукЗапрос.Вставить("Назначение", "Запросы");
СтрукЗапрос.Вставить("Элементы", новый Массив);

СтрукЭлемент = новый Структура;
СтрукЭлемент.Вставить("Дети", новый Массив);
СтрукЭлемент.Вставить("Имя", "Запрос");
СтрукЭлемент.Вставить("Текст", Запрос.Текст);
СтрукЭлемент.Вставить("СпособВыгрузки", 0);
СтрукЭлемент.Вставить("Параметры", новый Массив);

Если ВключатьВременныеТаблицы и Запрос.МенеджерВременныхТаблиц <> Неопределено и Запрос.МенеджерВременныхТаблиц.Таблицы <> Неопределено и Запрос.МенеджерВременныхТаблиц.Таблицы.Количество() <> 0 Тогда
Если МаксЧислоЗаписей >= 0 Тогда
пЗапрос = новый Запрос;
пЗапрос.МенеджерВременныхТаблиц = Запрос.МенеджерВременныхТаблиц;
пШаблонЗапроса =
"ВЫБРАТЬ" + ?(МаксЧислоЗаписей = -1, "", " ПЕРВЫЕ " + Формат(МаксЧислоЗаписей, "ЧРГ=0;ЧН=;")) + "
| т.*
|ИЗ
| %1 КАК т
|";
КонецЕсли;

ТекстЗапроса = "";
Для каждого Элем из Запрос.МенеджерВременныхТаблиц.Таблицы Цикл

Если МаксЧислоЗаписей < 0 Тогда
ТабРезультат = Элем.ПолучитьДанные().Выгрузить();

Иначе
пЗапрос.Текст = СтрЗаменить(пШаблонЗапроса, "%1", Элем.ПолноеИмя);
ТабРезультат = пЗапрос.Выполнить().Выгрузить();
КонецЕсли;

ТекстЗапроса = ТекстЗапроса + "ВЫБРАТЬ";
СтрукКолонки = новый Структура;
Для каждого Кол из ТабРезультат.Колонки Цикл
Если ПреобразовыватьНеТипизированныеКолонки и Кол.ТипЗначения.Типы().Количество() = 0 Тогда
СтрукКолонки.Вставить(Кол.Имя); // не типизированная колонка
КонецЕсли;
ТекстЗапроса = ТекстЗапроса + "
| " + ?(ТабРезультат.Колонки.Индекс(Кол) = 0, "", ",") + "ТабДанные." + Кол.Имя;
КонецЦикла;
ТекстЗапроса = ТекстЗапроса + "
|ПОМЕСТИТЬ " + Элем.ПолноеИмя + "
|ИЗ
| &__мвт__" + Элем.ПолноеИмя + " КАК ТабДанные
|;
|
|";

ТипНеопределено = новый ОписаниеТипов("Число, Дата");
Для каждого Кол из СтрукКолонки Цикл
ТабРезультат.Колонки.Удалить(Кол.Ключ);
ТабРезультат.Колонки.Добавить(Кол.Ключ, ТипНеопределено);
КонецЦикла;

СтрукПараметр = новый Структура;
СтрукПараметр.Вставить("Имя", "__мвт__" + Элем.ПолноеИмя);
СтрукПараметр.Вставить("ЭтоСпецЗначение", истина);
СтрукПараметр.Вставить("Значение", "ТаблицаЗначений");
СтрукПараметр.Вставить("ТипЗначения", "ТаблицаЗначений");
СтрукПараметр.Вставить("СпецЗначение", ЗначениеВСтрокуВнутр(ТабРезультат));

СтрукЭлемент.Параметры.Добавить(СтрукПараметр);
КонецЦикла;

ТекстЗапроса = ТекстЗапроса + Запрос.Текст;
СтрукЭлемент.Текст = ТекстЗапроса;
КонецЕсли;

// ВАЖНО: алгоритм формирования параметров должен быть идентичен (метка:001)
ПараметрыЗапроса = Запрос.Параметры;
Для каждого Элем из ПараметрыЗапроса Цикл
СтрукПараметр = новый Структура;
СтрукПараметр.Вставить("Имя", Элем.Ключ);
СтрукПараметр.Вставить("Значение", Элем.Значение);
СтрукПараметр.Вставить("ЭтоСпецЗначение", ложь);
СтрукПараметр.Вставить("СпецЗначение", "");
СтрукПараметр.Вставить("ТипЗначения", "");

Если ТипЗнч(Элем.Значение) = Тип("Массив") Тогда
Список = новый СписокЗначений;
Список.ЗагрузитьЗначения(Элем.Значение);
СтрукПараметр.Значение = Список;

ИначеЕсли ТипЗнч(Элем.Значение) = Тип("ФиксированныйМассив") Тогда
Список = новый СписокЗначений;
Список.ЗагрузитьЗначения(новый Массив(Элем.Значение));
СтрукПараметр.Значение = Список;

ИначеЕсли ТипЗнч(Элем.Значение) = Тип("Граница") Тогда
СтрукПараметр.ЭтоСпецЗначение = истина;
СтрукПараметр.Значение = "Граница";
СтрукПараметр.ТипЗначения = "Граница";
СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);

ИначеЕсли ТипЗнч(Элем.Значение) = Тип("ТаблицаЗначений") Тогда
СтрукПараметр.ЭтоСпецЗначение = истина;
СтрукПараметр.Значение = "ТаблицаЗначений";
СтрукПараметр.ТипЗначения = "ТаблицаЗначений";
СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);

ИначеЕсли ТипЗнч(Элем.Значение) = Тип("МоментВремени") Тогда
СтрукПараметр.ЭтоСпецЗначение = истина;
СтрукПараметр.Значение = "МоментВремени";
СтрукПараметр.ТипЗначения = "МоментВремени";
СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);

ИначеЕсли ТипЗнч(Элем.Значение) = Тип("УникальныйИдентификатор") Тогда
СтрукПараметр.ЭтоСпецЗначение = истина;
СтрукПараметр.Значение = Строка(Элем.Значение);
СтрукПараметр.ТипЗначения = "УникальныйИдентификатор";
СтрукПараметр.СпецЗначение = ЗначениеВСтрокуВнутр(Элем.Значение);
КонецЕсли;

СтрукЭлемент.Параметры.Добавить(СтрукПараметр);
КонецЦикла;

СтрукЗапрос.Элементы.Добавить(СтрукЭлемент);

// преобразование запроса в строку XML
Если ИмяФайла = Неопределено Тогда
Попытка
СтрукЗапросXML = новый Структура;
СтрукЗапросXML.Вставить("СжиматьПараметрыXML", СжиматьПараметрыXML);
СтрукЗапросXML.Вставить("Текст", СтрукЭлемент.Текст);

СтрукЗапросXML.Вставить("Параметры", новый Структура);
Для каждого Элем из СтрукЭлемент.Параметры Цикл
ИмяПараметра = Элем.Имя;
Если Элем.ЭтоСпецЗначение Тогда
Если СжиматьПараметрыXML Тогда
ЗначениеПараметра = ЗначениеИзСтрокиВнутр(Элем.СпецЗначение);
Если ТипЗнч(ЗначениеПараметра) = Тип("ТаблицаЗначений") Тогда
ЗначениеПараметра = новый ХранилищеЗначения(ЗначениеПараметра, новый  СжатиеДанных(9));
КонецЕсли;
Иначе
ЗначениеПараметра = ЗначениеИзСтрокиВнутр(Элем.СпецЗначение);
КонецЕсли;
Иначе
ЗначениеПараметра = Элем.Значение;
КонецЕсли;
СтрукЗапросXML.Параметры.Вставить(ИмяПараметра, ЗначениеПараметра);
КонецЦикла;

ЗаписьXML = новый ЗаписьXML;
ЗаписьXML.УстановитьСтроку();
СериализаторXDTO.ЗаписатьXML(ЗаписьXML, СтрукЗапросXML, НазначениеТипаXML.Явное);

Возврат ЗаписьXML.Закрыть();
Исключение
Возврат ОписаниеОшибки();
КонецПопытки;
КонецЕсли;

СтрокаДанных = ЗначениеВСтрокуВнутр(СтрукЗапрос);

ТДок = новый ТекстовыйДокумент;
ТДок.УстановитьТекст(СтрокаДанных);

Если Найти(ИмяФайла, ".") = 0 Тогда
ИмяФайла = ИмяФайла + ".dat";
КонецЕсли;

Попытка
ТДок.Записать(ИмяФайла);
Возврат "Ок";
Исключение
Возврат ОписаниеОшибки();
КонецПопытки;

КонецФункции

Для обработки результатов запроса есть закладка «Алгоритмы»

в Web клиенте выполнить алгоритм можно только на стороне сервера
Алгоритм – это код на языке 1С
Алгоритмы хранятся в виде дерева, функционал аналогичен дереву запросов
Алгоритмы могут выполнятся как на стороне сервера, так и на стороне клиента; имеют доступ к результатам запроса, можно указать дополнительные параметры (число, дата, ссылка и т.д.)
В консоль встроены примеры реализации алгоритмов на стороне сервера и клиента. В примере для клиента обратите внимание на строки «//— Сервер:старт» и «//— Сервер:финиш» — код между этими строками будет выполняться на сервере.

Некоторые примеры скриншотов

Основное окно консоли запросов

Закладка "Настройки"

Закладка "Параметры запроса"

Вывод уникального идентификатора объекта в результатах запроса

Иллюстрация команды "Открыть объект…" в результатах запроса

Выгрузка ссылочных объектов из колонки результатов запроса в XML

Просмотр временных таблиц и запросов пакета

Выгрузка результатов в дерево значений

Перехват запроса в отладчике

Обработка результатов запроса произвольным алгоритмом

Тестирование

Платформа (8.3.11.2867, 8.3.13.1513, 8.3.15.1489), на платформах ниже 8.3.8 работать не будет
Управление холдингом, редакция 3.0 (3.0.4.4)
1С:ERP Управление предприятием 2 (2.4.10.56)

Это инструмент для программистов и продвинутых пользователей (я использую постоянно).

Версия 1.1.0.29 от 04.03.2024

Версия 1.1.0.31 от 31.03.2024

Версия 1.1.0.33 от 21.04.2024

Версия 1.1.0.35 от 15.08.2024

Версия 1.1.0.37 от 27.08.2024

Версия 1.1.0.39 от 14.10.2024

Версия 1.1.0.41 от 26.11.2024

обновлена специальная форма объекта (Редактор объектов информационной базы 8.3), предоставляющей доступ ко всем реквизитам объектов и движениям документов
доработан функционал для работы с параметрами запроса
добавлен новый тип параметра "Выражение" (с помощью него можно задать любое значение параметра)
добавлена возможность использования битой ссылки (ссылка на удаленный объект) в качестве параметра запроса
добавлен новый способ вывода результатов пакета — "Таблица значений + размеры временных таблиц"
добавлена возможность задать ограничение на максимальное число строк при выводе временных таблиц
доработана функция для сохранения запроса из отладчика: СохранитьЗапросДляСДРКонсолиХ

7 Comments

Perk0n 08.11.2018 at 10:57

Спасибо.

В 1С:Документооборот и БП 3.0 работает.

В ЗУПе 3.1 не работает.

Платформа: 1С:Предприятие 8.3 (8.3.13.1513)

Конфигурация: Зарплата и управление персоналом, редакция 3.1 (3.1.7.144) (http://v8.1c.ru/hrm/)

Copyright © ООО «1C-Софт», 2007-2018. Все права защищены

(http://www.1c.ru)

Режим: Серверный (сжатие: усиленное)

Приложение: Тонкий клиент

Локализация: Информационная база: русский (Россия), Сеанс: русский

Вариант интерфейса: Такси

Ошибки:

———————————————————————————

08.11.2018 14:44:53

{(1, 1)}: Ожидается выражение «ВЫБРАТЬ»

При начале работы с интерактивам конструктором запросов ЗУПе. Например при раскрытии справочников.

Штука классная. Надеюсь поправите для ЗУПа.

Reply ↓
Evg-Lylyk 08.11.2018 at 11:17

Посмотрите другой подобный инструмент https://infostart.ru/public/835718/

Reply ↓
ROL32 08.11.2018 at 11:48

Спасибо.

По поводу ЗУПа — для открытия конструктора используется платформенный вызов, поэтому поправить что либо проблематично.

Думаю, что ошибка вызвана или ошибкой платформы (наблюдал для ERP под 8.3.12.1685), или подпорченной струтурой хранения самой базы (проверить можно на новой пустой или демонстрационной базе ЗУП)

Reply ↓
ROL32 08.11.2018 at 11:52

Обязательно

Reply ↓
ROL32 05.02.2019 at 13:45

Странно, что так мало комментариев.

Похоже, что у тех, кто скачал все работает и их все устраивает.

А может наоборот посмотрели и сразу удалили.

Reply ↓
vova-1c 30.03.2019 at 11:43

Не подключается

Конфигурация

Reply ↓
vova-1c 30.03.2019 at 11:43

ошибка

Reply ↓

Консоль запросов для управляемых форм 8.3

Related Posts

7 Comments

Leave a Comment Отменить ответ