Свертка номенклатуры при выгрузке из Управления Торговлей 11 в Бухгалтерию 3.0

При выгрузке из Управления Торговлей 11 в Бухгалтерию с товарами обычно поступают так:

• либо выгружают все позиции типовым обменом
• либо заменяют все позиции одним названием "Товар" и перебивают документы вручную

С учетом, того, что позициями товаров в УТ 11 часто наблюдается некоторый бардак и пересортица, при выгрузке документов в Бухгалтерию возникают ошибки проведения по бухгалтерским регистрам. Поэтому бухгалтера и используют иногда второй подход.

Если уменьшить количество позиций номенклатуры, то ошибок станет меньше, и объем работы по проведению документов в Бухгалтерии уменьшится. Можно например каталог из 20 тыс. позиций заменить списком в 500 позиций.

Сам принцип свертки лучше придумать исходя из конкретных товаров. Например, взять название группы иерархии в качестве "свернутой" позиции (например, все дрели у нас лежат в папке "дрели", и им присвоить название для бухгалтерии "дрель"). Такие "свернутые" позиции товаров мы тоже создаем в справочнике номенклатуры — под отдельным видом, чтобы не смешивались с основной номенклатурой. И создаем доп. реквизит (название "Товар для Бухгалтерии") у всех товаров, в котором будет храниться ссылка на "свернутую" номенклатуру.

Далее нам нужно добиться, чтобы типовой обмен Управление Торговлей 11 — Бухгалтерия 3 выгружал не исходный товар во всех документах движения, а соответствующую позицию "свернутого" товара. Для этого мы будем дорабатывать типовые правила обмена (универсальный обмен в формате EnterpriseData).

Сначала необходимо выгрузить типовые правила обмена из 1С Управление Торговлей 11, и загрузить в Конвертацию 3. Как это сделать, очень подробно описано тут Конвертация данных 3. Инструкции и примеры

Переходим к доработке правил обмена. Прежде всего нам потребуются некоторые "служебные" параметры, которые мы будем использовать в наших алгоритмах конвертации. Эти параметры мы поместим в специальную структуру — параметры конвертации.

Эта структура создается вот в этом алгоритме:

В алгоритме ПередКонвертациейУТКАУП добавляем наши параметры:

//EComIntegrator
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ДополнительныеРеквизитыИСведения.Ссылка
|ИЗ
| ПланВидовХарактеристик.ДополнительныеРеквизитыИСведения КАК ДополнительныеРеквизитыИСведения
|ГДЕ
| ДополнительныеРеквизитыИСведения.Заголовок = ""Номенклатура для Бухгалтерии""
| И ДополнительныеРеквизитыИСведения.НаборСвойств = ЗНАЧЕНИЕ(Справочник.НаборыДополнительныхРеквизитовИСведений.Справочник_Номенклатура_Общие)"
;
Выборка = Запрос.Выполнить().Выбрать();
Выборка.Следующий();
ПараметрыКонвертации.СвойствоНоменклатураДляБухгалтерии = Выборка.Ссылка;

ПараметрыКонвертации.ВидНоменклатурыДляБухгалтерии = Справочники.ВидыНоменклатуры.НайтиПоНаименованию("Товар для Бухгалтерии");
ПараметрыКонвертации.ВидНоменклатурыТовар = Справочники.ВидыНоменклатуры.НайтиПоНаименованию("Товар");
ПараметрыКонвертации.ВидНоменклатурыУслуги = Справочники.ВидыНоменклатуры.НайтиПоНаименованию("Услуга");

Всю нашу "бухгалтерскую" номенклатуру мы поместим в отдельную папку "Номенклатура для Бухгалтерии", чтобы в Бухгалтерию не выгружалась вся иерархическая структура каталога. И на выгрузку наложим фильтр в правило "Справочник_Номенклатура_Отправка" в обработчик "При обработке":

Если ДанныеИБ.ЭтоГруппа Тогда

ИспользованиеПКО.Справочник_НоменклатураГруппа = ?(ДанныеИБ.Наименование = "Номенклатура для Бухгалтерии", Истина, Ложь);

КонецЕсли;

Меняем обработчик "При отправке" в ПКО Справочник Номенклатура. Все, что есть в типовом обработчике, убираем (в вашей конкретной ситуации смотрите на этот вопрос осознанно — посмотрите, что там делается). Новый текст обработчика, в котором мы производим замену исходной номенклатуры на "свернутую":

