Создание внешних печатных форм под управляемым приложением с нуля

25.03.2019 98 Comments

Печатные формы документов, Разработка

, , ,



















    49.JPG
    48.JPG
    СозданиеВПФдляУП.JPG
    2.jpg
    3.jpg
    4.jpg
    5.jpg
    6.jpg
    7.jpg
    8.jpg
    10.jpg
    11.jpg
    9.jpg
    12.jpg
    13.jpg
    14.jpg
    15.jpg
    16.jpg
    17.jpg

Когда мне пришлось создавать внешние печатные формы под приложения на БСП («1С: Бухгалтерия предприятия 3.0», «1С: Управление торговлей 11»), я обнаружил, что нет грамотных инструкций. Те, что имелись, использовали так называемые шаблоны: готовые обработки, в которых необходимо выполнять определенные корректировки. Но как создать сам шаблон, конкретных мануалов не было, справочную информацию я нашел на сайте ИТС и, обработав ее, написал статью, где подробно и понятно объясняются все этапы создания внешней печатной формы для управляемого приложения на примере конфигурации «1С: Бухгалтерия предприятия 3.0»

UPD Статья и обработки к ней обновлены на февраль 2024 года

UPD 25.03.2024 Добавлены примеры внешних печатных форм для УТ 11.4

В этой статье мы научимся создавать внешнюю печатную форму для "1С: Бухгалтерия предприятия 3.0". Причем создавать с нуля, не используя так называемые шаблоны. Вы сами научитесь создавать шаблоны внешних печатных форм.

Все это делается довольно просто))

И так, создадим новую обработку.

Мы будем создавать внешний счет на оплату покупателю, поэтому обработку так и назовем: «СчетНаОплатуВнешний».

 

 

 Сохраним ее на жесткий диск.

Регистрация внешней обработки или отчета в базе 1С осуществляется на основании сведений, которые поставляет сама обработка. Поэтому эти сведения должны быть описаны в обработке. Осуществляется это с помощью структуры, которая имеет определенный набор полей, и которая возвращается экспортной функций СведенияОВнешнейОбработке.

Зайдем в модуль обработки, и создадим экспортную функцию СведенияОВнешнейОбработке.

Функция СведенияОВнешнейОбработке() Экспорт

КонецФункции

Внутри этой функции создадим структуру ПараметрыРегистрации, которая будет содержать определенный список полей. Каждое поле мы разберем в отдельности.

Функция СведенияОВнешнейОбработке() Экспорт

ПараметрыРегистрации = Новый Структура;

КонецФункции

Создадим первый элемент структуры, он будет иметь ключ с название «Вид».

ПараметрыРегистрации = Новый Структура;
ПараметрыРегистрации.Вставить("Вид",);

Значением данной связки КлючИЗначение идет одна из строк:

  • «ДополнительнаяОбработка»
  • «ДополнительныйОтчет»
  • «ЗаполнениеОбъекта»
  • «Отчет»
  • «ПечатнаяФорма»
  • «СозданиеСвязанныхОбъектов»

В нашем случае должна быть строка "ПечатнаяФорма".

ПараметрыРегистрации = Новый Структура;
ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");

 Следующий элемент структуры должен иметь ключ с названием Назначение.

ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");
ПараметрыРегистрации.Вставить("Назначение",);

В качестве значения данного элемента должен выступать массив, где перечислены будут все документы или справочники, в которых будет выходить данная печатная форма.

Они должны иметь тип строка, и быть в следующем формате:

Документ."НазваниеДокумента"

Справочник."НазваниеСправочника"

У нас этот массив будет возвращать отдельная функция ПолучитьНазначениеОбработки.

Создадим ее.

Функция ПолучитьНазначениеОбработки()
Массив = Новый Массив;
Массив.Добавить("Документ.СчетНаОплатуПокупателю");

Возврат Массив;
КонецФункции

Допишем созданный последним элемент структуры.

ПараметрыРегистрации.Вставить("Назначение",ПолучитьНазначениеОбработки());

 Создадим новый элемент структуры, ключ которого будет называться «Наименование», а в значении будет содержаться наименование обработки, которое будет отображаться в справочнике "Дополнительные внешние печатные формы".

ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");
ПараметрыРегистрации.Вставить("Назначение",ПолучитьНазначениеОбработки());
ПараметрыРегистрации.Вставить("Наименование","Счет на оплату ВНЕШНИЙ");

Следующий элемент структуры будет иметь название «Версия»,  значением данного элемента будет версия обработки. Задается программистом на его усмотрение.

ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");
ПараметрыРегистрации.Вставить("Назначение",ПолучитьНазначениеОбработки());
ПараметрыРегистрации.Вставить("Наименование","Счет на оплату ВНЕШНИЙ");
ПараметрыРегистрации.Вставить("Версия","1.0");

 Следующий элемент имеет название «Информация», который содержит краткую информацию по обработке.

ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");
ПараметрыРегистрации.Вставить("Назначение",ПолучитьНазначениеОбработки());
ПараметрыРегистрации.Вставить("Наименование","Счет на оплату ВНЕШНИЙ");
ПараметрыРегистрации.Вставить("Версия","1.0");
ПараметрыРегистрации.Вставить("Информация","Счет на оплату (внешняя печатная форма)");

 Следующий элемент имеет название «БезопасныйРежим», его необходим устанавливать в значение истина или ложь, в зависимости от того необходимо устанавливать или отключать безопасный режим во время выполнения обработки. Мы установим значение  Истина.

ПараметрыРегистрации.Вставить("Вид","ПечатнаяФорма");
ПараметрыРегистрации.Вставить("Назначение",ПолучитьНазначениеОбработки());
ПараметрыРегистрации.Вставить("Наименование","Счет на оплату ВНЕШНИЙ");
ПараметрыРегистрации.Вставить("Версия","1.0");
ПараметрыРегистрации.Вставить("Информация","Счет на оплату (внешняя печатная форма)");
ПараметрыРегистрации.Вставить("БезопасныйРежим",Истина);

И в последнем параметре необходимо добавить команды, которые будут поставляться обработкой.  Для этого нам необходимо создать и заполнить таблицу команд. Разработаем функцию, которая создает и возвращает таблицу с определенным набором полей. Делать это будем в функции ПолучитьТаблицуКоманд.

