Выгрузка характеристик номенклатуры в бухгалтерию

СОДЕРЖАНИЕ

I ВВЕДЕНИЕ

II ТЕРМИНОЛОГИЯ И ОБЩИЕ ЗАМЕЧАНИЯ

III ОБЩЕЕ ОПИСАНИЕ НЕОБХОДИМЫХ ДОРАБОТОК

IV РЕАЛИЗАЦИЯ

1. ИЗМЕНЕНИЯ В КОНФИГУРАЦИИ. ДОБАВЛЕНИЕ ВСПОМОГАТЕЛЬНЫХ ОБЪЕКТОВ В КОНФИГУРАЦИЮ

2 ИЗМЕНЕНИЯ В ПРАВИЛАХ ОБМЕНА. ВЫГРУЗКА ЭЛЕМЕНТОВ СПРАВОЧНИКА «НОМЕНКЛАТУРА»

2.1 ЧТО НУЖНО СДЕЛАТЬ

2.2 КУДА ВНОСИТЬ ИЗМЕНЕНИЯ

2.3 КАКИЕ ИЗМЕНЕНИЯ ВНОСИТЬ

2.4 СОСТАВ ИЗМЕНЕНИЙ

3 ИЗМЕНЕНИЯ В ПРАВИЛАХ ОБМЕНА. ВЫГРУЗКА ПОЛЕЙ ТИПА «НОМЕНКЛАТУРА»

3.1 ЧТО НУЖНО СДЕЛАТЬ

3.2 КУДА ВНОСИТЬ ИЗМЕНЕНИЯ

3.3 СОСТАВ ИЗМЕНЕНИЙ

4 ДОПОЛНИТЕЛЬНЫЕ ИЗМЕНЕНИЯ В ПРАВИЛАХ ОБМЕНА

I ВВЕДЕНИЕ

Ниже рассматривается выгрузка номенклатуры с использованием "Конвертации данных 2". Вариант для "Конвертации данных 3" предложен другим автором: //infostart.ru/public/1012589/

При переводе базы УНФ 1.6 на учёт номенклатуры по характеристикам для одного из клиентов (с помощью обработок infostart.ru/public/556773/) мы столкнулись с тем, что клиент не хочет менять структуру номенклатуры в связанной базе бухгалтерии БП 3.0.

Проблема сводилась к следующему:

Допустим, в базе УНФ ведётся учёт по характеристикам и присутствует номенклатура «Бетолюкс аква краска для полов» с шестью характеристиками «A 0.9 л»; «A 2.7 л»; «A 9 л»; «C 0.9 л»; «C 2.7 л»; «C 9 л».

В базе БП 3.0 отсутствует возможность вести учёт в разрезе характеристик, поэтому при выгрузке в бухгалтерию эта номенклатура свернётся в одну общую позицию номенклатуры «Бетолюкс аква краска для полов» без характеристик.

Допустим, мы хотим, чтобы каждая комбинация «Номенклатура + Характеристика» была выгружена в базу бухгалтерии в виде независимой позиции номенклатуры без характеристик, то есть чтобы в бухгалтерии нашей номенклатуре с шестью характеристиками из УНФ соответствовали шесть позиций номенклатуры без характеристик:

1) «Бетолюкс аква краска для полов A 0.9 л»

2) «Бетолюкс аква краска для полов A 2.7 л»

3) «Бетолюкс аква краска для полов A 9 л»

4) «Бетолюкс аква краска для полов C 0.9 л»

5) «Бетолюкс аква краска для полов C 2.7 л»

6) «Бетолюкс аква краска для полов C 9 л»

Далее в статье предлагается способ решения описанной задачи.

Сразу оговоримся, что:

1. Решение тестировалось только на конфигурациях «УНФ 1.6.10.38» и «Бухгалтерия 3.0.52.39». Всё же постараемся описать решение в виде общего алгоритма, не привязанного к конкретным конфигурациям.

2. Решение затрагивает только односторонний обмен УНФ -> Бухгалтерия.

3. Предполагается, что синхронизация номенклатуры выполняется по реквизиту «Код».

4. Предполагается, что используются индивидуальные характеристики номенклатуры (не рассматривается вариант характеристик, общих для вида номенклатуры).

5. Решение предполагает добавление в конфигурацию одной константы и одного регистра сведений

6. Решение предполагает изменение правил обмена (а это значит, что при обновлении правил обмена необходимо будет переносить изменения в новые правила обмена).

II ТЕРМИНОЛОГИЯ И ОБЩИЕ ЗАМЕЧАНИЯ

