Как использовать ПоказатьВопрос в обработчике формы ПередЗаписью

24.09.2019 33 Comments

Практика программирования, Разработка

    Вопрос
В данной статье будет рассмотрен пример, как без модальных методов задать вопрос пользователю в обработчике формы ПередЗаписью. В ИТС (http://its.1c.ru/docs/v8nonmodal/) есть конкретные примеры по уходу от модальных окон, но в теме «Вопрос в обработчике формы ПередЗаписью» нет конкретного примера, а есть только общая информация, куда надо двигаться при решении данной задачи.

Вступление

Для чего вообще стоит отказываться от модальности и, например, Вопрос заменять на ПоказатьВопрос?  Всё дело в том, что больше года назад 1С-ники объявили «войну» модальным окнам. Исключение составляют только те, у кого самописная конфигурация, работа с которой не будет вестись на IPad, в режиме сервиса или с помощью веб-клиента. А если у вас обычная Бухгалтерия 3.0 и вы не собираетесь бухгалтеру давать доступ к базе через IPad, всё равно вам придётся заменить все модальные методы на немодальные, т.к. рано или поздно «Режим использования модальности» станет «Не использовать»!

Что же думает по предлагаемому вопросу специалисты фирмы 1С? Для начала можно посмотреть на тему «Вопрос в обработчике формы ПередЗакрытием»:

Особенность диалога с пользователем в этом (и многих других) обработчиках заключается в том, что в зависимости от реакции пользователя принимается решение: продолжать дальнейшие действия, или отказаться от них. Для этого используется параметр процедуры Отказ. При одном ответе пользователя мы отказываемся от продолжения (Отказ = Истина). При другом ответе пользователя — продолжаем дальнейшие действия.

В данном случае сложность заключается в том, что ответ пользователя мы узнаем уже после того, как выйдем из контекста этого обработчика. В процедуре, обрабатывающей оповещение. А параметр Отказ нужно установить именно в этом обработчике.

Поэтому мы действуем в два приёма:

В первый раз безусловно отменяем дальнейшие действия (Отказ = Истина) и выводим вопрос пользователю;

В обработчике оповещения, в зависимости от реакции пользователя, либо снова программно закрываем форму, либо ничего не делаем.

Проблема заключается в том, что обработчик ПередЗакрытием будет выполнен два раза. И чтобы отличить первое его выполнение от второго (когда ответ пользователя уже известен) мы используем клиентскую переменную ВыполняетсяЗакрытие в качестве флага.

В первый проход её значение равно Ложь, и это значит, что нужно отказаться от закрытия и задать вопрос. Во второй проход её значение равно Истина, и это значит, что вопрос задавать не надо:

&НаКлиенте
Перем ВыполняетсяЗакрытие;

&НаКлиенте
Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)

Если Не ВыполняетсяЗакрытие Тогда
Отказ=Истина;
ПоказатьВопрос(Новый ОписаниеОповещения("ПередЗакрытиемЗавершение", ЭтотОбъект),
"Закрывать форму?", РежимДиалогаВопрос.ДаНет);
КонецЕсли;

КонецПроцедуры

&НаКлиенте
Процедура ПередЗакрытиемЗавершение(РезультатВопроса, ПараметрыЗаписи) Экспорт

Если РезультатВопроса = КодВозвратаДиалога.Да Тогда
ВыполняетсяЗакрытие = Истина;
Закрыть();
КонецЕсли;

КонецПроцедуры

ВыполняетсяЗакрытие = Ложь;

Этот пример схож с нашей темой и очень часто на него ссылаются в теме «ПоказатьВопрос в обработчике формы ПередЗаписью»:

В обработчике события формы ПередЗаписью также может возникнуть потребность задать вопрос. Как и в предыдущем примере. Однако здесь вопрос так просто не решается. Отличие заключается в следующем.

В предыдущем примере, оказываясь в обработчике ПередЗакрытием, мы однозначно знали действие, которое должно быть выполнено. Это закрытие формы. Поэтому в обработке оповещения мы смело писали Закрыть().

Но в обработчике ПередЗаписью мы такой однозначной информации не имеем. В этом обработчике мы можем оказаться по двум причинам: если пользователь нажал Записать, или если он нажал Записать и закрыть. То есть дальнейший сценарий действий нам неизвестен. Определить его стандартными способами, находясь внутри этого обработчика, мы не можем.

Поэтому тут можно предложить три варианта, но все они, к сожалению, обладают недостатками:

* Изменить логику прикладного решения так, чтобы не было диалога с пользователем в этом обработчике. Это не всегда возможно;

* В обработке оповещения с помощью собственной блокирующей формы задавать пользователю развернутый вопрос, предполагающий точное описание дальнейших действий: Отказаться?, Только записать?, Записать и закрыть? Это может выглядеть не очень красиво, ведь пользователь уже нажал "Записать и закрыть", а его опять об этом спрашивают;

* Не использовать стандартные команды формы Записать, "Записать и закрыть". Вместо них создать собственные команды, в которых и выполнять необходимые алгоритмы. Создание собственных команд потребует дополнительных трудозатрат.

Задача сложная, поэтому разработчики при задании вопроса ПередЗаписью, в первую очередь рекомендуют отказаться от этой идеи…

Дальше предлагают задать вопрос с множеством вариантов: «Отказаться, Только записать, Записать и закрыть». Помимо описанного минуса (пользователь и так уже заранее выбрать вариант, а его тут ещё раз спрашивают) есть ещё: в ПередЗаписью программа могла попасть и из «Отмена проведения». Т.е. надо добавлять ещё кнопку? Мне кажется этот вариант некрасивым.

Остаётся только третий вариант с использованием нестандартных команд формы. Его мы и будем реализовывать. И не стандартной командой у нас будет только «Провести и закрыть». Как и в примере к теме «Вопрос в обработчике формы ПередЗакрытием», нам придётся при первом заходе давать Отказ = Истина, и только во втором заходе выполнять реальную запись. И ещё нам где-то нужно будет запоминать, что это именно второй заход в процедуру «ПередЗаписью». 1С-ники предложили это сделать через общую клиентскую переменную, в рассматриваемом примере это можно сделать через ПараметрыЗаписи.

 

Пример использования ПоказатьВопрос в обработчике формы ПередЗаписью

1. Сначала нам нужно убрать стандартную команду «Провести и закрыть» из формы и создать свою команду и кнопку.

1.А. Если у вас уже кнопка «Провести и закрыть» не типовая – вам повезло, можете смело приступать к п. 2.

1.Б. Стандартная команда убирается через Свойства формы – Состав команд – Снимаем ненужную команду. Как добавлять команду и кнопку на форму, я не буду описывать, только напомню, что кнопку «Провести и закрыть» необходимо сделать кнопкой по умолчанию.

1.В. Теперь вариант сложнее в реализации, но проще в сопровождении типовой конфигурации. Практически в каждом обновлении Бухгалтерии программисты умудряются изменить 10-50% форм документов, поэтому в типовой конфигурации для сопровождения проще кодом убрать стандартную кнопку и добавить свою команду и кнопку.

Для начала в обработчике формы «ПриОткрытии» необходимо убрать стандартную кнопку «ПровестиИЗакрыть».

Элементы.ФормаПровестиИЗакрыть.Видимость = Ложь;

Замечание: у пользователя с большими ограничениями к документу в платформе 8.3.7 вообще не появляется кнопка "Провести и закрыть". Поэтому для платформы 8.3.7 корректней писать код:

Если Элементы.Найти("ФормаПровестиИЗакрыть")<>Неопределено Тогда
Элементы.ФормаПровестиИЗакрыть.Видимость = Ложь;
КонецЕсли;

Дальше добавляем команду и кнопку в обработчике формы «ПриСозданииНаСервере»::

НоваяКоманда1 = ЭтаФорма.Команды.Добавить("ПровестиИЗакрыть2");
НоваяКоманда1.Действие = "ПровестиИЗакрыть";
НовыйЭлемент = Элементы.Добавить("ФормаПровестиИЗакрыть2" , Тип("КнопкаФормы"), Элементы.ФормаКоманднаяПанель);
НовыйЭлемент.Заголовок = "Провести и закрыть";
НовыйЭлемент.ИмяКоманды = НоваяКоманда1.Имя;
НовыйЭлемент.КнопкаПоУмолчанию = Истина;
Элементы.Переместить(НовыйЭлемент,НовыйЭлемент.Родитель,Элементы.ГруппаКнопкиКоманднойПанели);

Соответственно в этом коде заложены типовые наименования для ФормаДокументаОбщая документа «Поступление (акты, накладные)» (например Элементы.ГруппаКнопкиКоманднойПанели), которые в каждом конкретном случае необходимо будет менять на свои.

2. Дальше нам нужно в процедуру на новую кнопку «Провести и закрыть» написать код:

&НаКлиенте
Процедура ПровестиИЗакрыть(Команда)

ПараметрыЗаписи = Новый Структура();
ПараметрыЗаписи.Вставить("РежимЗаписи", ПредопределенноеЗначение("РежимЗаписиДокумента.Проведение"));
ПараметрыЗаписи.Вставить("Закрыть", Истина);

Если Записать(ПараметрыЗаписи) Тогда
Закрыть();
КонецЕсли;

КонецПроцедуры

Как я писал выше, мы будем обмениваться информацией между нашими процедурами через ПараметрыЗаписи. В ПередЗаписью мы не знаем, нажали мы «Записать», «Провести» или «Провести и закрыть», для этого в параметрах мы передаём параметр Закрыть. Если в параметрах записи есть этот параметр, значит надо закрыть форму после успешной записи.

3. Допустим, нам надо задавать вопрос не всегда, а только когда документ проведён. Теперь мы в процедуру «ПередЗаписью» добавляем (если эта процедура не существовала – создаём) новый код:

Если Не ПараметрыЗаписи.Свойство("ВопросЗадан") И Объект.Проведен Тогда
Отказ = Истина;
Оповещение = Новый ОписаниеОповещения("ПоказатьВопросЗавершение", ЭтаФорма, ПараметрыЗаписи);
ТекстВопроса = "Данный документ уже проведён. Вы действительно хотите перепровести или отменить проведение документа?";
ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНет, 20, КодВозвратаДиалога.Нет,, КодВозвратаДиалога.Нет);
КонецЕсли;

Свойство «ВопросЗадан» мы будем заполнять в оповещении, чтобы узнавать, когда в процедуру «ПередЗаписью» мы зашли во второй раз (в примере 1С в процедуре ПередЗакрытием это делалось через переменную «ВыполняетсяЗакрытие»). Другими словами: в структуре «ПараметрыЗаписи» есть свойство «ВопросЗадан», значит, вопрос уже задавали, и пользователь уже ответил утвердительно, если же свойства нет, значит, в процедуре «ПередЗаписью» мы первый раз.

После метода ПоказатьВопрос можно ещё написать «Возврат», если у вас есть ещё какой-то код в процедуре «ПередЗаписью», выполняемый после вопроса.

4. Создаём процедуру «ПоказатьВопросЗавершение», в которую программа будет входить, когда пользователь ответит на вопрос (или произошёл таймаут).

&НаКлиенте
Процедура ПоказатьВопросЗавершение(Результат, ПараметрыЗаписи) Экспорт

Если Результат = КодВозвратаДиалога.Да Тогда
ПараметрыЗаписи.Вставить("ВопросЗадан", Истина);
Если Записать(ПараметрыЗаписи) И ПараметрыЗаписи.Свойство("Закрыть") Тогда
Закрыть();
КонецЕсли;
КонецЕсли;

КонецПроцедуры

В этой процедуре мы и используем переданное ранее свойство «Закрыть». Если свойства нет, значит, закрывать не надо. 

5. Теперь нам надо обработать нажатие «крестика» пользователем. Для этого нам нужна обработчик формы «ПередЗакрытием». Если его нет, то его можно создать на форме «ручками» или программно в обработчике «ПриСозданииНаСервере»:

ЭтаФорма.УстановитьДействие("ПередЗакрытием","ПередЗакрытием");

Далее добавляем код в ПередЗакрытием и создаём ещё одну процедуру:

&НаКлиенте
Процедура ПередЗакрытием(Отказ, СтандартнаяОбработка)

Если Модифицированность Тогда
Отказ = Истина;
ТекстВопроса = НСтр("ru = 'Данные были изменены. Сохранить изменения?'");
Оповещение = Новый ОписаниеОповещения("ВопросПередЗакрытиемЗавершение", ЭтотОбъект);
ПоказатьВопрос(Оповещение, ТекстВопроса, РежимДиалогаВопрос.ДаНетОтмена);
КонецЕсли;

КонецПроцедуры

&НаКлиенте
Процедура ВопросПередЗакрытиемЗавершение(Результат, ДополнительныеПараметры) Экспорт

Если Результат = КодВозвратаДиалога.Да Тогда
ПараметрыЗаписи = Новый Структура();
ПараметрыЗаписи.Вставить("Закрыть", Истина);
Если Записать(ПараметрыЗаписи) Тогда
Закрыть();
КонецЕсли;
ИначеЕсли Результат = КодВозвратаДиалога.Нет Тогда
Модифицированность = Ложь;
Закрыть();
КонецЕсли;