Создадим функцию и таблицу значений внутри нее.

Функция ПолучитьТаблицуКоманд()

Команды = Новый ТаблицаЗначений;

КонецФункции

Теперь создадим пять колонок этой таблицы.

И первая колонка – Представление (тип строка).

Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));

Эта колонка – представление команды в пользовательском интерфейсе, т.е. то, что пользователь увидит при нажатии меню"Печать" в документе или справочнике.

Вторая колонка – Идентификатор.

Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));

Это может быть любая текстовая строка, уникальная в пределах данной обработки.

Третья колонка – Использование.

Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));

Параметр данной колонки типа строка, должен принимать одно из четырех  значений –

  • ОткрытиеФормы – Открывает форму обработки.
  • ВызовКлиентскогоМетода – будет вызвана клиентская процедура из модуля формы обработки.
  • ВызовСерверногоМетода  — будет вызвана серверная процедура из модуля обработки.
  • СценарийВБезопасномРежиме – тоже будет вызвана серверная процедура из модуля обработки в безопасном режиме.

 

Конкретно мы будем использовать вызов серверного метода.

Следующая колонка – показывать оповещение. Принимает значение истина или ложь, в зависимости от того надо показывать оповещение или нет.

Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));

И последняя колонка – модификатор. Это дополнительный модификатор команды. В нашем случае будет иметь название ПечатьXML.

Функция ПолучитьТаблицуКоманд()

Команды = Новый ТаблицаЗначений;
Команды.Колонки.Добавить("Представление", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Идентификатор", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("Использование", Новый ОписаниеТипов("Строка"));
Команды.Колонки.Добавить("ПоказыватьОповещение", Новый ОписаниеТипов("Булево"));
Команды.Колонки.Добавить("Модификатор", Новый ОписаниеТипов("Строка"));

Возврат Команды;

КонецФункции

Теперь создадим процедуру, которая будет заполнять данную таблицу значений.


Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = "")
НоваяКоманда = ТаблицаКоманд.Добавить();
НоваяКоманда.Представление = Представление;
НоваяКоманда.Идентификатор = Идентификатор;
НоваяКоманда.Использование = Использование;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
НоваяКоманда.Модификатор = Модификатор;
КонецПроцедуры

 

В данном коде все понятно.

 В функции СведенияОВнешнейОбработке создадим команду и заполним ее.

Создаем таблицу значений: 

//....
ПараметрыРегистрации.Вставить("БезопасныйРежим",Истина);

Команды = ПолучитьТаблицуКоманд();

Теперь заполним ее.

Команды = ПолучитьТаблицуКоманд();

ДобавитьКоманду(Команды,"Счет на оплату (внешняя печатная форма)",
"СчетНаОплатуВнешний",
"ВызовСерверногоМетода",
Ложь,
"ПечатьMXL");

Еще раз пройдемся по параметрам.

  • Первый параметр, непосредственно таблица команд вновь созданная.
  • Второй параметр, как будет отображаться команда пользователю на форме (документа, справочника).
  • Третий – уникальный идентификатор команды, запомните его, он нам еще пригодится!
  • Четвертый параметр – использование, что вызовет Ваша команда.
  • Пятый  параметр – показывать оповещение, мы не будем это делать.
  • Шестой параметр – модификатор, в нашем случае он всегда один ПечатьXML.

Теперь передадим вновь созданную таблицу команд в структуру ПараметрыРегистрации.

И пусть наша функция СведенияОВнешнейОбработке возвращает данную структуру.

ПараметрыРегистрации.Вставить("Команды",Команды);
Возврат ПараметрыРегистрации;

Все теперь наша обработка будет передавать нужные параметры регистрации, которые будут необходимы при создании элемента справочника дополнительные печатные формы и обработки. Обращаю ваше внимание, что название всех полей в структуре Параметры регистрации, а также название и типы всех колонок в таблице команд, должны быть те которые приведены в примере, иначе Ваша обработка не зарегистрируется.

Теперь в модуле объекта создадим процедуру Печать. Это процедура с четырьмя параметрами: МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода.

Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

КонецПроцедуры

И вот начинается самое интересное, теперь вам необходимо войти в аналогичную процедуру в менеджере объекта счет на оплату покупателю, или в обработке, которая, по сути, является менеджером печати. 

Как узнать, где находится нужная нам функция? 

Откроем модуль менеджера документа Счет на оплату покупателю.

 

И найдем процедуру ДобавитьКомандыПечати, которая заполняет список команд .

В этой процедуре найдем код, где добавляется команда для нужной нам печатной формы (список команд добавляется в таблицу значений КомандыПечати). И обратим внимание на свойство МенеджерПечати. Если этому свойству присваивается какое-нибудь значение — это путь к объекту метаданных, как правило к обработке, то значит при выводе нужной печатной формы будет отработан код в процедуре Печать, которая находится в модуле менеджере этого объекта (в обработке). А если это свойство в принципе не фигурирует при заполнении команды печати, то значит будет отработан код в процедуре Печать, которая находится в модуле менеджера нашего основного объекта (в нашем случае это документ СчетНаОплатуПокупателю)

Посмотрим на процедуру ДобавитьКомандыПечати в модуле менеджера документа "Счет на оплату покупателя".

Поскольку мы делаем внешнюю печатную форму счета на оплату, то нас интересует первое добавление в таблицу значений (см. свойство Представление), и мы видим, что в этом случае заполнено свойство МенеджерПечати, где указан объект Обработка.ПечатьСчетаНаОплату. Это значит, что нам нужно найти процедуру Печать в модуле  менеджера обработки ПечатьСчетаНаОплату. 

А если бы мы решили сделать внешнюю печатную форму договора счета на оплату (второе добавление в таблицу значений КомандыПечати), то нам нужно было бы найти процедуру Печать в модуле менеджера документа СчетНаОплатуПокупателя.

Откроем модуль менеджера обработки ПечатьСчетаНаОплату.

И раскроем процедуру Печать.

Нас интересует второе условие (где фигурирует строка "СчетЗаказ", см. идентификатор нужной команды в процедуре ДобавитьКомандыПечати  модуля менеджера документа), скопируем это условие в процедуру Печать нашей внешней обработки.