Далее в статье под «виртуальной» номенклатурой понимается номенклатура, выгружаемая в бухгалтерию для каждой комбинации «Номенклатура + Характеристика» (выше в примере это, например, номенклатура «Бетолюкс аква краска для полов A 0.9 л»).

Идентификаторы объектов и переменных, которые будут встречаться далее, могут включать префикс «ГИ_». Этот префикс мы добавляем к собственным объектам при редактировании типовых конфигураций.

III ОБЩЕЕ ОПИСАНИЕ НЕОБХОДИМЫХ ДОРАБОТОК

Обмен с бухгалтерией в контексте выгрузки номенклатуры состоит из двух этапов:

Этап 1. Выгрузка элементов справочника «Номенклатура»

Этап 2. Выгрузка полей типа «Номенклатура» (например, реквизитов «Номенклатура» в табличных частях документов)

Рассмотрим подробнее, каким образом нам необходимо модифицировать выгрузку на каждом из этапов.

Этап 1. Выгрузка элементов справочника «Номенклатура»

При выгрузке группы номенклатуры должная отрабатывать типовая выгрузка.

При выгрузке номенклатуры, для которой НЕ ведётся учёт по характеристикам, должна отрабатывать типовая выгрузка.

При выгрузке номенклатуры, для которой ведётся учёт по характеристикам, необходимо вместо одной позиции номенклатуры выгружать новые позиции, соответствующие комбинациям «Номенклатура + Характеристика».

Так как синхронизация у нас выполняется по реквизиту «Код», для каждой виртуальной номенклатуры необходимо будет генерировать уникальный код.

Этот код необходимо будет где-то сохранять, чтобы при следующем обмене с бухгалтерией не генерировать новый код для ранее выгруженной виртуальной номенклатуры (иначе в бухгалтерии будут дубли виртуальной номенклатуры).

Для каждой виртуальной номенклатуры необходимо будет генерировать своё наименование.

Этап 2. Выгрузка полей типа «Номенклатура»

На этом этапе выгружается код, соответствующий полю «Номенклатура».

При выгрузке номенклатуры, для которой НЕ ведётся учёт по характеристикам, должна отрабатывать типовая выгрузка (выгружается код этой номенклатуры).

Если для номенклатуры ведётся учёт по характеристикам, то при выгрузке поля типа «Номенклатура» нужно подменять код этой номенклатуры на код виртуальной номенклатуры.

Предполагается, что в той же структуре, которой принадлежит поле «Номенклатура», мы можем найти и поле «Характеристика», чтобы однозначно идентифицировать выгружаемую виртуальную номенклатуру.

Например, при выгрузке поля «Номенклатура» из табличной части документа «РасходнаяНакладная» мы в этой же табличной части можем найти реквизит «Характеристика».

Код виртуальной номенклатуры мы будем находить по комбинации полей «Номенклатура» + «Характеристика» в регистре сведений, в который этот код был записан на этапе 1.

IV РЕАЛИЗАЦИЯ АЛГОРИТМА

1. ИЗМЕНЕНИЯ В КОНФИГУРАЦИИ. ДОБАВЛЕНИЕ ВСПОМОГАТЕЛЬНЫХ ОБЪЕКТОВ В КОНФИГУРАЦИЮ

Изменения в конфигурации будут состоять только в добавлении двух объектов для генерации и сохранения кодов виртуальной номенклатуры:

1. Константа «ГИ_ПоследнийКодНоменклатурыНаВыгрузкуВБухгалтерию», которая будет хранить максимальный на данный момент код виртуальной номенклатуры

2. Регистр сведений для кодов виртуальной номенклатуры:

Имя: ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию

Периодичность: Непериодический

Режим записи: Независимый

Измерения:

2 ИЗМЕНЕНИЯ В ПРАВИЛАХ ОБМЕНА. ВЫГРУЗКА ЭЛЕМЕНТОВ СПРАВОЧНИКА «НОМЕНКЛАТУРА»

2.1 ЧТО НУЖНО СДЕЛАТЬ

Необходимо исправить правила обмена, чтобы:

— группы номенклатуры выгружались типовым способом

— номенклатура без характеристик выгружалась типовым способом

— номенклатура с характеристиками разворачивалась в нужное количество позиций виртуальной номенклатуры

— для виртуальной номенклатуры генерировался и сохранялся код в регистре сведений

— максимальный код виртуальной номенклатуры сохранялся в константе (для генерации новых кодов виртуальной номенклатуры)

— для виртуальной номенклатуры генерировалось наименование