КонецПроцедуры

Получается, что пользователь когда нажал крестик ответит сначала на вопрос «Сохранить изменения?» и потом задастся ещё вопрос, который у вас прописан «ПередЗаписью». Если вас это не устраивает, можно передать параметр «ВопросЗадан» в «ВопросПередЗакрытиемЗавершение» и тогда второго вопроса не будет.

 

Вопрос против ПоказатьВопрос

А как бы мы решили задачу, если бы можно было использовать модальные вызовы? А очень просто, мы бы написали в процедуре «ПередЗаписью» следующий код:

Если Объект.Проведен Тогда
ТекстВопроса = "Данный документ уже проведён. Вы действительно хотите перепровести или отменить проведение документа?";
Ответ = Вопрос(ТекстВопроса,РежимДиалогаВопрос.ДаНет,20,КодВозвратаДиалога.Нет,,КодВозвратаДиалога.Нет);
Если Не Ответ=КодВозвратаДиалога.Да Тогда
Отказ = Истина;
Возврат;
КонецЕсли;
КонецЕсли;

И всё! Никаких «заморочек» типа «А что пользователь нажал: Провести или ПровестиИЗакрыть?». И ещё надо будет отработать нажатие крестика в «ПередЗакрытием».

 

 

P.s.

Изначально похожий код я реализовывал у себя в Бухгалтерии предприятия 3.0. Задача заключалась в следующем: при определённом наборе условий (это не одно условие Объект.Проведен, как указано в примере в данной публикации) из ФормаДокументаОбщая документа ПоступлениеТоваровУслуг спрашивать дополнительно подтверждения его действий. Ниже перечислены нюансы, которые мне не пришлось обходить, т.к. не подпадали под задачу.

В обработчик формы «ПередЗаписью» программа не заходит, если: 1) пользователь нажал на кнопку «Пометить на удаление / снять пометку»; 2) если пользователь нажал на не проведённом документе кнопку «ДТ/КТ».  И это не всё: если вы на форме документа создали всё, как я написал, и пользователь из формы списка перепроведёт документ – то никаких вопросов программа ему не задаст. Необходимо все интересующие вас кнопки на форме списка заменять на свои и отслеживать действия пользователя. Ещё у документа может быть не одна форма документа, а несколько (например, документ ПоступлениеТоваровУслуг в БП 3.0, где 3 формы: общая, товары и услуги). В каждой форме документа надо написать много кода…

В связи с кучей нюансов остаётся актуальным первый совет от 1С (который сначала, без подробного вникания в задачу, может вызвать улыбку): «Изменить логику прикладного решения так, чтобы не было диалога с пользователем в этом обработчике».

 

Related Posts