Внимание! Копировать напрямую процедуру Печать из модуля менеджера (без разницы обработка это, документ или справочник) не следует. Поскольку у них отличается количество параметров, в последствие это приводит к ошибкам при работе.

Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "СчетЗаказ") Тогда
СформироватьПечатнуюФорму(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, "СчетЗаказ", "Счет на оплату",
ОбъектыПечати, ПараметрыВывода);
КонецЕсли;

Так же из модуля менеджера обработки скопируем процедуру СформироватьПечатнуюФорму.


Процедура СформироватьПечатнуюФорму(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета, ОбъектыПечати, ПараметрыВывода)

ТипыОбъектов = ОбщегоНазначенияБП.РазложитьСписокПоТипамОбъектов(МассивОбъектов);

Для каждого ОбъектыТипа Из ТипыОбъектов Цикл

МенеджерОбъекта = ОбщегоНазначения.МенеджерОбъектаПоСсылке(ОбъектыТипа.Значение[0]);

ДокументыБезСчетовНаОплату = Неопределено;
ТаблицаСведенийСчетНаОплату = МенеджерОбъекта.ПолучитьТаблицуСведенийСчетаНаОплату(ОбъектыТипа.Значение, ДокументыБезСчетовНаОплату);

Если ЗначениеЗаполнено(ДокументыБезСчетовНаОплату) Тогда
Если ПараметрыПечати.Свойство("СокращенноеСообщениеОбОшибке") Тогда
ВывестиСообщениеНеУказанСчетНаОплату(ДокументыБезСчетовНаОплату, ПараметрыПечати.СокращенноеСообщениеОбОшибке);
Иначе
ВывестиСообщениеНеУказанСчетНаОплату(ДокументыБезСчетовНаОплату);
КонецЕсли;
КонецЕсли;

УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета,
ПечатьТорговыхДокументов.ПечатьСчетаНаОплату(ТаблицаСведенийСчетНаОплату, ОбъектыПечати, ПараметрыПечати),,"ОбщийМакет.ПФ_MXL_СчетЗаказ");

КонецЦикла;

ПараметрыВывода.Вставить("ФормироватьЭД", Истина);

ОбщегоНазначенияБП.ЗаполнитьДополнительныеПараметрыПечати(МассивОбъектов,
КоллекцияПечатныхФорм,
ОбъектыПечати,
ПараметрыВывода);

КонецПроцедуры

В этом коде есть строка, где заполняется таблица сведений счета на оплату.

ТаблицаСведенийСчетНаОплату = МенеджерОбъекта.ПолучитьТаблицуСведенийСчетаНаОплату(ОбъектыТипа.Значение, ДокументыБезСчетовНаОплату);

Эта таблица получается при помощи функции модуля менеджера объекта (в нашем случае это документ СчетНаОплатуПокупателю). Найдем эту функцию в модуле менеджера документа СчетНаОплатуПокупателю.

И скопируем её в модель нашей внешней обработки.

А сам код процедуры СформироватьПечатнуюФорму в модуле внешней обработки исправим, убрав все не нужное от туда.

Процедура СформироватьПечатнуюФорму(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета, ОбъектыПечати, ПараметрыВывода)

ТипыОбъектов = ОбщегоНазначенияБП.РазложитьСписокПоТипамОбъектов(МассивОбъектов);

Для каждого ОбъектыТипа Из ТипыОбъектов Цикл

ТаблицаСведенийСчетНаОплату = ПолучитьТаблицуСведенийСчетаНаОплату(ОбъектыТипа.Значение);

УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета,
ПечатьТорговыхДокументов.ПечатьСчетаНаОплату(ТаблицаСведенийСчетНаОплату, ОбъектыПечати, ПараметрыПечати),,"ОбщийМакет.ПФ_MXL_СчетЗаказ");

КонецЦикла;

ПараметрыВывода.Вставить("ФормироватьЭД", Истина);

ОбщегоНазначенияБП.ЗаполнитьДополнительныеПараметрыПечати(МассивОбъектов,
КоллекцияПечатныхФорм,
ОбъектыПечати,
ПараметрыВывода);

КонецПроцедуры

Если мы сейчас сделаем проверку модуля внешней обработки, то выйдет две ошибки. Первая, что не определена переменная ПараметрыПечати в процедуре Печать, и, что не найдена функция ПолучитьТекстЗапросаДляФормированияТаблицыСведенийСчетаНаОплату в функции ПолучитьТаблицуСведенийСчетаНаОплату. 

Создадим переменную ПараметрыПечати в процедуре Печать. Это будет простая структура.

Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

ПараметрыПечати = Новый Структура;

Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "СчетЗаказ") Тогда
СформироватьПечатнуюФорму(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, "СчетЗаказ", "Счет на оплату",
ОбъектыПечати, ПараметрыВывода);
КонецЕсли;

КонецПроцедуры

А потом найдем функцию ПолучитьТекстЗапросаДляФормированияТаблицыСведенийСчетаНаОплату в модуле менеджера документа  СчетНаОплатуПокупателю и скопируем её в модуль внешней обработки.

Должен получится следующий состав процедур и функций модуля внешней обработки (для удобства я разделил их на две области). 

Еще раз делаем проверку модуля. Ошибок не обнаружено.

Продолжаем, теперь нам необходимо, что бы брался наш макет, и печатался по нашей команде.

Нас интересует процедура СформироватьПечатнуюФорму, а в ней мы уделим внимание методу ПечатьСчетаНаОплату общего модуля ПечатьТорговыхДокументов.

Очевидно, она непосредственно формирует табличный документ. Перейдем в этот общий модуль, и скопируем функцию ПечатьСчетаНаОплату в модуль нашей внешней обработки.

Делаем проверку модуля внешней обработки. Ругается на несуществующие методы ВывестиЗаголовокПредупреждение и НомерСчетаНаОплату.

 

Переходим в общий модуль, от куда мы взяли функцию ПечатьСчетаНаОплату, находим процедуру ВывестиЗаголовокПредупреждение , и копируем ее в модуль внешней обработки.

А функция НомерСчетаНаОплату в общем модуле ПечатьТорговыхДокументов экспортная, поэтому мы просто исправим код в процедуре ПечатьСчетаНаОплату, где используется проблемная функция, сделав вызов этой функции из вышеупомянутого общего модуля.