//EComIntegrator
Если ДанныеИБ.ВидНоменклатуры = КомпонентыОбмена.ПараметрыКонвертации.ВидНоменклатурыТовар Тогда

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| Номенклатура.Ссылка,
| Номенклатура.Родитель как Группа,
| Номенклатура.Код как КодВПрограмме,
| Номенклатура.Наименование,
| Номенклатура.Артикул,
| Номенклатура.ЕдиницаИзмерения,
| Номенклатура.НаименованиеПолное,
| Номенклатура.СтавкаНДС,
| Номенклатура.ТипНоменклатуры
|ИЗ
| Справочник.Номенклатура.ДополнительныеРеквизиты КАК НоменклатураДополнительныеРеквизиты
|  ВНУТРЕННЕЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК Номенклатура
|  ПО НоменклатураДополнительныеРеквизиты.Значение = Номенклатура.Ссылка
|   И (НоменклатураДополнительныеРеквизиты.Ссылка = &НоменклатураИсходная)
|   И (НоменклатураДополнительныеРеквизиты.Свойство = &СвойствоНоменклатураДляБух)"
;

Запрос.УстановитьПараметр("НоменклатураИсходная", ДанныеИБ.Ссылка);
Запрос.УстановитьПараметр("СвойствоНоменклатураДляБух", КомпонентыОбмена.ПараметрыКонвертации.СвойствоНоменклатураДляБухгалтерии);

Выборка = Запрос.Выполнить().Выбрать();
Выборка.Следующий();
ЗаполнитьЗначенияСвойств(ДанныеXDTO, Выборка);
ЗаполнитьЗначенияСвойств(ДанныеXDTO.КлючевыеСвойства, Выборка);

ИначеЕсли  ДанныеИБ.ВидНоменклатуры = КомпонентыОбмена.ПараметрыКонвертации.ВидНоменклатурыДляБухгалтерии Тогда

ЗаполнитьЗначенияСвойств(ДанныеXDTO, ДанныеИБ);
ЗаполнитьЗначенияСвойств(ДанныеXDTO.КлючевыеСвойства, ДанныеИБ);

ИначеЕсли ДанныеИБ.ВидНоменклатуры = КомпонентыОбмена.ПараметрыКонвертации.ВидНоменклатурыУслуги Тогда

ЗаполнитьЗначенияСвойств(ДанныеXDTO, ДанныеИБ);
ЗаполнитьЗначенияСвойств(ДанныеXDTO.КлючевыеСвойства, ДанныеИБ);

Если ДанныеXDTO.КлючевыеСвойства.Свойство("Группа") Тогда

ДанныеXDTO.КлючевыеСвойства.Группа = Неопределено;

КонецЕсли;
Если ДанныеXDTO.Свойство("Группа") Тогда

ДанныеXDTO.Группа = Неопределено;

КонецЕсли;

Если Не ЗначениеЗаполнено(ДанныеИБ.ЕдиницаИзмерения) Тогда

ЕдиницаПоУмолчанию = Справочники.УпаковкиЕдиницыИзмерения.НайтиПоКоду("796",,,Справочники.НаборыУпаковок.БазовыеЕдиницыИзмерения);
Если ЕдиницаПоУмолчанию = Справочники.УпаковкиЕдиницыИзмерения.ПустаяСсылка() Тогда
ЕдиницаПоУмолчанию = Справочники.УпаковкиЕдиницыИзмерения.НайтиПоНаименованию("шт", Истина,,Справочники.НаборыУпаковок.БазовыеЕдиницыИзмерения);
КонецЕсли;

ДанныеXDTO.Вставить("ЕдиницаИзмерения", ЕдиницаПоУмолчанию);

КонецЕсли;

Иначе



КонецЕсли;

ДанныеXDTO.Вставить("ВидАлкогольнойПродукции", Неопределено);

При сохранении ПКО Конвертация будет ругаться, что "не указан вариант идентификации". Выбирете, что это ПКО "для отправки и получения", укажите вариант идентификации на последней вкладке, потом обратно переключите на "для отправки".

Протестировано на 1С Управление Торговлей 11.4.2.144

Еще примеры применения обмена в формате вы можете посмотреть в публикации Организация обмена с базой филиала