33 Comments

  1. Fragster

    Сколько уже лучей любви послано в торону 1с по поводу этой «асинхронности». по факту ни для пользователя, ни для программиста. Более того, если попробовать использовать асинхронность, например для параллельного помещения файлов, или нескольких подтверждений пользователя — легко получаем вылеты платформы.

    Всю эту «асинхронность ради гуглохрома и айпада» можно было от прикладных 1с программистов спрятать, что обеспечило бы намного более высокую обратную совместимость для внешних обработок и подсистем.

    Reply ↓
  2. klinval

    (1) Fragster, А что поделать, приходится исходить (кодить) из того что дают…

    «Лучи любви» очень обильно можно наблюдать в статье http://infostart.ru/public/302910/ (не везде я со статьёй согласен, но в целом автор пишет верно). Кому интересна тема модальности — рекомендую прочитать статью и коменты под ней.

    Reply ↓
  3. webester

    (1)

    Сколько уже лучей любви послано в торону 1с по поводу этой «асинхронности»

    Лучи добра, заключались в основном в «опять надо писать по новому, почему нельзя писать по старому», всегда слышу это нытье при вводе чего то нового и удивляюсь когда не слышу. Насчет «спрятать» логику от программиста, не понимаю зачем это делать? Явное лучше неявного и по моему там все логично и просто.

    Reply ↓
  4. DitriX

    А можно использовать расширение конфигурации 🙂

    Reply ↓
  5. klinval

    (3) webester, всё это спорно… В комментариях к статье вы с автором статьи долго спорили по этому вопросу. Не хотелось бы начинать спор заново, но всё-таки поправлю вас:

    Лучи добра, заключались в основном в «опять надо писать по новому, почему нельзя писать по старому», всегда слышу это нытье при вводе чего то нового и удивляюсь когда не слышу.

    Вы слышали негатив по поводу введения СтрНайти() вместо Найти()? Тоже новшество, писать надо по новому, но никто не «ноет», потому что это новое лучше старого и не требует больших трудозатрат (по сравнение со старым методом). А ПоказатьВопрос вместо Вопрос предполагает большее количество кода + общее ухудшение читабельности. Я не пишу, что мне прям так уж плохо читать стало код с ПоказатьВопрос, но однозначно читабельность ухудшилась. А количество кода (и количество заморочек/трудностей) у ПоказатьВопрос в сравнении с Вопрос вы можете увидеть из моей статьи. И всё это ради чего? Чтобы пользователь мог работать на Ipad с 1С?

    Я смирился с новой реальностью: теперь нужно использовать новые не модальные методы. Я не посылаю «лучи добра» 1С-никам, но в то-же время и не считаю что они сделали лучше чем было.

    Reply ↓
  6. klinval

    (4) Поручик, спасибо за наводку, не заметил, что 1С-ники в БП 3.0 уже используют ПоказатьВопрос ПередЗаписью. Они там обошли ситуацию с нажатием крестика, а я не знал как это сделать. Позже дополню статью.

    (5) DitriX. Честно признаюсь: механизм расширения конфигурации ещё не пробовал, но официальное описание и статьи на Инфостарте читал. Есть сомнения, что станет проще обновляться, если мы реализуем этот код через расширения. Точнее сказать обновлять то станет проще, но может быть мы упустим какое-либо изменение, например очередное изменение кнопки «Провести и закрыть» со стандартной на нетиповую (и наоборот) — тогда у пользователя появится 0 или 2 кнопки «Провести и закрыть» (в зависимости от варианта изменения)

    Reply ↓
  7. Fragster

    (3) почему было не сделать на время «модального» вызова сохранение состояния в «стек» и по завершении — его восстановление? А теперь приходится писать две версии обработки — с использованием модальности, и без. писать в 1,5-2 больше кода и т.п.

    Предыдущее возмущение было связано с «изменение данных формы не допустимо» и костылем копироватьДанныеФормы (когда хочется не весь контекст обработать на сервере — функция с передачей данных формы по значению, изменением и возврата их копии, и потом копирования их в исходные данные формы), но текущая боль при необходимости использования цепочки асинхронных вызовов или асинхронных вызовов в цикле, или использования диалога в функции, которая раньше возвращала значение на основе данных пользователя (или добавление ввода данных пользователя в подобную функцию, которая используется в куче мест). Или когда необходимость в вводе данных пользователя не определена. Обслуживающего кода реально становится больше, чем работающего с бизнес логикой.

    Reply ↓
  8. wolfsoft

    (3) webester,

    Лучи добра, заключались в основном в «опять надо писать по новому, почему нельзя писать по старому»

    Да-да, нашим аборигенам обязательно надо чтоб по-новому. Без этого никак, ага.

    Насчет «спрятать» логику от программиста, не понимаю зачем это делать? Явное лучше неявного и по моему там все логично и просто.

    Так зачем же вы на 1С программируете? Пишите в машинных кодах. 1С скрывает от вас очень многое, вы не в курсе?

    Прорыв 1С в своё время был основан именно на том, что она скрыла ненужное и предоставила удобную платформу для создания бизнес-приложений. Если бы не это, писали бы на других языках, а не на 1с — 100%. Даже в своих типовых 1С уже прикручивает целую кучу стандартных процедур и функций, чтобы обходить ограниченность своей же платформы. Хотя всё то же самое можно было реализовать на уровне платформы, и работало бы это значительно быстрее.

    Reply ↓
  9. androgin

    ужасный код!

    и 1С не объявляла никому войны с модальными окнами, а всего лишь подстроилась под веб-технологии.

    Reply ↓
  10. DrAku1a

    Может не совсем в тему, но

    Для начала можно посмотреть на тему «Вопрос в обработчике формы ПередЗакрытием»

    — как реализовать этот вопрос для формы, которая выведена на рабочий стол. Ведь для такой формы нельзя использовать метод «Закрыть()»

    Reply ↓
  11. klinval

    (10) androgin,

    ужасный код!

    Не совсем понял к кому эти слова: ко мне или к разработчикам платформы, которые заставляют нас так писать? Если ко мне, то опишите конкретно где ошибка и я подправлю статью.

    Reply ↓
  12. klinval

    (11) DrAku1a,

    как реализовать этот вопрос для формы, которая выведена на рабочий стол. Ведь для такой формы нельзя использовать метод «Закрыть()»

    К сожалению не сталкивался с конкретно этой проблемой, поэтому не могу подсказать… Думаю есть смысл на форуме создать тему — может кто поможет.

    Reply ↓
  13. veretennikoff

    Я реализовал без создания доп кнопок. Вроде бы работает.

    1. Создаете переменную на клиенте, называете ее например ЗаписьРазрешена

    2. Инициализируете ее в модуле формы значением Ложь

    3. В обработчике ПередЗаписью() в зависимости от значения этой переменной вы продолжаете выполнение кода в нормальном режиме или ставите Отказ в Истина и задаете вопрос пользователю

    Если ЗаписьРазрешена Тогда