2.2 КУДА ВНОСИТЬ ИЗМЕНЕНИЯ

Изменения будем вносить в правило выгрузки данных справочника «Номенклатура», обработчик «Перед обработкой».

2.3 КАКИЕ ИЗМЕНЕНИЯ ВНОСИТЬ

Для того чтобы при выгрузке номенклатура с характеристиками разворачивалась в нужное количество позиций виртуальной номенклатуры, необходимо:

— заблокировать типовую выгрузку этой номенклатуры (иначе она выгрузится в свёрнутом виде)

— добавить на выгрузку позиции виртуальной номенклатуры

Чтобы понять, каким образом мы будем модифицировать выгрузку, опишем в общих чертах алгоритм выгрузки по правилам обмена, реализованный в УНФ (см. процедуру ВыполнитьВыгрузкуЗарегистрированныхДанных обработки КонвертацияОбъектовИнформационныхБаз):

ТИПОВОЙ ЦИКЛ ВЫГРУЗКИ:

ВыборкаИзменений = ВыбратьИзменения(…);

Пока ВыборкаИзменений.Следующий() Цикл

Данные = ВыборкаИзменений.Получить();

Выполнить(ПравилоВыгрузкиДанных.ПередОбработкой);

ВыгрузкаОбъектаВыборки(Данные, …);

КонецЦикла;

Мы будем «вклиниваться» в этот алгоритм в точке Выполнить(ПравилоВыгрузкиДанных.ПередОбработкой);, определив собственный алгоритм выгрузки в обработчике «ПередОбработкой» правил обмена для справочника «Номенклатура».

Наша задача состоит в том, чтобы с помощью обработчика «ПередОбработкой» модифицировать алгоритм выгрузки таким образом:

ВыборкаИзменений = ВыбратьИзменения(…);

Пока ВыборкаИзменений.Следующий() Цикл

// Данные выгрузки мы будем подготавливать ниже самостоятельно,
// поэтому следующая строчка сработает вхолостую для элементов выборки типа «Номенклатура»:
Данные = ВыборкаИзменений.Получить();

// Далее отработает код, определённый нами в обработчике ПравилоВыгрузкиДанных.ПередОбработкой:
ВыгрузитьВсюНеобходимуюНоменклатуру();
ПозиционироватьВыборкуИзмененийНаПоследнемЭлементеТипаНоменклатура();
Данные = ПолучитьНоменклатуруДляВыгрузкиНаПоследнейИтерации();

// Далее отработает типовой код и выгрузит последнюю позицию номенклатуры,
// подготовленную выше в переменной Данные:
ВыгрузкаОбъектаВыборки(Данные, …);

КонецЦикла;

Выборка изменений включает объекты разных типов (другие справочники, документы и т.д.), поэтому нам нужно изменить только ту итерацию цикла, которая относится к выгрузке номенклатуры, и продолжить типовую выгрузку объектов других типов.

Для этого:

— на итерации цикла, относящейся к первой выгружаемой номенклатуре из выборки ВыборкаИзменений, мы выгружаем сразу все позиции номенклатуры

— после выгрузки позиций мы «подсовываем» циклу какую-нибудь подходящую номенклатуру, чтобы на этой номенклатуре отработала типовая строчка ВыгрузкаОбъектаВыборки(Данные, …); и цикл пошёл на следующую итерацию (итерацию, на которой уже выгружаются объекты других типов).

2.4 СОСТАВ ИЗМЕНЕНИЙ

Правило выгрузки данных «ПередОбработкой» для справочника «Номенклатура»

Код правила вынесен в алгоритм «ГИ_ПВД_Номенклатура_ПередОбработкойПравила»:

Выполнить(Алгоритмы.ГИ_ПВД_Номенклатура_ПередОбработкойПравила);

Алгоритм 1 «ГИ_ПВД_Номенклатура_ПередОбработкойПравила»

Код алгоритма состоит из последовательного вызова алгоритмов:

ГИ_МенеджерВТ = Новый МенеджерВременныхТаблиц();
ГИ_ПоследняяНоменклатура = Неопределено;
ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации = Неопределено;

Выполнить(Алгоритмы.ГИ_ИнициализироватьВТНоменклатурыНаВыгрузку);
Выполнить(Алгоритмы.ГИ_ПолучитьПоследнююНоменклатуруВВыборкеИзменений);
Выполнить(Алгоритмы.ГИ_ПолучитьНоменклатуруДляПоследнейИтерации);
Выполнить(Алгоритмы.ГИ_ВыгрузитьНоменклатуру);
Выполнить(Алгоритмы.ГИ_ИнициализироватьПоследнююИтерацию);

