Здесь, я расскажу вам о тех ситуациях, в которых мне понадобилась эта функция, и как она меня не раз выручила. Все свое повествование я сопровожу реальными примерами, которые реализовывались мной в одном из проектов.
Описание функции ВыгрузитьПоПравилу().
Функция ВыгрузитьПоПравилу() используется для выгрузки объекта в xml-узел и возвращает узел ссылки на этот объект.
В процессе выгрузки эта функция вызывается из:
ПВД, когда объект из выборки получен и необходимо произвести его конвертацию.
ПКО, когда необходимо выгрузить связанную с выгружаемым объектом информацию.
ПКС, когда свойство имеет ссылочный тип и необходимо выгрузить по ссылке из этого свойства объект.
Из функции ВыгрузитьПоПравилу() могут быть вызваны другие функции, выгружающие субконто, свойства и т.д. этого объекта, а из этих функций – рекурсивно может быть вызвана функция ВыгрузитьПоПравилу(). После того, как объект со всеми необходимыми свойствами выгружен, управление возвращается в то место кода, откуда функция была вызвана. Таким образом, вызов этой функции из обработчиков событий какого-либо правила (ПВД, ПКО, ПКС), не изменяет процесса выгрузки объекта по этому правилу.
Функция ВыгрузитьПоПравилу() имеет ряд параметров
ВыгрузитьПоПравилу(Источник,
Приемник,
ВходящиеДанные,
ИсходящиеДанные,
ИмяПКО,
УзелСсылки,
ТолькоПолучитьУзелСсылки,
ПКО,
ЭтоПравилоСГлобальнойВыгрузкойОбъектов,
ВыборкаДляВыгрузкиДанных)
Все эти параметры в функции имеют значения по умолчанию, и, как правило, передавать имеет смысл только параметр ИмяПКО, а также параметры Источник и/или ВходящиеДанные – в зависимости от того, как настроено ПКО.
ИмяПКО – строка, название ПКО, в которое передаем управление.
Источник – ссылка на элемент объекта-источника, который передаем для конвертации.
ВходящиеДанные – структура. Элементы в ней должны быть названы аналогично ПКС, у которых стоит флаг «Получить из входящих данных». Если таких ПКС нет, передавать этот параметр не нужно. Если в ПКО у всех ПКС стоит флаг «Получить из входящих данных», то, наоборот, необходимо передать структуру ВходящиеДанные, а Источник тогда передавать не нужно.
Выгрузка произвольной выборки данных через стандартную выборку с регистрацией объекта источника.
Необходимость в такой задаче может возникнуть, когда объект «источника» и объект «приемника» имеют различную смысловую или функциональную структуру.
Например, документ «источника» позволяет вводить информацию по нескольким подразделениям предприятия, документ «приемника» позволяет вводить информацию только об одном подразделении предприятия.
Данная задача отлично решается при помощи произвольного алгоритма выборки в ПВД, но данное решение имеет два недостатка:
- Мы лишаемся механизма регистрации изменений;
- Алгоритм произвольной выборки отказывается работать в БСП.
БСП — библиотека стандартных подсистем. В частности, имеет своем составе подсистему «Обмен данными», данная подсистема реализует механизмы автоматической синхронизации данных между конфигурациями, по правилам написанным в Конвертации данных.
- Создаем ПВД со Стандартным алгоритмом выборки;
- Указываем объект выборки;
- Пишем обработчик «Перед выгрузкой»(хочу подчеркнуть, что нужно использовать именно этот обработчик). Например, следующего содержания:
//Начинаем отбор данных для выгрузки
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ РАЗЛИЧНЫЕ
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации КАК Подразделение,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Должность,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ЗанимаемыхСтавок КАК Ставка,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ДатаПриема,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник.ВидЗанятости КАК ВидЗанятости,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Дата,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Номер,
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка.Проведен,
| ВЫБОР
| КОГДА ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета = ЗНАЧЕНИЕ(ПланВидовРасчета.ОсновныеНачисленияОрганизаций.ОкладПоЧасам)
| ТОГДА ИСТИНА
| ИНАЧЕ ЛОЖЬ
| КОНЕЦ КАК СдельнаяОплатаТруда,
| ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета КАК ВидРасчета
|ИЗ
| Документ.ПриемНаРаботуВОрганизацию.РаботникиОрганизации КАК ПриемНаРаботуВОрганизациюРаботникиОрганизации
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.ПриемНаРаботуВОрганизацию.ОсновныеНачисления КАК ПриемНаРаботуВОрганизациюОсновныеНачисления
| ПО ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка = ПриемНаРаботуВОрганизациюОсновныеНачисления.Ссылка
| И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Сотрудник = ПриемНаРаботуВОрганизациюОсновныеНачисления.Сотрудник
|ГДЕ
| ВЫБОР
| КОГДА &ИспользоватьОтборПоПодразделениям ТОГДА
| ПриемНаРаботуВОрганизациюРаботникиОрганизации.ПодразделениеОрганизации В ИЕРАРХИИ (&Подразделения)
| ИНАЧЕ
| ИСТИНА
| КОНЕЦ
| И ВЫБОР
| КОГДА &ИспользоватьОтборПоВидамРасчета ТОГДА
| ПриемНаРаботуВОрганизациюОсновныеНачисления.ВидРасчета В ИЕРАРХИИ (&ВидРасчета)
| ИНАЧЕ
| ИСТИНА
| КОНЕЦ
| И ПриемНаРаботуВОрганизациюРаботникиОрганизации.Ссылка = &Ссылка";
Выполнить(Алгоритмы.ЗаполнитьПараметрыОтбораПоВидамРасчета);
Запрос.УстановитьПараметр("Ссылка", Объект.Ссылка);
Выполнить(Алгоритмы.ЗаполнитьПараметрыОтбораПоПодразделениям);
ВыбранныеДанные = Неопределено;
ПустаяТабличнаяЧасть = Неопределено;
Выполнить(Алгоритмы.ПолучитьСтруктуруВыгрузкиКадровыхДокументов);
РезультатЗапроса = Запрос.Выполнить().Выгрузить();
Сотрудники = ПустаяТабличнаяЧасть.Скопировать();
СтрокаДокумента = Неопределено;
Для Каждого СтрокаРезультата Из РезультатЗапроса Цикл
ДанныеИзВнешнихСистем = "Выгружено из ЗиКБУ, документ ""Прием на работу в организацию"" №" + СтрокаРезультата.Номер + " от " + Формат(СтрокаРезультата.Дата, "ДФ=dd.MM.yyyy") +
", " + СтрокаРезультата.Подразделение.Наименование;
СтрокаДокумента = ВыбранныеДанные.Найти(ДанныеИзВнешнихСистем);
Если СтрокаДокумента = Неопределено Тогда
СтрокаДокумента = ВыбранныеДанные.Добавить();
СтрокаДокумента.Дата = СтрокаРезультата.ДатаПриема;
СтрокаДокумента.Кафедра = СтрокаРезультата.Подразделение;
СтрокаДокумента.Проведен = СтрокаРезультата.Проведен;
СтрокаДокумента.ДокументСАктивнымиДолжностями = Истина;
СтрокаДокумента.ДанныеИзВнешнихСистем = ДанныеИзВнешнихСистем;
СтрокаДокумента.АктивныеДолжности = ПустаяТабличнаяЧасть.Скопировать();
СтрокаДокумента.НеактивныеДолжности = ПустаяТабличнаяЧасть.Скопировать();
КонецЕсли;
СтрокаРаботников = СтрокаДокумента.АктивныеДолжности.Добавить();
СтрокаРаботников.Должность = СтрокаРезультата.Должность;
СтрокаРаботников.Сотрудник = СтрокаРезультата.Сотрудник.Физлицо;
СтрокаРаботников.Ставка = СтрокаРезультата.Ставка * 100;
СтрокаРаботников.ВидНачисления = СтрокаРезультата.ВидРасчета;
СтрокаРаботников.ВидЗанятости = СтрокаРезультата.ВидЗанятости;
КонецЦикла;
//Переводим отобранные данные из Таблицы значений в Массив структур для дальнейшей передачи в ПКО
ДокументыЗакреплениеЗаКафедрой = Неопределено;
Выполнить(Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой);
//Обходим отобранные данные и выгружаем с помощью функции ВыгрузитьПоПравилу
Для каждого Документ Из ДокументыЗакреплениеЗаКафедрой Цикл
ВыгрузитьПоПравилу(,,Документ,,"ЗакреплениеЗаКафедройИзВходящихДанных");
КонецЦикла;
//Отменяем стандартную выгрузку объекта
Отказ = Истина;
Большую часть этого обработчика, как вы можете видеть, занимает отбор данных необходимых для выгрузки. Тут и множество фильтров: по подразделениям, по видам расчетов и механизм разбиения одного документа «источника» на несколько документов «приемника». Если коротко, то в данном примере табличная часть одного документа «источника» разносится по табличным частям нескольких документов «приемника», а значением разбиения данных является значение Подразделения.
Для удобства работы при отборе данных мы использовали Таблицу значений, наш алгоритм подразумевает ПКО с получением данных из «входящих данных», которые будут переданы в функцию ВыгрузитьПоПравилу, поэтому в соответсвующем алгоритме мы производим перевод Таблицы значений в Массив структур.
На следующем шаге мы обходим отобранные данные и вот уже в этом месте мы используем нашу функцию ВыгрузитьПоПравилу. Параметр Документ, здесь является структурой, которую мы передаем как входящие данные, а второй передаваемый нами параметр, это название ПКО, которому мы передаем наши данные.
В самом конце мы отменяем выполнение стандартной выгрузки, так как все необходимые данные связанные с объектом выборки мы уже выгрузили.
Тем самым мы сохраняем функциональность регистрации изменений — документ изменился, зарегистрировался для выгрузки, данные выгрузили. И в то же время делаем произвольный отбор необходимых нам данных.
В ПКО в этом случае для свойств необходимо указать, что они получаются из «Входящих данных».
Выгрузка Регистр сведений -> Регистр сведений с зависимостью от переноса другого объекта.
Типичным примером такой задачи является перенос контактной информации физического лица. Простейший способ решения задачи — это перенос всех «Физических лиц» и всего регистра сведений «Контактная информация» физических лиц. Что делать если нам необходимо переносить не всех физических лиц? Например, только тех физических лиц, которые упоминаются в каком-либо переносимом нами документе. В таком случае, как известно, ПКС документа вызывает ПКО справочника «Физические лица» и тем самым обеспечивается перенос физических лиц упоминаемых в документе.
В переносе «Контактной информации» физических лиц в данной ситуации может помочь функция ВыгрузитьРегистр, очень похожая на функцию ВыгрузитьПоПравилу.
Хочу отметить, что потребность в использовании функции ВыгрузитьРегистр у меня появилась, когда я начал адаптировать правила под БСП уже отлаженные на обработке Универсальный обмен XML. Регистры через обработку спокойно выгружались с использованием функции ВыгрузитьПоПравилу, но БСП ни как не хотело правильно понимать такую выгрузку, в результате чего пришлось переписывать код через ВыгрузитьРегистр.
В обработчике»После выгрузки в файл» ПКО «Физические лица», пишем код следующего вида:
//////////////////////////////////////////////////////
//Выгрузим контактную информацию типа Адрес
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| КонтактнаяИнформация.Представление,
| КонтактнаяИнформация.Вид,
| КонтактнаяИнформация.Тип,
| КонтактнаяИнформация.Объект
|ИЗ
| РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
|ГДЕ
| КонтактнаяИнформация.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес)
| И КонтактнаяИнформация.Вид В (ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресФизЛица), ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресФизЛица))
| И КонтактнаяИнформация.Объект = &Объект";
Запрос.УстановитьПараметр("Объект", Источник);
Выборка = Запрос.Выполнить ().Выбрать ();
Пока Выборка.Следующий () Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "Объект";
СтрокаОтбора.Значение = Выборка.Объект;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Представление");
Строки.Колонки.Добавить("Вид");
Строки.Колонки.Добавить("Тип");
Строки.Колонки.Добавить("Объект");
Строка = Строки.Добавить();
Строка.Представление = Выборка.Представление;
Строка.Вид = Выборка.Вид;
Строка.Тип = Выборка.Тип;
Строка.Объект = Выборка.Объект;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,,"КонтактнаяИнформация");
КонецЦикла;
Как видно, в коде отбираются все записи регистра сведений, относящиеся к текущему выгружаемому Физическому лицу, а полученная выборка обходится в цикле.
Для того, чтобы выгрузить записи регистра сведений через функцию ВыгрузитьРегистр, необходимо подготовить структуру НаборЗаписей, которая имеет два поля: Отбор и Строки.
ПКО «КонтактнаяИнформация» имеет следующий вид:
Выгрузка Табличная часть -> Регистр сведений.
По своему решению задача аналогична предыдущей. С той лишь разницей, что информацию для регистра сведений «приемника» брать придется из других объектов «источника», а точнее табличной части того объекта, который на данный момент выгружается. Если бы на стороне «приемника» была так же табличная часть, то задача легко решалась бы в виде ПГКС. Поэтому снова воспользуемся функцией ВыгрузитьРегистр.
Рассмотрим пример переноса информации по ученым степеням Физического лица. Опять создаем код в обработчике «После выгрузки в файл» ПКО «Физические лица». Так как задача аналогичная предыдущей привожу только, код отбора и выгрузки данных из обработчика:
///////////////////////////////////////////////////////
//Выгрузим информацию по ученым степеням
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ФизическиеЛицаУченыеСтепени.Ссылка,
| ФизическиеЛицаУченыеСтепени.УченаяСтепень,
| ФизическиеЛицаУченыеСтепени.ОтрасльНауки,
| ФизическиеЛицаУченыеСтепени.ДипломСерияНомер,
| ФизическиеЛицаУченыеСтепени.ДатаПрисужденияУченойСтепени
|ИЗ
| Справочник.ФизическиеЛица.УченыеСтепени КАК ФизическиеЛицаУченыеСтепени
|ГДЕ
| ФизическиеЛицаУченыеСтепени.Ссылка = &ФизЛицо";
Запрос.УстановитьПараметр("ФизЛицо", Источник);
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "ФизическоеЛицо";
СтрокаОтбора.Значение = Выборка.Ссылка;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Ссылка");
Строки.Колонки.Добавить("ФизическоеЛицо");
Строки.Колонки.Добавить("УченаяСтепень");
Строки.Колонки.Добавить("Специальность");
Строки.Колонки.Добавить("НомерДиплома");
Строки.Колонки.Добавить("Период");
Строка = Строки.Добавить();
Строка.ФизическоеЛицо = Выборка.Ссылка;
Строка.УченаяСтепень = Выборка.УченаяСтепень;
Строка.Специальность = Выборка.ОтрасльНауки;
Строка.НомерДиплома = Выборка.ДипломСерияНомер;
Строка.Период = Выборка.ДатаПрисужденияУченойСтепени;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,Истина,"УченыеСтепениФизическихЛиц");
КонецЦикла;
Выгрузка Табличная часть -> Документ.
Предположим, в «источнике» информация для переноса хранится в менее детализированном виде, чем в приемнике, но достаточном для переноса. Например, мной решалась задача по переносу информации об образовании физических лиц из ЗиКБУ в Университет. Понятно, что на стороне кадровой программы нужна минимальная информация об образовании физических лиц, главное что сотрудник обладает необходимой квалификацией и хватит. А вот на стороне университета, информация об образовании, а точнее о дипломах хранится куда более подробно, в связи со спецификой учереждения.
И опять задача решается, при помощи все той же функции ВыгрузитьПоПравилу.
Вот пример выгрузки Дипломов физических лиц. Все тот же обработчик «После выгрузки в файл» ПКО «Физические лица», пишем следующий код:
///////////////////////////////////////////////////////
//Выгрузим образование Физического лица
Запрос = Новый Запрос;
Запрос.Текст = "ВЫБРАТЬ
| ФизическиеЛицаОбразование.Ссылка КАК Студент,
| ФизическиеЛицаОбразование.ВидОбразования,
| ФизическиеЛицаОбразование.УчебноеЗаведение,
| ФизическиеЛицаОбразование.Специальность.Наименование КАК Специальность,
| ФизическиеЛицаОбразование.Диплом,
| ФизическиеЛицаОбразование.ГодОкончания,
| ФизическиеЛицаОбразование.Квалификация
|ИЗ
| Справочник.ФизическиеЛица.Образование КАК ФизическиеЛицаОбразование
|ГДЕ
| ФизическиеЛицаОбразование.Ссылка = &ФизЛицо";
Запрос.УстановитьПараметр("ФизЛицо", Источник);
РезультатЗапроса = Запрос.Выполнить();
ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
ВходящиеДанные = Новый Структура;
ВходящиеДанные.Вставить("Студент", ВыборкаДетальныеЗаписи.Студент);
ВходящиеДанные.Вставить("ВидОбразования", ВыборкаДетальныеЗаписи.ВидОбразования);
ВходящиеДанные.Вставить("ОбразовательноеУчреждениеПриОкончании", ВыборкаДетальныеЗаписи.УчебноеЗаведение);
ВходящиеДанные.Вставить("Специальность", ВыборкаДетальныеЗаписи.Специальность);
СерияНомерДиплома = ВыборкаДетальныеЗаписи.Диплом;
СерияДиплома = "";
НомерДиплома = "";
Выполнить(Алгоритмы.ПолучитьСериюИНомер);
ВходящиеДанные.Вставить("СерияДиплома", СерияДиплома);
ВходящиеДанные.Вставить("НомерДиплома", НомерДиплома);
Если НЕ ВыборкаДетальныеЗаписи.ГодОкончания = 0 Тогда
ВходящиеДанные.Вставить("ГодЗавершения", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
Иначе
ВходящиеДанные.Вставить("ГодЗавершения", Дата("00010101"));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата("00010101"));
КонецЕсли;
ВходящиеДанные.Вставить("Квалификация", ВыборкаДетальныеЗаписи.Квалификация);
ВыгрузитьПоПравилу(,,ВходящиеДанные,,"ДипломИзВходящихДанных");
КонецЦикла;
Тут мы отбираем данные из табличной части и формируем входящие данные для документа на стороне «приемника», после чего при помощи функции ВыгрузитьПоПравилу, передаем входящие данные ПКО ДипломИзВходящихДанных, которое имеет следующий вид:
В общем, как вы понимаете, можно приводить еще много вариаций перегрузок: справочники, документы, регистры. Главное, надо понимать, что не стоит фанатично бросаться на функции ВыгрузитьПоПравилу и ВыгрузитьРегистр.
Замечания по перегрузке.
1. У меня возникли сложности при использовании правил в БСП, в части выгрузки объектов по ссылкам, проблема решилась принудительной установкой параметра ВыгрузитьОбъект в значение Истина, для каждого ПКС ссылочного типа:
2. Надо помнить, что при выгрузке через указанные функции, зачастую отсутствует УникальныйИдентификатор объекта, например, когда объект для выгрузки собирается по частям в виде структуры ВходящихДанных, поэтому поиск по уникальному идентификатору придется отключить.
Подводим итоги. Когда использовать эти функции?
- Вам необходимо перегрузить объекты с сильно различной структурой или на стороне «источника» необходимо собирать объекты для выгрузки из разных объектов.
- Вам необходимо перегружать объекты с привязкой к выгрузке других объектов.
UPDATE от 11.11.2025
А что если оптимизировать выше написанное?
Пишу дополнение к статье, после оставленного пользователем TarasovAV комментария. Данный пользователь заметил, что можно оптимизировать выгрузку связанной информации, путем накопления списка тех объектов, информацию о которых надо будет отдельно выгружать, а потом через один запрос отобрать сразу всю информацию.
Описываю алгоритм предложенный вышеуказанным пользователем:
1. В правиле конвертации «После загрузки правил обмена», создается параметр типа ТаблицаЗначений, в который будет накапливаться список объектов, для которых в последующем будет выгружаться информация:
Параметры.Вставить("СписокФизическихЛиц", Новый ТаблицаЗначений());
Параметры.СписокФизическихЛиц.Колонки.Добавить("ФизическоеЛицо");
2. В в обработчике «После выгрузки» ПКО «Физические лица» (именно для них в примерах мы выгружаем контактные данные, образование и т.п.), мы пополняем нашу таблицу значений новым физическим лицом, проверяя перед этим, а не добавлено ли уже это физическое лицо в таблицу:
НайденнаяСтрока = Параметры.СписокФизическихЛиц.Найти(Источник);
Если НайденнаяСтрока = Неопределено Тогда
НоваяСтрока = Параметры.СписокФизическихЛиц.Добавить();
НоваяСтрока.ФизическоеЛицо = Источник;
КонецЕсли;
3. И финальным действием, будет непосредственная выгрузка информации, только уже с отбором по все физическим лицам сразу. Для этого все обработчики, что были приведены выше начиная, необходимо перенести в правило конвертации «После выгрузки данных», запросы же необходимо изменить, чтобы в них проверялось не равенство одному элементу, а вхождение значения реквизита в массив элементов:
Обратите внимание, как изменилась установка параметра запроса и проверка условия в запросе:
//...
"| И КонтактнаяИнформация.Объект В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
//...
Привожу полный код, исправленных ранее приведенных примеров:
//////////////////////////////////////////////////////
//Выгрузим контактную информацию типа Адрес
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| КонтактнаяИнформация.Представление,
| КонтактнаяИнформация.Вид,
| КонтактнаяИнформация.Тип,
| КонтактнаяИнформация.Объект
|ИЗ
| РегистрСведений.КонтактнаяИнформация КАК КонтактнаяИнформация
|ГДЕ
| КонтактнаяИнформация.Тип = ЗНАЧЕНИЕ(Перечисление.ТипыКонтактнойИнформации.Адрес)
| И КонтактнаяИнформация.Вид В (ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ЮрАдресФизЛица), ЗНАЧЕНИЕ(Справочник.ВидыКонтактнойИнформации.ФактАдресФизЛица))
| И КонтактнаяИнформация.Объект В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
Выборка = Запрос.Выполнить ().Выбрать ();
Пока Выборка.Следующий () Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "Объект";
СтрокаОтбора.Значение = Выборка.Объект;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Представление");
Строки.Колонки.Добавить("Вид");
Строки.Колонки.Добавить("Тип");
Строки.Колонки.Добавить("Объект");
Строка = Строки.Добавить();
Строка.Представление = Выборка.Представление;
Строка.Вид = Выборка.Вид;
Строка.Тип = Выборка.Тип;
Строка.Объект = Выборка.Объект;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,,"КонтактнаяИнформация");
КонецЦикла;
///////////////////////////////////////////////////////
//Выгрузим образование Физического лица
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ФизическиеЛицаОбразование.Ссылка КАК Студент,
| ФизическиеЛицаОбразование.ВидОбразования,
| ФизическиеЛицаОбразование.УчебноеЗаведение,
| ФизическиеЛицаОбразование.Специальность.Наименование КАК Специальность,
| ФизическиеЛицаОбразование.Диплом,
| ФизическиеЛицаОбразование.ГодОкончания,
| ФизическиеЛицаОбразование.Квалификация
|ИЗ
| Справочник.ФизическиеЛица.Образование КАК ФизическиеЛицаОбразование
|ГДЕ
| ФизическиеЛицаОбразование.Ссылка В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
РезультатЗапроса = Запрос.Выполнить();
ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();
Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
ВходящиеДанные = Новый Структура;
ВходящиеДанные.Вставить("Студент", ВыборкаДетальныеЗаписи.Студент);
ВходящиеДанные.Вставить("ВидОбразования", ВыборкаДетальныеЗаписи.ВидОбразования);
ВходящиеДанные.Вставить("ОбразовательноеУчреждениеПриОкончании", ВыборкаДетальныеЗаписи.УчебноеЗаведение);
ВходящиеДанные.Вставить("Специальность", ВыборкаДетальныеЗаписи.Специальность);
СерияНомерДиплома = ВыборкаДетальныеЗаписи.Диплом;
СерияДиплома = "";
НомерДиплома = "";
Выполнить(Алгоритмы.ПолучитьСериюИНомер);
ВходящиеДанные.Вставить("СерияДиплома", СерияДиплома);
ВходящиеДанные.Вставить("НомерДиплома", НомерДиплома);
Если НЕ ВыборкаДетальныеЗаписи.ГодОкончания = 0 Тогда
ВходящиеДанные.Вставить("ГодЗавершения", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата(ВыборкаДетальныеЗаписи.ГодОкончания, 1, 1));
Иначе
ВходящиеДанные.Вставить("ГодЗавершения", Дата("00010101"));
ВходящиеДанные.Вставить("ДатаВыдачи", Дата("00010101"));
КонецЕсли;
ВходящиеДанные.Вставить("Квалификация", ВыборкаДетальныеЗаписи.Квалификация);
ВыгрузитьПоПравилу(,,ВходящиеДанные,,"ДипломИзВходящихДанных");
КонецЦикла;
///////////////////////////////////////////////////////
//Выгрузим информацию по ученым степеням
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
| ФизическиеЛицаУченыеСтепени.Ссылка,
| ФизическиеЛицаУченыеСтепени.УченаяСтепень,
| ФизическиеЛицаУченыеСтепени.ОтрасльНауки,
| ФизическиеЛицаУченыеСтепени.ДипломСерияНомер,
| ФизическиеЛицаУченыеСтепени.ДатаПрисужденияУченойСтепени
|ИЗ
| Справочник.ФизическиеЛица.УченыеСтепени КАК ФизическиеЛицаУченыеСтепени
|ГДЕ
| ФизическиеЛицаУченыеСтепени.Ссылка В &СписокФизЛицо";
Запрос.УстановитьПараметр("СписокФизЛицо", Параметры.СписокФизическихЛиц.ВыгрузитьКолонку("ФизическоеЛицо"));
Выборка = Запрос.Выполнить().Выбрать();
Пока Выборка.Следующий() Цикл
Отбор = Новый ТаблицаЗначений;
Отбор.Колонки.Добавить ("Имя");
Отбор.Колонки.Добавить ("Значение");
Отбор.Колонки.Добавить ("Использование");
СтрокаОтбора = Отбор.Добавить ();
СтрокаОтбора.Имя = "ФизическоеЛицо";
СтрокаОтбора.Значение = Выборка.Ссылка;
СтрокаОтбора.Использование = Истина;
Строки = Новый ТаблицаЗначений;
Строки.Колонки.Добавить("Ссылка");
Строки.Колонки.Добавить("ФизическоеЛицо");
Строки.Колонки.Добавить("УченаяСтепень");
Строки.Колонки.Добавить("Специальность");
Строки.Колонки.Добавить("НомерДиплома");
Строки.Колонки.Добавить("Период");
Строка = Строки.Добавить();
Строка.ФизическоеЛицо = Выборка.Ссылка;
Строка.УченаяСтепень = Выборка.УченаяСтепень;
Строка.Специальность = Выборка.ОтрасльНауки;
Строка.НомерДиплома = Выборка.ДипломСерияНомер;
Строка.Период = Выборка.ДатаПрисужденияУченойСтепени;
НаборЗаписей = Новый Структура("Отбор, Строки");
НаборЗаписей.Отбор = Отбор;
НаборЗаписей.Строки = Строки;
ВыгрузитьРегистр(НаборЗаписей,,,Истина,"УченыеСтепениФизическихЛиц");
КонецЦикла;
Related Posts
Получение логина и пароля техподдержки 1С из базы
Класс для вывода отчета в Excel
Счет-фактура для УПП
Библиотека классов для создания внешней компоненты 1С на C#- Акт об оказании услуг (со скидками) — внешняя печатная форма для Управление торговлей 11.1.10.86
Прайс-лист с артикулом в отдельной колонке
Статья хорошая. Есть замечание по поводу 2 примера.
По поводу переноса контактной информации физ. лиц (и вообще связанной информации), на мой взгляд, лучше делать так (пример для переноса КИ физ. лиц):
1. В процедуре конвертации «После загрузки правил обмена» определить параметр «ТаблицаФизЛиц» типа таблица значений с колонкой «Объект».
2. В процедуре ПКО справочника физ. лиц «После выгрузки» заполняем таблицу из пункта 1: если физ лицо присутствует в таблице — ничего не делаем, иначе добавляем.
3. В процедуре конвертации «После выгрузки данных» формируем запрос по РС «КонтактнаяИнформация» с отбором по массиву объектов из параметра «ТаблицаФизЛиц». После этого применяем функцию «ВыгрузитьПоПравилу» или «ВыгрузитьРегистр» для каждой строки результата запроса.
В данном случае имеем всего лишь 1 запрос к БД, в вашем же случае имеем столько обращений к БД за контактной информацией, сколько раз выгружаются объекты с типом «Физические лица», плюс к этому в вашем случае одна и та же информация по контактной информации может быть выгружена несколько раз (если одно и тоже физ. лицо выгружается несколько раз), что ведет к увеличению файла обмена.
(1) TarasovAV, Согласен. Логичнее было бы сначала всех отобрать, а потом выгружать одним запросом. Как-то упустил этот нюанс)))
КД интересна тем, что для решения задачи можно выбрать разные решения, в принципе каждый из ваших примеров можно сделать по другому, и каждый из этих способов будет правильным, но все таки хотелось бы избегать запросы в циклах как в вашем решении.
(1) TarasovAV,
Делал немного по-другому- в ПВД ФЛ, т.к. регистрация ФЛ производилась и они выгружались по своему ПВД, а не по ссылке.
— ПВД.ПослеВыгрузки собирал ТЗ физлиц
— ПВД.ПослеОбработки делал запрос по этой ТЗ и выгружал паспортные данные и проч.
Но ваш вариант более универсален.
Хорошая статья, однозначно плюс.
Очень интересная статья, спасибо!
Но сейчас я бьюсь над зеркальной задачей.
В базу-приёмник приходят данные по справочнику и регистру сведений, в котором данные по этому элементу справочника. И у справочника указано, что, при выполнении определённых условий, он не должен записывать элемент. Т.е. элемент справочника, хотя и пришёл в файле обмена, не создаётся в базе. Но проблема в том, что по нему пришли записи регистра сведений. И их тоже не надо записывать, если элемент справочника не был записан. Как проверить, был он записан или не был, если сама эта запись регистра и создала этот элемент справочника в момент загрузки.
Проблема в том, что все описанные в статье приёмы работают на стороне источника, а у меня все эти условия проверяются в приёмнике, где уже нет ВыгрузитьПоПравилу() или ЗагрузитьПоПравилу()
Знает кто-нибудь, как победить эту проблему?
(6) for_sale, Если в регистре только элемент справочника является ссылочным или если другие ссылочные измерения и реквизиты Регистра по определению должны уже существовать в базе приемнике можно попробовать отключить перенос по ссылка, если объекты не находятся:
Вкладка ПКО Настройки — Не выгружать объекты свойств источника по ссылкам.. и посмотреть какие ошибки выдаст обмен, когда у регистра не будет заполнено измерение
Какие вы условия проверяете, что они должны быть обязательно проверяться на стороне приемника? Может как-то перестроить эти условия, чтобы они проверялись на стороне Источника и не закачивать в файл вообще элементы?
Очень интересная и главное полезная статья.
Есть несколько вопросов:
1. ДокументыЗакреплениеЗаКафедрой = Неопределено;
Далее идет цикл по ДокументыЗакреплениеЗаКафедрой. Но оно же «Неопределено»?
2. можно увидеть текст алгоритма Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой ?
Спасибо!
//Переводим отобранные данные из Таблицы значений в Массив структур для дальнейшей передачи в ПКО
ДокументыЗакреплениеЗаКафедрой = Неопределено;
Выполнить(Алгоритмы.ПереводТаблицыЗначенийВМассивЗакреплениеЗаКафедрой);
//Обходим отобранные данные и выгружаем с помощью функции ВыгрузитьПоПравилу
Для каждого Документ Из ДокументыЗакреплениеЗаКафедрой Цикл
ВыгрузитьПоПравилу(,,Документ,,»ЗакреплениеЗаКафедройИзВходящихДанных»);
КонецЦикла;
//Отменяем стандартную выгрузку объекта
(8) Yuri1C, ДокументыЗакреплениеЗаКафедрой, как раз в Алгоритме Перевода из ТЗ в Массив и заполняется.
В том алгоритме каждая строка ТЗ переводится в структуру с соответствующими ключевыми полями, и добавляется в массив, т.е. вместо ТЗ получается массив структур.
Сейчас этих правил нет под рукой.
Подскажите, пожалуйста!
в первом пункте: Выгрузка произвольной выборки данных через стандартную выборку с регистрацией объекта источника.
Все получилось. один вопрос. На последней картинке перед вторым пунктом «Выгрузка Регистр сведений -> Регистр сведений с зависимостью от переноса другого объекта.» показано, но непонятно как сделать. Нужно загрузить данные именно в табличную часть, какой там код?
Добрый день!
Подскажите пож-та как получить значение выгруженное с помощью этой функции?
Выгружаю т.ч. документа и в ней собираю справочник (объекта такого нет):
и т.д. далее :
объект выгружается в справочник успешно и вот теперь нужно получить и записать ссылку:
!!! но так не работает!
Я правильно понимаю, что в данных примерах, при использовании функции «ВыгрузитьПоПравилу()» как бы можно вообще не использовать ПВД? Ведь мы и так указываем что и по какому ПКО выгрузить. Так?
(12) slawanix, Для тех данных которые выгружаются с помощью этой функции ПВД, не то чтобы можно не использовать, его не нужно использовать. Потому что все данные будут выгружены через функцию, а через ПВД пойдут грузиться все зарегистрированные к выгрузке данные, т.е. могут выгрузиться лишние данные, не предусмотренные алгоритмом, который подразумевает использование функции ВыгрузитьПоПравилу().
(13) ок. Спасибо. И у меня возник еще вот такой вопрос, сейчас решаю свою задачу методами, взятыми на вооружение из статьи и нужно мне динамически добавить свой параметр типа ТЗ и заполнить его в обработчиках ПВД или ПКО, не важно. Делаю как в статье :
Параметры.СписокФизическихЛиц.Колонки.Добавить(«ФизическоеЛицо»);
Но за одним исключением: мне нужно чтобы этот параметр был доступен для чтения в обработчике «После загрузки данных» конвертации. То есть как будто я создал параметр в форме конвертации на закладке «Параметры» и поставил ему галку При загрузке. Как это можно сделать? Мне нужны эти параметры уже для их использования на стороне приемника.
Добавлю, что параметр создается нормально и заполняется тоже как надо. Но прочитать его после загрузки данных в приемник я не могу. Не доступен.
а можно увидеть ПКО «УченыеСтепениФизическихЛиц». Какой тип источника? Если не указывать тип источника и в ПКО структуру конвертировать в РС, то получаем следующую ошибку:
{Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(9676)}: Ошибка в обработчике события ПередОбработкойВыгрузки группы свойств ПКО = ГруппыПользователей (Пользователи -> Группы пользователей) ПКГС = 4 (—> Состав) Объект = ОТР (Справочник объект: Пользователи) Обработчик = ПередОбработкойВыгрузкиГруппыСвойств ОписаниеОшибки = Поле объекта не обнаружено (Ссылка) ПозицияМодуля = Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(11286) КСообщенияОбОшибках = 48 ВызватьИсключение СтрокаСообщенияОбОшибке;Показать
если имеем источник с пустым типом, то механизм в модуле объекта «КонвертацияОбъектовИнформационныхБаз» думает, что выгружается ссылочный объект. Можно ли обойти данную проблему без правки кода БСП?
а у меня ругается, не находит функцию «ВыгрузитьРегистр»
(15)
Столкнулся с аналогичной проблемой, решил путём добавления колонки с именем «Ссылка» в строки набора записей.
Рабочий пример для обработчика ПКО «После выгрузки в файл»
Показать
Добрый день, подскажите как можно сделать следующее: в источнике получаем запросом таблицу проводок (запросом), а в приемнике ее необходимо загрузить в документ Операция (бухгалтерия)??? поможет ли сделать ВыгрузитьПоПравилу???
Спасибо, статья прям направила на путь истинный!
Хотелось бы еще аналогичную со стороны загрузки, какие преобразования и как выполняются. Потому что иногда в источнике есть данные, а в приемник их нужно преобразовать. Значение реквизита справочника, например, в строковое значение.
Спасибо за труд. Почерпнул для себя полезное. Поставлю +
Ошибка в обработчике события ПослеВыгрузкиДанных (конвертация)
Обработчик = ПослеВыгрузкиДанных (конвертация)
ОписаниеОшибки = Ошибка компиляции при вычислении выражения или выполнении фрагмента кода: {(1,9)}: Переменная не определена (Источник)
ПозицияМодуля = Обработка.УниверсальныйОбменДаннымиXML.МодульОбъекта(12962)
КодСообщения = 63
Сначала сделала как в статье. Работает, но очень долго.
Сделала с учетом апдейт, ошибка выше, что я сделала не так(?
(21)Очень похоже на то, что в том обработчике каком вы пишите код, нет переменной Источник
(22) да с этим разобралась.
теперь дургая тема, как значение Организации передать в приемник
если можете, помогите)))
…И еще, вопрос ко всем кто «втыкнул» в эту тему: почему у автора «гранула обмена» (набор записей) для ВыгрузитьРегистр — это каждая ученая степень??? (последний пример)
Ведь отбор установили на уровне физ. лица!
…
…
Не правильнее ли было в запрос добавить итоги по физ-лицу, и сделать обход двумя вложенными циклами, «отправляя» набор записей в ВыгрузитьРегистр во внешнем цикле (по физ. лицу), а не каждую ученую степень…
(24) …сам себе же и отвечу: видимо, у автора (и тех, у кого «все получилось») совсем другая «кухня» КД, в которой все «варится» — т.е., та самая встроенная универсальная обработка, которая осуществляет функциональность конвертации. У меня это ОбменДаннымиXML.
Так вот, при раскуривании процедуры ВыгрузитьРегистр стало ясно, что никакую структуру(«Отбор, Строки») она не поймет. Только НаборЗаписей регистра:
Т.е., в этой версии «кухни», эта функция годиться ТОЛЬКО для переноса регистра в регистр. И без доработки (неизвестно заранее, насколько глубокой — например, после того как я изменил выше на НаборЗаписейДляВыгрузки.СТРОКИ — полезли новые ошибки) не «взлетит».
П.С. Тут, кстати, пример, который ответил на мой следующий вопрос про «гранулярность» применения этой функции:
Все-таки автор не вполне корректно применил функцию ВыгрузитьРегистр.
П.П.С.
А вот тут почерпнул для себя рабочую, в итоге, идею, как перенести таб.часть в регистр сведений:
Правда, там не учтен (или не раскрыт) один важный нЬюанс: при УДАЛЕНИИ записи табчасти в источнике, это удаление никак не отразится в приемнике — там запись останется!! Надо что-то мутить в правилах на стороне приемника…Вот над этим сейчас работаю — если добью, постараюсь поделиться.
Здравствуйте! Пожалуйста, помогите!
В «После загрузки правил обмена» написал:
В «После выгрузки» у справочника «Сотрудники» написал:
Показать
С помощью оператора «Сообщить» я узнал, что параметр заполняется как надо. Однако в XML-файл параметр «СписокСотрудников» не попадает. Использую «Универсальный обмен данных». Выгрузку делаю из ЗУП 3.1.8.155.
В чем может быть причина?
(28)Попробуйте параметр объявить в самих правилах и выставить свойство используется в при загрузке. А в «После загрузки правил обмена», уже указать, что это таблица значений.
(29) Увы, чуда не произошло. Параметр заполняется как надо, но в XML-файл не попадает.
(30)Передавать при выгрузке пробовали еще поставить?
Возможно это означает, что параметр будет помещен в файл выгрузки, когда будут выгружать данные.
(31) Не помогло.
Добрый день. Не подскажите почему у меня Функция ВыгрузитьПоПравилу не работает в БСП.
Выходит Ошибка при ЗаполнитьЗначениеСвойств(*, Источник) — где источник = Неопределенно выходит. И поэтому выходит ошибка во втором параметре. Хотя Источник мне нет необходимости выгружать, если у меня все через ВходящиеДанные выгружается.
Помогите с этим вопросом разобраться. Не могу узел из-за этого добавить
(33) А как вы собираетесь использовать функцию ЗаполнитьЗначениеСвойств, если вы не указываете откуда эта функция должна заполнять свойства?
(34) ПервыйПараметр — *, Второй — Источник. Ругается именно на «Источник»…
(34) И эта функция Типовая в КомплекснойАвтоматизации в Обрваботке «КонвертацияОбъектовИнформационнойБазы.
вот сама ошибка
{Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(4283)}: Ошибка в обработчике события ПередВыгрузкойОбъекта
ПВД = ЗаказКлиента
Объект = Заказ клиента 00АШ-000177 от 17.01.2019 9:49:00 (Документ объект: Заказ клиента)
Обработчик = ПередВыгрузкойОбъектаВыборки
ОписаниеОшибки = Ошибка при вызове метода контекста (ЗаполнитьЗначенияСвойств): Недопустимое значение параметра (параметр номер ‘2’)
ПозицияМодуля = Обработка.КонвертацияОбъектовИнформационныхБаз.МодульОбъекта(324)
КСообщенияОбОшибках = 33
ВызватьИсключение СтрокаСообщенияОбОшибке;
(36) Как мне кажется это не типовая функция в обработке, а это ваш код, который вы вызываете в обработчике ПередВыгрузкойОбъектаВыборки…
Проверяйте код в этом обработчике. Вам же пишет Недопустимое значение параметра номер 2.
Вы сказали что Источник = Неопределено, ЭТО не правильно. Нельзя передавать неопределенный Источник. Там должен быть объект с свойствами.
(38) ошибка именно в обработке которая типовая. Номер строки модуля указывает туда. Даже в самой статье указано… Что если все реквизиты документа получать из входящих данных тогда можно источник не указывать…
(38)
По своему решению задача аналогична предыдущей. С той лишь разницей, что информацию для регистра сведений «приемника» брать придется из других объектов «источника», а точнее табличной части того объекта, который на данный момент выгружается. Если бы на стороне «приемника» была так же табличная часть, то задача легко решалась бы в виде ПГКС. Поэтому снова воспользуемся функцией ВыгрузитьРегистр.
Надеюсь это решение моей проблемы.
Может я чего не так понимаю, но.
В первом примере автор пишет:
и пихает в него свой запрос выборки данных и потом в цикле выгружает данные по этой выгрузку..
Причем подчеркивает, что нужно использовать именно этот обработчик (впрочем, никак не объясняя, почему).
Однако в описании данного обработчика сказано:
Условия возникновения события
Событие выполняется при получении очередного объекта из выборки, до передачи этого объекта правилу конвертации.
соответственно если сделать так как говорит автор, то получим получение нашей выборки много много раз — столько раз, сколько возвращается объектов из стандартной выборки. То что мы в конце отменили стандартную выгрузку объекта вовсе не отменяет саму стандартную выборку.