ЗаписьРазрешена = Ложь;
// продолжим в нормальном режиме
Иначе
Отказ = Истина;
// диалог пользователю
КонецЕсли;

    Показать

    4. В обработчике оповещения об ответе пользователя при согласии пользователя записать документ изменяем нашу переменную и вызываем запись документа еще раз

    Если Не РезультатВопроса = КодВозвратаДиалога.Нет Тогда
ЗаписьРазрешена = Истина;
Записать();
КонецЕсли;

    5. Профит

    P.S.: в 3 можно добавить дополнительное условие на режим записи документа (например мне нужно было исключить проверку для режима отмены проведения)

    Если Не ПараметрыЗаписи.РежимЗаписи = РежимЗаписиДокумента.ОтменаПроведения Тогда
Если ЗаписьРазрешена Тогда
…

    Принимаю замечания

    Reply ↓
  14. klinval

    (14) veretennikoff,

    Я реализовал без создания доп кнопок. Вроде бы работает.

    Нажимаете вы кнопку «Провести и закрыть» у вас задаётся вопрос. Ответ — «да» — записывается, но форма не закрывается. Я прав?

    Кнопка нужна только для того чтобы отслеживать, что пользователь нажал «Записать» или «Записать и закрыть». Кодом никак ПередЗаписью это не увидеть. Поэтому если кнопка изначально типовая — придётся её добавлять… Или мириться с тем, что «Записать и закрыть» не закрывает форму.

    Что касается:

    Создаете переменную на клиенте, называете ее например ЗаписьРазрешена

    Работать будет, но зачем плодить новые сущности, если и так есть «ПараметрыЗаписи»?

    Reply ↓
  15. veretennikoff

    (15)

    Согласен

    Невнимательно прочитал, что вам нужно именно отслеживать, какая кнопка была нажата: Записать или Записать и закрыть

    ИМХО: преимущественно пользуются кнопкой Записать и закрыть , а не Записать, поэтому можно закрывать форму тоже программно

    (в итоге конечно все зависит от того, какие кнопки нажимают пользователи)

    Reply ↓
  16. HystriX

    Спасибо за статью и советы, взял образец из Бухгалтерии 3.0. Однако у этого метода есть недостаток — при такой нестандартной обработке команды «Записать и закрыть» платформа автоматом не выдает стандартное затухающее оповещение о перезаписи в углу. По крайней мере, так дело обстоит на 8.3.5.

    Reply ↓
  17. ProDeveloper

    Странные решения. Если курить мануал https://its.1c.ru/db/metod8dev/content/5272/hdoc, то есть же метод ВыполнитьОбработкуОповещения()

    в том же синтаксис помощнике к этому методу написано:

    Используется в реализации процедур, которые внутри себя могут открывать блокирующие окна (например, вызывать метод ПоказатьВопрос) и при этом должны каким-то образом вернуть свой результат в вызывающие процедуры.

    Reply ↓
  18. klinval

    (18) Не понимаю вашего решения. Можете подробнее написать? Перед записью на форме какой код (неужели там без Отказ=Истина обошлись)?

    Reply ↓
  19. ProDeveloper

    Беру свои слова назад. Вот официальный ответ от 1С — «красиво это никак не сделать»:

    http://its.1c.ru/docs/v8nonmodal/#25

    Вопрос в обработчике формы ПередЗаписью

    В обработчике события формы ПередЗаписью также может возникнуть потребность задать вопрос. Как и в предыдущем примере. Однако здесь вопрос так просто не решается. Отличие заключается в следующем.

    В предыдущем примере, оказываясь в обработчике ПередЗакрытием, мы однозначно знали действие, которое должно быть выполнено. Это закрытие формы. Поэтому в обработке оповещения мы смело писали Закрыть().

    Но в обработчике ПередЗаписью мы такой однозначной информации не имеем. В этом обработчике мы можем оказаться по двум причинам: если пользователь нажал Записать, или если он нажал Записать и закрыть. То есть дальнейший сценарий действий нам неизвестен. Определить его стандартными способами, находясь внутри этого обработчика, мы не можем.

    Поэтому тут можно предложить три варианта, но все они, к сожалению, обладают недостатками:

    Изменить логику прикладного решения так, чтобы не было диалога с пользователем в этом обработчике. Это не всегда возможно;

    В обработке оповещения с помощью собственной блокирующей формы задавать пользователю развернутый вопрос, предполагающий точное описание дальнейших действий: Отказаться?, Только записать?, Записать и закрыть? Это может выглядеть не очень красиво, ведь пользователь уже нажал «Записать и закрыть», а его опять об этом спрашивают;

    Не использовать стандартные команды формы Записать, «Записать и закрыть». Вместо них создать собственные команды, в которых и выполнять необходимые алгоритмы. Создание собственных команд потребует дополнительных трудозатрат.

    Reply ↓
  20. klinval

    (20)

    Не использовать стандартные команды формы Записать, «Записать и закрыть». Вместо них создать собственные команды, в которых и выполнять необходимые алгоритмы. Создание собственных команд потребует дополнительных трудозатрат.

    Именно это я и сделал, т.к. примера кода у них именно на эту ситуацию нет. Остальные варианты (1. Отказаться от использования или 2. Задать пользователю доп. вопросы Отказаться?, Только записать?, Записать и закрыть?) и так понятно как реализовать.

    Reply ↓
  21. ProDeveloper

    Нашел как теперь делают это 1Сники в свежих конфах аля ERP2, KA2.

    Нужно курить модуль формы, процедура ПередЗаписью

    &НаКлиенте

    Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)

    СобытияФормКлиент.ПередЗаписью(ЭтотОбъект, Отказ, ПараметрыЗаписи);

    P.S. В структуре ПараметрыЗаписи хранят признак — ПараметрыЗаписи.ЕстьВопросыПередЗаписью

    Reply ↓
  22. ProDeveloper

    Как я и писал ранее используют метод ВыполнитьОбработкуОповещения()

    Суть в чем, от записи формы они отказываются, после чего вызывают обёртку, в которой задаются вопросы ПоказатьВопрос() и т.д.

    Далее прыгают из процедуры в процедуру как в кроличью нору , использьуя ВыполнитьОбработкуОповещения() , в самом конце используют вызов ОбщегоНазначенияУТКлиент.ОбработатьЗаписьОбъектаВФорме(ДополнительныеПараметры.Форма, ДополнительныеПараметры.ПараметрыЗаписи); с программной записью этой формы, т.е. Форма.Записать(ПараметрыЗаписи);

    Reply ↓
  23. dialogsoft

    он спер с сайта 1с:

    http://its.1c.ru/docs/v8nonmodal/

    и забыл в первом случае написать внизу:

    ВыполняетсяЗакрытие = Ложь;

    из- за этого ошибка

    Reply ↓
  24. klinval

    (24)

    он спер с сайта 1с:http://its.1c.ru/docs/v8nonmodal/

    Вы обвиняете меня, что после слов

    Что же думает по предлагаемому вопросу специалисты фирмы 1С? Для начала можно посмотреть на тему «Вопрос в обработчике формы ПередЗакрытием»:

    Я спер текст из 1С… Смысл фразы и выделение в блок цитирования предполагает, что дальше будет цитата. В анонсе статьи я даже ссылку дал откуда спер процитировал.

    Сама же статья про «Как использовать ПоказатьВопрос в обработчике формы ПередЗаписью». Примеров этого случая в http://its.1c.ru/docs/v8nonmodal/ нет, что я и пытался исправить. Про «Вопрос в обработчике формы ПередЗакрытием» я статью не писал, т.к. на ИТС достаточно подробно описан алгоритм.

    А то что в цитируемом коде нет строчки «ВыполняетсяЗакрытие = Ложь; » — согласен, не заметил.

    Reply ↓
  25. berezin84

    Код для использования в расширении, для обработки события «ПередЗаписью», в случае если нам нужно записывать или нет после ответа пользователя.

    &НаКлиенте