Алгоритм 2 «ГИ_ИнициализироватьВТНоменклатурыНаВыгрузку»

Помещаем во временную таблицу «ВТ_НоменклатураНаВыгрузку» менеджера временных таблиц ГИ_МенеджерВТ выгружаемую номенклатуру и её характеристики:

— номенклатуру, для которой зарегистрированы изменения (из типовой выборки ВыборкаИзменений)

— всю номенклатуру с характеристиками, для которой ещё нет записей в регистре «ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию». Так как при создании новой характеристики для существующей номенклатуры эта номенклатура не регистрируется как изменённая, то ВыборкаИзменений не будет содержать эту номенклатуру. Поэтому мы принудительно добавляем на выгрузку такую номенклатуру, ориентируясь на содержимое регистра «ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию».

ГИ_ВсяНоменклатураНаВыгрузку = Новый Массив();

ВыборкаИзменений.Сбросить();
Пока ВыборкаИзменений.Следующий() Цикл

ГИ_Данные = ВыборкаИзменений.Получить();
Если ТипЗнч(ГИ_Данные) = Тип("СправочникОбъект.Номенклатура") Тогда
ГИ_ВсяНоменклатураНаВыгрузку.Добавить(ГИ_Данные.Ссылка);
КонецЕсли;

КонецЦикла;

ГИ_Запрос = Новый Запрос();
ГИ_Запрос.МенеджерВременныхТаблиц = ГИ_МенеджерВТ;
ГИ_Запрос.УстановитьПараметр("ВсяНоменклатураНаВыгрузку", ГИ_ВсяНоменклатураНаВыгрузку);
ГИ_Запрос.Текст = "
|ВЫБРАТЬ
| СправочникНоменклатура.Родитель КАК Группа,
| СправочникНоменклатура.Ссылка КАК Номенклатура,
|   ЕСТЬNULL(Характеристики.Ссылка, ЗНАЧЕНИЕ(Справочник.ХарактеристикиНоменклатуры.ПустаяСсылка)) КАК Характеристика,
| ВЫБОР
|  КОГДА СправочникНоменклатура.ЭтоГруппа
|       ТОГДА ЛОЖЬ
|  ИНАЧЕ СправочникНоменклатура.ИспользоватьХарактеристики
| КОНЕЦ КАК ИспользоватьХарактеристики
|ПОМЕСТИТЬ
| ВТ_НоменклатураНаВыгрузку
|ИЗ
| Справочник.Номенклатура КАК СправочникНоменклатура
| ЛЕВОЕ СОЕДИНЕНИЕ
| Справочник.ХарактеристикиНоменклатуры КАК Характеристики
|   ПО
|    СправочникНоменклатура.Ссылка = Характеристики.Владелец
|ГДЕ
| СправочникНоменклатура.Ссылка В (&ВсяНоменклатураНаВыгрузку)
|
|ОБЪЕДИНИТЬ
|
|ВЫБРАТЬ
| Владелец.Родитель КАК Группа,
| Владелец КАК Номенклатура,
| Ссылка КАК Характеристика,
| ИСТИНА КАК ИспользоватьХарактеристики
|ИЗ
| Справочник.ХарактеристикиНоменклатуры
|ГДЕ
| Ссылка НЕ В (ВЫБРАТЬ Характеристика ИЗ РегистрСведений.ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию)
|  И
| Владелец ССЫЛКА Справочник.Номенклатура
|;";
ГИ_Запрос.Выполнить();

Алгоритм 3 «ГИ_ПолучитьПоследнююНоменклатуруВВыборкеИзменений»

Записываем в переменную ГИ_ПоследняяНоменклатура последний элемент выборки ВыборкаИзменений с типом «Номенклатура», чтобы после нашей выгрузки позиционировать выборку ВыборкаИзменений на этом элементе – тогда типовой цикл выгрузки на следующих итерациях продолжит свою работу по выгрузке данных других типов.

ВыборкаИзменений.Сбросить();
Пока ВыборкаИзменений.Следующий() Цикл

ГИ_Данные = ВыборкаИзменений.Получить();
Если ТипЗнч(ГИ_Данные) <> Тип("СправочникОбъект.Номенклатура") Тогда
Продолжить;
КонецЕсли;

Если ТипЗнч(ГИ_Данные.Ссылка) = Тип("СправочникСсылка.Номенклатура") Тогда
ГИ_ПоследняяНоменклатура = ГИ_Данные.Ссылка;
КонецЕсли;