НомерДокумента = ПечатьТорговыхДокументов.НомерСчетаНаОплату(СведенияОДокументе.ГосударственныйКонтракт, СведенияОДокументе.НомерДокумента);

Проверяем еще раз ошибки. Все нормально.

Не забудем в процедуре СформироватьПечатнуюФорму убрать вызов метода ПечатьСчетаНаОплату из общего модуля.

Процедура СформироватьПечатнуюФорму(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета, ОбъектыПечати, ПараметрыВывода)

ТипыОбъектов = ОбщегоНазначенияБП.РазложитьСписокПоТипамОбъектов(МассивОбъектов);

Для каждого ОбъектыТипа Из ТипыОбъектов Цикл

ТаблицаСведенийСчетНаОплату = ПолучитьТаблицуСведенийСчетаНаОплату(ОбъектыТипа.Значение);

УправлениеПечатью.ВывестиТабличныйДокументВКоллекцию(КоллекцияПечатныхФорм, ИмяМакета, СинонимМакета,
ПечатьСчетаНаОплату(ТаблицаСведенийСчетНаОплату, ОбъектыПечати, ПараметрыПечати),,"ОбщийМакет.ПФ_MXL_СчетЗаказ");

КонецЦикла;

ПараметрыВывода.Вставить("ФормироватьЭД", Истина);

ОбщегоНазначенияБП.ЗаполнитьДополнительныеПараметрыПечати(МассивОбъектов,
КоллекцияПечатныхФорм,
ОбъектыПечати,
ПараметрыВывода);

КонецПроцедуры

Теперь зайдем в скопированную функцию ПечатьСчетаНаОплату, и посмотрим, где в ней подтягивается макет.

Находим данный макет в общих макетах и копируем его в макеты нашей обработки.

Исправляем выделенный код, где подтягивается макет, следующий образом.

Макет = ПолучитьМакет("ПФ_MXL_СчетЗаказ");

Теперь зайдем в наш скопированный макет, и сделаем какое-нибудь изменение, чтобы вы видели, что команда подтянула именно макет из внешней обработки.

Вернемся обратно в процедуру Печать нашей внешней обработки.

И теперь осталась одна небольшая хитрость, без которой ваш внешний отчет не будет работать. Необходимо текст "СчетЗаказ" (это идентификатор типовой печатной формы).

 Заменить на название идентификатора команды ("СчетНаОплатуВнешний").

Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

ПараметрыПечати = Новый Структура;

Если УправлениеПечатью.НужноПечататьМакет(КоллекцияПечатныхФорм, "СчетНаОплатуВнешний") Тогда
СформироватьПечатнуюФорму(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, "СчетНаОплатуВнешний", "Счет на оплату",
ОбъектыПечати, ПараметрыВывода);
КонецЕсли;

КонецПроцедуры

Все, сохраняем данную обработку. И запускаем "1С: Предприятие" из конфигуратора.

Идем в администрирование. В дополнительные отчеты и обработки.

Нажимаем на кнопку "Добавить из файла" и выбираем нашу созданную обработку.

Записываем. И смотрим, как выходит наша печатная форма.

Оригинал статьи

Ниже приведены примеры внешних печатных форм для конфигураций:

"1С: Бухгалтерия предприятия" (релиз 3.0.67.67).

  • Счета на оплату,
  • ТОРГ 12, 
  • ПКО ,
  • М11  и Требование накладная в одной обработке (документ Требование накладная).

"1С: Управление торговлей 11.4" (релиз 11.4.6.230).

  • Счет на оплату (для документов Счета на оплату и Заказы клиенту, выполняется в небезопасном режиме из-за использования штрих-кода)
  • ТОРГ12 (для документа Реализация товаров и услуг, выполняется в небезопасном режиме из-за использования штрих-кода, три команды: печать простая, печать с гтд, печать без услуг)
  • УПД  (для документа Реализация товаров и услуг и Счет-фактура выданная, выполняется в небезопасном режиме из-за использования штрих-кода)

Related Posts