Процедура БЕА_ПередЗаписьюПеред(Отказ, ПараметрыЗаписи)

СуммаЗатрат = Объект.Затраты.Итог(«Сумма»);
Если СуммаЗатрат > Объект.СуммаДокумента И НЕ ПараметрыЗаписи.Свойство(«ВопросЗадан») Тогда
Сообщить(«Сумма затрат превышает сумму документа!»,СтатусСообщения.Важное);
Отказ = Истина;
ИначеЕсли СуммаЗатрат < Объект.СуммаДокумента И НЕ ПараметрыЗаписи.Свойство(«ВопросЗадан») Тогда
Отказ = Истина;
Режим = РежимДиалогаВопрос.ДаНет;
Оповещение = Новый ОписаниеОповещения(«ПослеЗакрытияВопросаПользователю»,ЭтаФорма, ПараметрыЗаписи);
ПоказатьВопрос(Оповещение, «Сумма затрат меньше суммы документа, продолжить запись?», Режим, 0);
КонецЕсли;

КонецПроцедуры

&НаКлиенте
Функция ПослеЗакрытияВопросаПользователю(Результат, ПараметрыЗаписи) Экспорт

Если Результат = КодВозвратаДиалога.Да Тогда
ПараметрыЗаписи.Вставить(«ВопросЗадан»);
Записать(ПараметрыЗаписи);
КонецЕсли;