КонецЦикла;

Алгоритм 4 «ГИ_ПолучитьНоменклатуруДляПоследнейИтерации»

Записываем в переменную ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации номенклатуру, которую мы можем выгрузить типовым образом – то есть номенклатуру, которая будет обработана в строчке ВыгрузкаОбъектаВыборки(Данные, …) типового цикла выгрузки. Эту строчку типового цикла мы не можем пропустить (т.к. не меняем конфигурацию), поэтому должны «скормить» ей какую-то подходящую номенклатуру.

Подходящей не может быть номенклатура с характеристиками (т.к. такую номенклатуру мы выгружаем по-особому), поэтому в качестве такой номенклатуры может выступать либо группа, либо номенклатура без характеристик. Поиск такой номенклатуры и реализован в алгоритме.

Если ГИ_ПоследняяНоменклатура.ЭтоГруппа ИЛИ НЕ ГИ_ПоследняяНоменклатура.ИспользоватьХарактеристики Тогда
ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации = ГИ_ПоследняяНоменклатура;
Перейти ~ГИ_Выход_ГИ_ПолучитьНоменклатуруДляПоследнейИтерации;
КонецЕсли;

ГИ_Запрос = Новый Запрос();
ГИ_Запрос.МенеджерВременныхТаблиц = ГИ_МенеджерВТ;
ГИ_Запрос.Текст = "
|ВЫБРАТЬ ПЕРВЫЕ 1
| Группа
|ИЗ
| ВТ_НоменклатураНаВыгрузку
|ГДЕ
| Группа <> ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)
|;";
ГИ_ВыборкаГруппы = ГИ_Запрос.Выполнить().Выбрать();
Если ГИ_ВыборкаГруппы.Следующий() Тогда
ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации = ГИ_ВыборкаГруппы.Группа;
Перейти ~ГИ_Выход_ГИ_ПолучитьНоменклатуруДляПоследнейИтерации;
КонецЕсли;

ГИ_Запрос = Новый Запрос();
ГИ_Запрос.Текст = "
|ВЫБРАТЬ ПЕРВЫЕ 1
| Группа
|ИЗ
| Справочник.Номенклатура
|ГДЕ
| ЭтоГруппа
|  И
| НЕ ПометкаУдаления
|;";
ГИ_ВыборкаГруппы = ГИ_Запрос.Выполнить().Выбрать();
Если ГИ_ВыборкаГруппы.Следующий() Тогда
ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации = ГИ_ВыборкаГруппы.Группа;
Перейти ~ГИ_Выход_ГИ_ПолучитьНоменклатуруДляПоследнейИтерации;
КонецЕсли;

ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации = Справочники.Номенклатура.ПустаяСсылка();

~ГИ_Выход_ГИ_ПолучитьНоменклатуруДляПоследнейИтерации:

Алгоритм 5 «ГИ_ВыгрузитьНоменклатуру»

Основной алгоритм выгрузки. Обходим в цикле выгружаемую номенклатуру из временной таблицы «ВТ_НоменклатураНаВыгрузку», подготовленной выше.

Если это номенклатура с характеристиками, то получаем данные виртуальной номенклатуры с помощью алгоритма «ГИ_ПолучитьДанныеНоменклатурыИзРегистраКодов».

Данные номенклатуры присваиваем переменной Данные и запускаем кусок кода выгрузки из типового цикла, вынесенный в алгоритм «ГИ_ВыполнитьТиповойКодВыгрузкиНоменклатуры».

ГИ_Запрос = Новый Запрос();
ГИ_Запрос.МенеджерВременныхТаблиц = ГИ_МенеджерВТ;
ГИ_Запрос.Текст = "
|ВЫБРАТЬ
| *
|ИЗ
| ВТ_НоменклатураНаВыгрузку
|;";
ГИ_НоменклатураНаВыгрузку = ГИ_Запрос.Выполнить().Выбрать();

Пока ГИ_НоменклатураНаВыгрузку.Следующий() Цикл

Если ГИ_НоменклатураНаВыгрузку.ИспользоватьХарактеристики Тогда


ГИ_Номенклатура = ГИ_НоменклатураНаВыгрузку.Номенклатура;
ГИ_Характеристика = ГИ_НоменклатураНаВыгрузку.Характеристика;

ГИ_ДанныеНоменклатуры = Неопределено;
Выполнить(Алгоритмы.ГИ_ПолучитьДанныеНоменклатурыИзРегистраКодов);