98 Comments

  1. slazzy

    спасибо тебе, мил человек. Полезное дело делаешь

    Reply ↓
  2. Yimaida

    Очень полезная статья. Понятная и наглядная инструкция. Не будет лишней даже для тех, кто уже создавал ВПФ. Вот неплохая статья на эту же тему http://programmist1s.ru/vneshnie-pechatnyie-formyi-v-1s/. Т.е. за основу понимания создания ВПФ можно брать БСП (Библиотека стандартных подсистем).

    Reply ↓
  3. AleksSF

    Не совсем корректное название статьи

    «Создание внешних печатных форм под управляемым приложением с нуля»

    Правильно было бы «Создание внешних печатных форм под управляемым приложением на основе готовых».

    В статье разобрано только как описать ВПФ и скопировать в нее готовые процедуры и функции.

    Это хорошо когда нужно изменить макет под свои нужды на основе данных которые формирует стандартная форма.

    Но если нужна ВПФ с данными, которых нет в стандартной форме, например СчетЗаказ в котором пропечатывается текущий долг Контрагента. То уже необходимо вносить изменения в функции печати, в запрос и т.д. А вот эти вопросы к сожалению не разобраны.

    Reply ↓
  4. signum2009

    (3) AleksSF, Да согласен, что статья несколько минимизирована, но если непосредственно править данные, то нужно править именно те процедуры и функции, которые скопированы, а тут может быть очень большое поле для деятельности….я думал о том что бы упомянуть это в статье, но посчитал что в принципе это будет понятно)) да и к тому же, работа с данными в тех же БП 3 и УТ 11 очень сильно отличается, по этому по идее нужно писать две статьи: создание ВПФ с корректированием данных для БП, и создание ВПФ с корректированием данных для УТ 11. В принципе есть такая идея, но нужна ли она людям?

    Reply ↓
  5. welard

    (4)signum2009, конечно нужна. Потому как с внешними печатными формами на основе стандартных все же проще дела обстоят. Писать мало, в основном копировать. А вот если нужны допданные вывести на форму, или еще «веселее» выбрать какие то параметры перед выводом на печать (как в 1-Т или транспортной накладной), вот тут то проблемы и начинаются.

    Reply ↓
  6. pahich

    (5) welard, Не вижу сложности. Если Вы — пишущий программист 1С, но ни разу не создавали ВПФ для УФ, то прочтение данной статьи заполнит брешь «как сделать», а уж что откуда взять и куда вывести, с такими моментами у Вас сложностей возникнуть не должно.

    (4) на мой взгляд, дополнительных статей с «разжовыванием» получения данных не надо. Данные меняются гораздо чаще чем механизм создания ВПФ. Спасибо за статью!

    Reply ↓
  7. Solovyeff

    Эту бы статью, да несколько месяцев назад, не пришлось бы тратить часы на поиск информации (довольно таки длительный поиск), с другой стороны это позволяет лучше усвоить материал, когда сам ищешь по крупицам и создаешь полную картину, но то дело вкуса и количества свободного времени) Автору однозначно плюс.

    Reply ↓
  8. burlakov

    очень хорошая статья! спасибо! напишите продолжение про использование скд на внешке. сам разбирался — все нетривиально несколько.

    Reply ↓
  9. AzagTot

    Автору спасибо за труд! Полезная статья.

    Reply ↓
  10. Bambini23

    Добрый день!

    Спасибо за статью — полезно! Все по полочкам разложено.

    А у меня вот какой вопрос, может быть не совсем по теме. Когда мы печатаем выводим стандартную печатную форму в ут, вызывается обработка.ПечатьСчетовНаОплату. А когда печатаем через внешнюю естественно, вызова этой обработки не происходит. Зачем это надо? Допустим я собираюсь делать отправку по электронной почте, и в случае печати через эту обработку, у меня автоматом подбираются контактные лица. А если печатать просто внешнюю форму, естественно, что никакие контактные лица не выбираются.

    Не пробовали делать впф через вызов этой самой обработки?

    Reply ↓
  11. Bambini23

    Прошу прощения=) Вопрос снят. После чашечки кофе голова соображает в разы лучше=)

    Reply ↓
  12. opus70

    прошу прощения а кто нибуть подскажет как программно распечатать внешнию печатную форму

    т.е. хочу на форму добавить кнопку и по этой кнопке распечатать внешнию печатную форму

    давно ищу ответ на этот вопрос

    Reply ↓
  13. vicmos

    Спасибо

    Reply ↓
  14. M.Nikitin

    Спасибо, полезный материал!

    Reply ↓
  15. markovki

    Плюсанул конечно за полезную статью и труды, но код картинками…

    Reply ↓
  16. maldinitaly

    Спасибо, автору за труды и конечно плюс. Очень полезная статья.

    Reply ↓
  17. wolfsoft

    (15) Поддержу. Начало было интересное, думал наконец-то статья систематизирующая, а в итоге разобран пример создания простейшей печатной формы, которую вполне можно сделать самому, взяв за основу любую внешнюю форму, даже если до этого ни разу их не делал, там всё интуитивно понятно.

    Reply ↓
  18. FractonKireyev

    Статья полезная! Пробел в знаниях на тему «как сделать» закрывает хорошо. А всё остальное (где взять данные, как вывести на печать и прочее) — это не тема для таких статей, это в каждой задаче индивидуально!

    За такую статью однозначно спасибо и плюс.

    Reply ↓
  19. ignor

    Не плюсую. Мне интересна тема организации ВПФ с опцией «ОткрытиеФормы», а она нигде толком не раскрыта. Мне надо что бы у пользователя при вызове открывалась некая моя форма.

    Reply ↓
  20. Roby

    Мне тоже очень интересна тема организации ВПФ с опцией «ОткрытиеФормы». Допустим, указала эту опцию и форма открылась. Что дальше? как пустить на печать?

    Reply ↓
  21. Styvi

    Плюсую за трудолюбие…

    Reply ↓
  22. AganinEvgeniy

    Спасибо автору за хорошо разобранный пример, который удобно использовать для начала экспериментов! Все понятно и доступно.

    Reply ↓
  23. bydk

    В конфигурации основанной на БСП 2.1+ функция СведенияОВнешнейОбработке() будет выглядеть так:

     ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(«2.1.3.1»);

ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиПечатнаяФорма();
ПараметрыРегистрации.Версия = «0.6»;
ПараметрыРегистрации.БезопасныйРежим = Истина;
ПараметрыРегистрации.Назначение.Добавить(«Документ._ДемоСчетНаОплатуПокупателю»);

НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
НоваяКоманда.Представление = НСтр(«ru = ‘Счет на оплату'»);
НоваяКоманда.Идентификатор = «СчетЗаказ»;
НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовСерверногоМетода();
НоваяКоманда.ПоказыватьОповещение = Истина;
НоваяКоманда.Модификатор = «ПечатьMXL»;

    Показать

    Примеры почти всех видов внешних обработок можно посмотреть в Демо по БСП.

    (21) ignor, (22) Roby, про предварительное открытие формы можно почитать здесь!

    Reply ↓
  24. DAnry

    Спасибо, грамотная статья. Работаю в основном с обычными формами, но приходится переходить понемногу на управляемые.

    Reply ↓
  25. qwed557

    Что такое модификатор — ПечатьXML, почему во всех печатках именно так называется, где это используется, где к этому модифиатору идет обращение?

    Reply ↓
  26. Roby

    (25) bydk, спасибо, как раз то, что нужно

    Reply ↓
  27. Oleg1708

    Жаль что механизм ВПФ меняется быстро.

    А параметр Использование = «Открытие Формы» только в последних версиях БПС работает.

    Reply ↓
  28. AlX0id

    Плюс за доходчивость изложения — буду проггерам начинающим рекомендовать )

    А то описание БСП конечно хорошо, но тяжеловато в усвоении.

    Reply ↓
  29. Algiz

    Спасибо за статью, полезно к усвоению, ну и как заметка теперь будет

    Reply ↓
  30. AlexeyPapanov

    Очень доступная статья. Спасибо автору!

    Reply ↓
  31. Патриот

    (12) opus70, может я что не так понял, в чём сложность? создаёшь команду в модуле формы, на основе команды элемент формы и нижеследующие процедуры:

    &НаКлиенте
Процедура Команда1(Команда)
Команда1НаСервере();
КонецПроцедуры