КонецФункции

    Показать

    Reply ↓
  26. klinval

    (26) А как вы определяете нужно ли закрывать форму (нажал ПровестиИЗакрыть или просто Провести)?

    Reply ↓
  27. SiroJah

    (26) Спасибо! Работает «Провести» и «Провести и закрыть»

    Reply ↓
  28. ah7777777

    сделал немного по другому:

    &НаКлиенте
Перем флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента;

&НаКлиенте
Процедура ПриОткрытии(Отказ)
флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента=0;
КонецПроцедуры

&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)

Если флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента<=1 тогда  //Если =0 Значит вопрос задается впервые если 1 после исправления повторно
Отказ=истина;                 //Нам надо вернутся в форму
Если ДатаДоговораРавнаДатеДокументаСервер() тогда
Оповещение = Новый ОписаниеОповещения(«ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДокумента»,ЭтотОбъект,ПараметрыЗаписи);//Параметры записи передадим в функцию ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДокумента
ПоказатьВопрос(Оповещение, «Дата создания договора совпадает с датой платежа.Верно ли указан договор?»,РежимДиалогаВопрос.ДаНет,0,КодВозвратаДиалога.Да);
Возврат;
КонецЕсли;
Возврат;
КонецЕсли;
КонецПроцедуры

&НаКлиенте
Процедура ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДокумента(Результат, Параметры) Экспорт
//****************************************************
Если Результат = КодВозвратаДиалога.Нет Тогда       //Надо остаться в форме
флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента=1;
Иначе
флПередЗаписью_ПослеОтветаНаВопрос_ДатаДоговораРавнаДатеДоку­мента=2;//Записать с параметрами и закрыть форму
Записать(Параметры);
Закрыть();
КонецЕсли;
КонецПроцедуры

    Показать

    Reply ↓
  29. klinval

    (30) Да, как вариант можно в переменной хранить ответ. Только один нюанс по вашему коду: если нажать «Записать» (без закрыть) и ответить на вопрос «Да» то форма закроется. Отслеживание/определение «нужно ли закрывать?» добавляет дополнительных трудностей (кода) к задаче.

    Reply ↓
  30. ah7777777

    тут по условиям задачи надо форму закрыть.

    Reply ↓
  31. Gaster

    в первом примере, в этой части кода:

    Если Не ВыполняетсяЗакрытие Тогда

    Вылетает ошибка что не может привести к типу Булево. Естественно, там же в первом проходе неопределено будет, как он может сравнивать… Как быть?

    Добавлено спустя 15 минут…

    странно, в другом документе не вылетает

    Reply ↓
  32. klinval

    (33) похоже забыли объявить переменную:

    &НаКлиенте
Перем ВыполняетсяЗакрытие;

    Или:

    ВыполняетсяЗакрытие = Ложь;
    Reply ↓
  33. klinval

    (33) И ещё, не знаю обратили ли вы внимание, но пример который вы смотрите это к теме «Вопрос в обработчике формы ПередЗакрытием» и взят код из http://its.1c.ru/docs/v8nonmodal/ . Данный код в публикации для примера, т.к. очень близок с темой «Как использовать ПоказатьВопрос в обработчике формы ПередЗаписью»

    Reply ↓

Leave a Comment

Ваш адрес email не будет опубликован. Обязательные поля помечены *