Данные = ГИ_НоменклатураНаВыгрузку.Номенклатура.ПолучитьОбъект();
Данные.Код = ГИ_ДанныеНоменклатуры.Код;
Данные.Наименование = ГИ_ДанныеНоменклатуры.Наименование;
Данные.НаименованиеПолное = ГИ_ДанныеНоменклатуры.Наименование;

Иначе

Данные = ГИ_НоменклатураНаВыгрузку.Номенклатура.ПолучитьОбъект();

КонецЕсли;

Выполнить(Алгоритмы.ГИ_ВыполнитьТиповойКодВыгрузкиНоменклатуры);

КонецЦикла;

Алгоритм 5.1 «ГИ_ПолучитьДанныеНоменклатурыИзРегистраКодов»

Получаем код виртуальной номенклатуры из регистра «ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию» по комбинации «Номенклатура + Характеристика».

Если такой записи в регистре нет (если эта комбинация выгружается впервые), то с помощь алгоритма «ГИ_ПолучитьНовыйКодНоменклатурыДляВыгрузки» генерируем новый код виртуальной номенклатуры и записываем его в регистр.

В качестве наименования виртуальной номенклатуры возвращаем строку, состоящую из наименований номенклатуры и характеристики, разделённых пробелом.

ГИ_Запрос = Новый Запрос();
ГИ_Запрос.УстановитьПараметр("Номенклатура", ГИ_Номенклатура);
ГИ_Запрос.УстановитьПараметр("Характеристика", ГИ_Характеристика);

ГИ_Запрос.Текст = "
|ВЫБРАТЬ
| Код
|ИЗ
| РегистрСведений.ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию
|ГДЕ
| Номенклатура = &Номенклатура
|  И
| Характеристика = &Характеристика
|;";

ГИ_РезультатЗапроса = ГИ_Запрос.Выполнить();
Если ГИ_РезультатЗапроса.Пустой() Тогда

ГИ_КодНоменклатуры = Неопределено;
Выполнить(Алгоритмы.ГИ_ПолучитьНовыйКодНоменклатурыДляВыгрузки);

ГИ_НаименованиеНоменклатуры = ГИ_Номенклатура.НаименованиеПолное;
Если НЕ ЗначениеЗаполнено(ГИ_НаименованиеНоменклатуры) Тогда
ГИ_НаименованиеНоменклатуры = ГИ_Номенклатура.Наименование;
КонецЕсли;

Если ЗначениеЗаполнено(ГИ_Характеристика) Тогда
ГИ_НаименованиеНоменклатуры = ГИ_НаименованиеНоменклатуры + ", " + ГИ_Характеристика.Наименование;
КонецЕсли;

ГИ_НаборЗаписей = РегистрыСведений.ГИ_КодыНоменклатурыНаВыгрузкуВБухгалтерию.СоздатьНаборЗаписей();
ГИ_НаборЗаписей.Отбор.Код.Установить(ГИ_КодНоменклатуры);

ГИ_Запись = ГИ_НаборЗаписей.Добавить();
ГИ_Запись.Код = ГИ_КодНоменклатуры;
ГИ_Запись.Номенклатура = ГИ_Номенклатура;
ГИ_Запись.Характеристика = ГИ_Характеристика;

ГИ_НаборЗаписей.Записать();

Иначе

ГИ_Выборка = ГИ_РезультатЗапроса.Выбрать();
ГИ_Выборка.Следующий();

ГИ_КодНоменклатуры = ГИ_Выборка.Код;

ГИ_НаименованиеНоменклатуры = ГИ_Номенклатура.НаименованиеПолное;
Если НЕ ЗначениеЗаполнено(ГИ_НаименованиеНоменклатуры) Тогда
ГИ_НаименованиеНоменклатуры = ГИ_Номенклатура.Наименование;
КонецЕсли;

Если ЗначениеЗаполнено(ГИ_Характеристика) Тогда
ГИ_НаименованиеНоменклатуры = ГИ_НаименованиеНоменклатуры + ", " + ГИ_Характеристика.Наименование;
КонецЕсли;

КонецЕсли;

ГИ_ДанныеНоменклатуры = Новый Структура("Код, Наименование", ГИ_КодНоменклатуры, ГИ_НаименованиеНоменклатуры);

Алгоритм 5.1.1 «ГИ_ПолучитьНовыйКодНоменклатурыДляВыгрузки»

Получаем код новой виртуальной номенклатуры, увеличивая на единицу значение константы «ГИ_ПоследнийКодНоменклатурыНаВыгрузкуВБухгалтерию».

Записываем новое значение последнего кода в константу.