&НаСервереБезКонтекста
Процедура Команда1НаСервере()
ОбработкаОбъект = ВнешниеОбработки.Создать(«Полный путь к файлу ВПФ»,);
ОбработкаОбъект.Печать();
КонецПроцедуры

    Показать

    Автору статьи плюс, естественно)

    Reply ↓
  32. chmv

    Супер полезно

    Reply ↓
  33. warrior1985

    Огромнейшее спасибо Аффтору! Все разложено по полочкам, если времени особо нет, то пригодится для быстрого получения практических навыков создания внешних печатных форм на платформе 1С: Предприятие 8.3.

    Reply ↓
  34. KliMich

    Спасибо! Очень полезно и познавательно!

    Маленькая просьба. У меня одному клиенту захотелось, чтобы счет формировался не в XML, а в Word…

    Можно ли в данной статье осветить еще и такой вариант?

    Reply ↓
  35. q_i

    Хорошо написано.

    Только не очень понял вот что:

    Следующий элемент имеет название «БезопасныйРежим», его необходим устанавливать в значение истина или ложь, в зависимости от того необходимо устанавливать или отключать безопасный режим во время выполнения обработки. Мы установим значение Ложь.

    а в самом коде:

    ПараметрыРегистрации.Вставить(«БезопасныйРежим»,Истина);

    Reply ↓
  36. KliMich

    Обычно устанавливается

    ПараметрыРегистрации.Вставить(«БезопасныйРежим»,Истина);

    Но иногда требуется установить «БезопасныйРежим» в Ложь, когда используются какие либо внешние компоненты или .dll (также могут вытаскиваться из макета)

    У меня потребовалась данная установка, когда во внешней печатной форме «Трудового догора» потребовалось применять СКЛОНЕНИЯ.

    Reply ↓
  37. Puk2

    (36) KliMich, во-первых, примеры различных видов внешних отчетов, обработок и печатных форм можно увидеть в самой конфигурации БСП в разделе Администрирование — Печатные формы, отчеты и обработки (users.v8.1c.ru..SSL22); во-вторых, если нет доступа в ИТС, то напишите в личку — отправлю обработку _ДемоДополнительнаяОбработкаПечатиMSWordНазначаемая.epf

    Reply ↓
  38. Algiz

    Спасибо, позновательная статья

    Reply ↓
  39. wolverine87

    Спасибо большое. Много познавательного и исчерпывающе. Автору +1))

    Reply ↓
  40. tindir

    Отлично «расписано» как собрать на коленке простейшую ВПФ для УФ. НО это уже давно есть на ИТС. А вот чего толком нет на ИТС, это — как пользоваться остальными видами Внешних обработок. Вот такую бы статью. Это было бы вооще «щиколад»!

    Reply ↓
  41. maiUsik

    Добрый день!

    Только начинаю разбираться с ВПФ, сделала все как описано в статье, но при попытке вывести документ на печать появляется следующая ошибка:

    {ОбщийМодуль.ДополнительныеОтчетыИОбработки.Модуль(221)}: Недостаточно фактических параметров ВнешняяОбработкаОбъект.Печать(

    Подскажите, пожалуйста, что нужно поправить, не могу сообразить 🙁

    Reply ↓
  42. signum2009

    (43) maiUsik, вот так должно быть:

    Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

    ЗЫ по остальным вопросам, готовлю статью, о возможности создания ВПФ с вводом дополнительных параметров.

    Так как прямого способа решения данной задачи с использованием БСП нет, то будет предложено три альтернативных метода…

    Reply ↓
  43. maiUsik

    (44)

    Все получилось, спасибо большое! 🙂

    Reply ↓
  44. signum2009

    Вот продолжение этой статьи: http://infostart.ru/public/295368/

    где будет предложено два способа создать ВПФ с возможностью передачи параметров.

    Reply ↓
  45. niko75

    Все превосходно написано. Возникает ошибка:

    {Обработка.СчетНаОплату1.МодульОбъекта(268,7)}: Слишком много фактических параметров (ДобавитьКоманду)

    <<?>>»ПечатьMXL»); (Проверка: Толстый клиент (обычное приложение))

    Помогите разобраться.

    Reply ↓
  46. niko75

    Разобрался, несколько раз код переписывал, копировал — вставлял, в итоге ругаться перестал.

    Reply ↓
  47. Hilda Fildgerald

    Добрый день! Вопрос вам как к эксперту. Ваша внешняя печатная форма счета работает после обновления БП 3.0 на релиз 3.0.37.32? Моя отказалась, ошибка:

    ВнешняяОбработка.ЗаявкаПокупателяЮрЛицоНовый.МодульОбъекта(14)}:

    Метод объекта не обнаружен (ПолучитьДанныеФайлаИДвоичныеДанные)

    ДанныеКартинки = РаботаСФайламиСлужебныйВызовСервера.ПолучитьДанныеФайлаИДвоичныеДанные(Организация.ФайлЛоготип); логотипов и картинок нет, почитав форум нашла пост где рекомендовано убрать из ПолучитьДанныеФайлаИДвоичныеДанные(Организация.ФайлЛоготип) слово Получить. Эта ошибка проскочила, но следующая: {ВнешняяОбработка.ЗаявкаПокупателяЧастноеЛицоНовый.МодульОбъекта(573)}:

    Поле объекта не обнаружено (ФИОПредпринимателя)

    ОбластьМакета.Параметры.ФИОПредпринимателя = СведенияОПолучателе.ФИОПредпринимателя;

    Вот и не знаю что делать? Может подскажите что?

    Reply ↓
  48. signum2009

    Да там изменилась структура процедур печати, необходимо переделать обработку…

    Reply ↓
  49. Hilda Fildgerald

    Вот с этим-то и проблема. Я бухгалтер, а не программист.

    Reply ↓
  50. Natali_77

    Спасибо огромное за статью! С её помощью без проблем создала внешнюю печатную форму,хотя в 8.3 ни разу не работала, только в 8.1. Спасибо, что делитесь таким важным опытом! Всё доходчиво и без заморочек!

    Reply ↓
  51. korppinen

    Спасибо!

    Reply ↓
  52. hladograd

    Спасибо за статью, все работает.

    Reply ↓
  53. KindLion

    Большое спасибо за классную статью!

    Reply ↓
  54. pavelyar

    Спасибо за статью!

    Reply ↓
  55. СержТ

    Спасибо. Познавательно.

    Reply ↓
  56. mike581

    ВПФ на УФ создавал, но как-то интуитивно. А теперь буду осознано. Полезная статья. Спасибо.

    Reply ↓
  57. lamp

    Спасибо автору, полезная статья. Проследовал по всем пунктам и получил результат.

    Reply ↓
  58. ccserg

    Спасибо !

    БГУ 2.0 не подключается обработка -Слишком много фактических параметров

    в ошибке не видно на что ругается , где искать ?

    Reply ↓
  59. cheiser1982

    Подскажите, как можно отладить работу внешней печатной формы?

    Reply ↓
  60. cdover

    Подскажите пожалуйста, у вас после добавления печ формы в справочник, она появилась в меню Печать документа как непосредственно печатная форма, а у меня как строка «Дополнительные печатные формы» по нажатию на которую у меня открывается выбор печатной формы которую я хочу запустить. Как можно убрать этот лишний выбор, тобы как у вас на картинках выбиралась непосредственно печатная форма из меню Печать?

    И как можно заменить стандартную печатную форму в меню Печать, на внешнюю из справочника?

    код в модуле объекта

    Функция СведенияОВнешнейОбработке() Экспорт