Добавляем префикс «ПХ» к коду, чтобы избежать конфликтов с кодами номенклатуры без характеристик, которая выгружается в бухгалтерию как есть.

ГИ_ПрефиксКодаСгенерированногоДляВыгрузкуВБухгалтерию = "ПХ";

ГИ_НовыйНомер = Константы.ГИ_ПоследнийКодНоменклатурыНаВыгрузкуВБухгалтерию.Получить() + 1;
ГИ_КодНоменклатуры = ГИ_ПрефиксКодаСгенерированногоДляВыгрузкуВБухгалтерию + Формат(ГИ_НовыйНомер, "ЧЦ=9; ЧДЦ=; ЧВН=; ЧГ=");
Константы.ГИ_ПоследнийКодНоменклатурыНаВыгрузкуВБухгалтерию.Установить(ГИ_НовыйНомер);

Алгоритм 5.2 «ГИ_ВыполнитьТиповойКодВыгрузкиНоменклатуры»

Алгоритм содержит часть кода типового цикла процедуры ВыполнитьВыгрузкуЗарегистрированныхДанных модуля объекта обработки КонвертацияОбъектовИнформационныхБаз. Изменения в типовом коде помечены текстом "ИЗМЕНЕНО".

Этот код выгружает данные номенклатуры, которые предварительно сохранены в переменной Данные.

Если ТипДанныхДляВыгрузки <> ТипРегистрСоответствия Тогда

// Определяем вид отправки объекта.
ОтправкаЭлемента = ОтправкаЭлементаДанных.Авто;

СтандартныеПодсистемыСервер.ПриОтправкеДанныхПодчиненному(Данные, ОтправкаЭлемента, НачальнаяВыгрузкаДанных, УзелДляОбменаОбъект);

Если ОтправкаЭлемента = ОтправкаЭлементаДанных.Удалить Тогда

Если ВыгружаетсяРегистр Тогда

// Удаление регистра отсылаем в виде пустого набора записей.

Иначе

// Посылаем информацию об удалении.
ОтработатьУдалениеОбъекта(Данные);

// ИЗМЕНЕНО >>
// типовой код закомментирован:
//Продолжить;
Перейти ~ГИ_Продолжить_ВыполнитьТиповойКодВыгрузкиНоменклатуры;
// ИЗМЕНЕНО <<

КонецЕсли;

ИначеЕсли ОтправкаЭлемента = ОтправкаЭлементаДанных.Игнорировать Тогда

// ИЗМЕНЕНО >>
// типовой код закомментирован:
//Продолжить;
Перейти ~ГИ_Продолжить_ВыполнитьТиповойКодВыгрузкиНоменклатуры;
// ИЗМЕНЕНО <<

КонецЕсли;

КонецЕсли;

// ВЫГРУЗКА ОБЪЕКТА
Если ВыгружаетсяРегистр Тогда

// выгрузка регистра
ВыгрузкаРегистра(Данные, ПравилоВыгрузкиДанных, ИсходящиеДанные, НеВыгружатьОбъектыПоСсылкам);

ИначеЕсли ВыгружаютсяКонстанты Тогда

// выгрузка набора констант
Свойства = Менеджеры[Тип("КонстантыНабор")];

ВыгрузитьНаборКонстант(ПравилоВыгрузкиДанных, Свойства, ИсходящиеДанные, ОбъектМетаданныхТекущий.Имя);

Иначе

// выгрузка ссылочных типов
ВыгрузкаОбъектаВыборки(Данные, ПравилоВыгрузкиДанных, , ИсходящиеДанные, НеВыгружатьОбъектыПоСсылкам);

КонецЕсли;

Если ЭтоОбменЧерезВнешнееСоединение Тогда

Если ЗагрузкаДанныхВыполняетсяВоВнешнемСоединении Тогда

Если ОбработкаДляЗагрузкиДанных().ИспользоватьТранзакции
И ОбработкаДляЗагрузкиДанных().КоличествоОбъектовНаТранзакцию > 0
И ОбработкаДляЗагрузкиДанных().СчетчикЗагруженныхОбъектов() % ОбработкаДляЗагрузкиДанных().КоличествоОбъектовНаТранзакцию = 0 Тогда

// Если используются транзакции и установлено количество элементов одной транзакции,
// то при чтении сообщения обмена необходимо контролировать,
// сколько объектов загружено. Если количество загруженных объектов
// равно количество объектов в одной транзакции, то существующую транзакцию
// необходимо зафиксировать и открыть новую.
ВнешнееСоединение.ЗафиксироватьТранзакцию();
ВнешнееСоединение.НачатьТранзакцию();