ПараметрыРегистрации = Новый Структура;
МассивНазначений = Новый Массив;
МассивНазначений.Добавить(«Документ.усПриемка»);
ПараметрыРегистрации.Вставить(«Вид», «ПечатнаяФорма»);
СозданиеСвязанныхОбъектов…
ПараметрыРегистрации.Вставить(«Назначение», МассивНазначений);
ПараметрыРегистрации.Вставить(«Наименование», «Приемный лист (Внешний)»);
ПараметрыРегистрации.Вставить(«БезопасныйРежим», ЛОЖЬ);
ПараметрыРегистрации.Вставить(«Версия», «1.0»);
ПараметрыРегистрации.Вставить(«Информация», «Приемный лист с корректировками»);
ТаблицаКоманд = ПолучитьТаблицуКоманд();
ДобавитьКоманду(ТаблицаКоманд, «Приемный лист (Внешний)», «ПриемныйЛистВнешний», «ВызовСерверногоМетода», Истина, «ПечатьMXL»);
ПараметрыРегистрации.Вставить(«Команды», ТаблицаКоманд);

Возврат ПараметрыРегистрации;

КонецФункции

Функция ПолучитьТаблицуКоманд()

Команды = Новый ТаблицаЗначений;
Команды.Колонки.Добавить(«Представление», Новый ОписаниеТипов(«Строка»));
Команды.Колонки.Добавить(«Идентификатор», Новый ОписаниеТипов(«Строка»));
Команды.Колонки.Добавить(«Использование», Новый ОписаниеТипов(«Строка»));
Команды.Колонки.Добавить(«ПоказыватьОповещение», Новый ОписаниеТипов(«Булево»));
Команды.Колонки.Добавить(«Модификатор», Новый ОписаниеТипов(«Строка»));

Возврат Команды;

КонецФункции

Процедура ДобавитьКоманду(ТаблицаКоманд, Представление, Идентификатор, Использование, ПоказыватьОповещение = Ложь, Модификатор = «»)

НоваяКоманда = ТаблицаКоманд.Добавить();
НоваяКоманда.Представление = Представление;
НоваяКоманда.Идентификатор = Идентификатор;
НоваяКоманда.Использование = Использование;
НоваяКоманда.ПоказыватьОповещение = ПоказыватьОповещение;
НоваяКоманда.Модификатор = Модификатор;

КонецПроцедуры

    Показать

    Reply ↓
  61. Nik_novosib

    (61) cheiser1982, Вот здесь посмотрите: http://www.obrabotki.com/otladka-bsp-1s/ За пару шагов получаете возможность отладки, причем режим отладки перезапускать не нужно.

    Reply ↓
  62. Nik_novosib

    (62) cdover, А что за конфигурация? Нужно смотреть какая версия БСП. Заменить вряд ли получится без снятие с поддержки. Кнопку «печать» платформа на КП выводит сама если не ошибаюсь.

    P.S. Сам сейчас разбираюсь ВО. Могу ошибаться.

    Reply ↓
  63. Maratuster

    Перевод внешних печатных форм с бухгалтерии 2.0 на 3.0, по сути, должен происходить схожим образом?

    Reply ↓
  64. avto1c
    Извиняюсь за много букв и картинок))

    Все буквы осилил. Плюс.

    Reply ↓
  65. a_l_e_xj

    Начало статьи замечательное, а потом не очень. Замах есть, а что если скопировать процедуры неоткуда?

    Хотелось бы упоминания о МассивОбъектов[0] — о синтаксисе, как получить доступ к объекту в котором была вызвана печатная форма.

    Reply ↓
  66. turinx

    Большое спасибо, очень понятно и грамотно все объяснено! Первый раз создал ВПФ, все по статье, очень помогло.

    Пара несоответствий: когда вставляем модификатор команды, написано «Печать XML», на картинке — «Печать MXL», и второе — значение «Безопасный режим» в ПараметрыРегистрации, в тексте — Ложь, на картинке — Истина.

    Reply ↓
  67. ovt256

    (44)

    За статью спасибо!

    Пытаюсь в УТ 11 по аналогии создать ВПФ Счет из Заказа клиента. Столкнулся с аналогичной ошибкой. Убрал по Вашей рекомендации параметр «ПараметрыПечати» из Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

    Теперь ошибка следующего вида:

    {ВнешняяОбработка.СчетДоговорВнешний.МодульОбъекта(56,73)}: Переменная не определена (ПараметрыПечати)

    СформироватьПечатнуюФормуСчетНаОплату(СтруктураТипов, ОбъектыПечати, <<?>>ПараметрыПечати)); (Проверка: Сервер)

    Reply ↓
  68. evg_m

    Как у вас в 14 году получился релиз УТ 11.1.15.16, если сейчас 11.1.10.197??

    Reply ↓
  69. Галина11

    Спасибо огромное! с нуля научилась создавать свои формы!!

    Reply ↓
  70. shotsdv

    В БП 3.0.43.147 эта ВПФ не подключается.

    Пишет, что не является объектом «Добавить»

    Reply ↓
  71. shotsdv

    А так статья очень полезная для всяких чайников, типа меня 🙂

    Reply ↓
  72. АИС

    Добрый день,

    БП 3.0.43.152 форма не работает.

    1я ошибка Поле не найдено СчетНаОплатуюЗаРуководителяПоПриказу

    2я ошибка Таблица не найдена Документ.СчетНаОплатуПокупателю.Услуги

    Reply ↓
  73. viktor_and_ko

    Здравствуйте, может быть подскажите как можно разрешить пользователям редактировать макет ВПФ в режиме предприятия?

    Reply ↓
  74. shotsdv

    Мда, статья, в целом, полезна, только на последних релизах БП она не подключается… 🙁

    Reply ↓
  75. RomVin

    Что правда на последних релизах не работает может подкорректировать статью для чайников типо меня как надо правильно делать?

    Reply ↓
  76. fixin

    Плохо что все в картинках. текст не скопипастить.

    Reply ↓
  77. ИНТЕГРА

    Это для бухгалтера писалось? 🙂

    Вот статья для программиста:

    // Возвращает сведения о внешней обработке.
Функция СведенияОВнешнейОбработке() Экспорт

ПараметрыРегистрации = ДополнительныеОтчетыИОбработки.СведенияОВнешнейОбработке(«2.1.1.10»);

ПараметрыРегистрации.Вид = ДополнительныеОтчетыИОбработкиКлиентСервер.ВидОбработкиЗаполнениеОбъекта();
ПараметрыРегистрации.Версия = «1.0»;
ПараметрыРегистрации.Назначение.Добавить(«Документ.СборкаЗапасов»);
ПараметрыРегистрации.БезопасныйРежим = Ложь;

НоваяКоманда = ПараметрыРегистрации.Команды.Добавить();
НоваяКоманда.Представление = НСтр(«ru = ‘Заполнить партии в документе'»);
НоваяКоманда.Идентификатор = «ЗаполнитьПартииСборкаЗапасов»;
НоваяКоманда.Использование = ДополнительныеОтчетыИОбработкиКлиентСервер.ТипКомандыВызовКлиентскогоМетода();
НоваяКоманда.ПоказыватьОповещение = Истина;

Возврат ПараметрыРегистрации;

КонецФункции

    Показать

    Взять отсюда: http://zdst.net/parametry-registratsii-vneshnej-obrab/

    Reply ↓
  78. botcc

    А как сделать так чтоб по результатам выполнения определенных условий печатная форма не выводилась а появлялось сообщение пользователю?

    в 8.2 достаточно Сообщить(«Парам пам пам») и вместо макета передать Неопределено.

    Reply ↓
  79. _Ramzes

    Спасибо большое!

    Просто и понятно.

    Reply ↓
  80. monkbest

    Исчерпывающее http://prosto1s.ru/index.php/oblako-tegov/3-pechatnie-fomi

    Reply ↓
  81. user827325

    Спасибо большое, статья очень хорошо и подробно все описывает. Автору низкий поклон!

    Reply ↓
  82. tena

    Большое спасибо автору!!! Попробую создать печатную форму по этой инструкции, надеюсь все получится))

    Reply ↓
  83. roma_semenov79

    Добрый день. Хорошая инструкция, автору спасибо, но не нашел в ней — как передать свои параметры отправки по электронной почте? Дело в том, что, например, в БП 3.0 при попытке отправки сформированной внешней печатной формы — параметры отправки (получатель, тема, тело письма) будут такими же, как и во встроенной форме. Как их можно изменить?

    Reply ↓
  84. riposte

    Код в виде скриншотов… Написано одно, а на скриншотах другое… Причем в важных местах нестыковки. Почему по тексту ПечатьXML, а на «картинке кода» нарисовано ПечатьMXL? И прочие подобные.

    Такая себе, я бы сказал, статья.

    Reply ↓
  85. IrinaU
    И теперь осталась одна небольшая хитрость, без которой ваш внешний отчет не будет работать.

    Спасибо автору за разъяснения. Очень выручил

    Reply ↓
  86. user633533_encantado

    Устарела эта статья, если использовать правильно функции БСП, то для объявления обработки нужна только одна функция и в три раза меньше кода.

    Reply ↓
  87. sty1000

    Пробую создать внешнюю печатную форму для розницы 2,2, где в поступлении товара будет выводится и код, и артикул. Вроде готово, но 1с говорит, что недостаточно фактических параметров.

    Reply ↓
  88. user1132335

    Такая же проблема! Недостаточно фактических параметров. Подскажите, что нужно добавить?)

    Reply ↓
  89. user1132335

    (90) Удалось как то исправить ошибку (недостаточно фактических параметров)? буду очень признательна!!!

    Reply ↓
  90. webester

    Пройдут тысячи лет. БСП перестанет существовать и воскреснет как ПСБ. А люди будут спрашивать почему не работает код из этой статьи.

    Reply ↓
  91. signum2009

    (93) Даже в старой редакции код был рабочий.

    По этой логике вообще ни чего писать не нужно, т.к. все когда-то устареет…

    Reply ↓
  92. webester

    (94) По этой логике устаревшие данные следует либо обновлять, либо убирать вообще, чтобы не вводить людей в заблуждение. Особенно начинающих.

    Reply ↓
  93. signum2009

    (95) Все ли свои публикации Вы обновляете на текущие релизы?

    Reply ↓
  94. webester

    (95)Логика когда нечего сказать, надо сказать «сам дурак»? Или в чем смысл данного выпада?

    Reply ↓
  95. mondordom

    Спасибо огромное! Мега-полезная статья.

    Только позволю себе одно замечение: «Управляемое приложение» <> «Приложение, использующее БСП».

    Поэтому название я бы поменял. Или, хотя бы, в предисловии к статье сделал соответствующий дисклаймер

    Reply ↓
  96. Vida

    (90)

    (91)

    (92)

    Мне тоже так писало.

    Удалила лишние параметры:

    Было

    Процедура Печать(МассивОбъектов, ПараметрыПечати, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

    Стало

    Процедура Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода) Экспорт

    Reply ↓
  97. Vida

    (21) Вы нашли информацию?

    Reply ↓
  98. signum2009

    (106) Может это поможет

    https://infostart.ru/public/295368/

    Правда, статья старая, еще не обновил

    Reply ↓

Leave a Comment

Ваш адрес email не будет опубликован. Обязательные поля помечены *