КонецЕсли;


Иначе

ОбработкаДляЗагрузкиДанных().ВнешнееСоединениеПроверитьНачалоИФиксациюТранзакцииПриЗагрузкеДанных();

КонецЕсли;

КонецЕсли;

// ИЗМЕНЕНО >>
~ГИ_Продолжить_ВыполнитьТиповойКодВыгрузкиНоменклатуры:
// ИЗМЕНЕНО <<

Алгоритм 6 «ГИ_ИнициализироватьПоследнююИтерацию»

Позиционирует выборку ВыборкаИзменений на последний элемент типа «Номенклатура», чтобы на следующей итерации типового цикла продолжилась выгрузка объектов других типов.

Переменной Данные присваивается значение, означенное в алгоритме «ГИ_ПолучитьНоменклатуруДляПоследнейИтерации», чтобы успешно отработал код ВыгрузкаОбъектаВыборки(Данные, …) в текущей итерации типового цикла.

ВыборкаИзменений.Сбросить();
Пока ВыборкаИзменений.Следующий() Цикл

ГИ_Данные = ВыборкаИзменений.Получить();
Если ТипЗнч(ГИ_Данные) <> Тип("СправочникОбъект.Номенклатура") Тогда
Продолжить;
КонецЕсли;

Если ГИ_Данные.Ссылка = ГИ_ПоследняяНоменклатура Тогда
Прервать;
КонецЕсли;

КонецЦикла;

Данные = ГИ_НоменклатураДляВыгрузкиНаПоследнейИтерации.ПолучитьОбъект();

3 ИЗМЕНЕНИЯ В ПРАВИЛАХ ОБМЕНА. ВЫГРУЗКА ПОЛЕЙ ТИПА «НОМЕНКЛАТУРА»

3.1 ЧТО НУЖНО СДЕЛАТЬ

При выгрузке реквизита типа «Номенклатура» необходимо, чтобы:

— номенклатура без характеристик выгружалась типовым способом

— вместо номенклатуры с характеристиками выгружался код виртуальной номенклатуры

3.2 КУДА ВНОСИТЬ ИЗМЕНЕНИЯ

Необходимо внести изменения в обработчик «ПриВыгрузке» правила конвертации свойств. Например, в правило конвертации свойств поля «Номенклатура» табличной части «Товары» документа «ПоступлениеТоваровУслуг».

Изменения необходимо вносить для полей «Номенклатура» правил конвертации свойств всех объектов, выгружаемых в бухгалтерию.

3.3 СОСТАВ ИЗМЕНЕНИЙ

Код правила вынесен в алгоритм «ГИ_ПКС_Номенклатура_ПриВыгрузкеСвойства».

Выполнить(Алгоритмы.ГИ_ПКС_Номенклатура_ПриВыгрузкеСвойства);

Алгоритм 7 «ГИ_ПКС_Номенклатура_ПриВыгрузкеСвойства»

Если в поле типа «Номенклатура» содержится номенклатура с характеристиками, то необходимо выгрузить код соответствующей виртуальной номенклатуры, полученный алгоритмом «ГИ_ПолучитьДанныеНоменклатурыИзРегистраКодов».

ГИ_Номенклатура = ОбъектКоллекции.Номенклатура;
ГИ_Характеристика = ОбъектКоллекции.Характеристика;

Если НЕ ГИ_Номенклатура.ЭтоГруппа И ГИ_Номенклатура.ИспользоватьХарактеристики Тогда

ГИ_ДанныеНоменклатуры = Неопределено;
Выполнить(Алгоритмы.ГИ_ПолучитьДанныеНоменклатурыИзРегистраКодов);
Значение = Новый Структура("Код, ЭтоГруппа", ГИ_ДанныеНоменклатуры.Код, Ложь);

КонецЕсли;

4 ДОПОЛНИТЕЛЬНЫЕ ИЗМЕНЕНИЯ В ПРАВИЛАХ ОБМЕНА

Типовые правила конвертации некоторых объектов могут содержать изменения в обработчиках событий. Если эти объекты выгружаются в бухгалтерию, необходимо проверить обработчики событий этих объектов и исправить их при необходимости.

Например, в правилах обмена УНФ-Бухгалтерия изменён обработчик события «ПередВыгрузкой» правила конвертации объекта «КорректировкаРеализации».

Код обработчика состоит из запроса, результат которого не включает поле «Характеристика». Необходимо добавить в секцию «ВЫБРАТЬ» запроса нужное поле: