Функция получения даты из текста по форматной строке

16.05.2017 25 Comments

Инструментарий разработчика, Разработка

Преобразует текст в дату при условии наличия форматной строки

Несколько громоздская, но полезная функция.

Добавил распознование строковых месяцев, но только на русском языке.

Очень красивое решение предоставил ildarovich, советую использовать сразу его код:

Функция СтрокаВДату(Знач ФорматДаты, Знач Дано, Ошибка = Ложь) Экспорт
Попытка
ё = Формат('00010101', "ДФ=" + ФорматДаты) // - необязательная проверка первого правильности параметра
Исключение
Ошибка = Истина;
Возврат '00010101'
КонецПопытки;
Ч = Новый Соответствие;
Для ё = 1 По СтрДлина(ФорматДаты) + 7 Цикл
Ч[Сред(ФорматДаты + "dMyHhms", ё, 1)] = 0 // - инициализация частей даты
КонецЦикла;
Для ё = 1 По 12 Цикл
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMММ"), Формат(ё, "ЧЦ=4; ЧВН=")); // - замена названий месяцев числами
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), "ДФ=MMМ" ), Формат(ё, "ЧЦ=3; ЧВН="))
КонецЦикла;
Для ё = 1 По СтрДлина(ФорматДаты) Цикл
Ч[Сред(ФорматДаты, ё, 1)] = 10 * Ч[Сред(ФорматДаты, ё, 1)] + Найти("123456789", Сред(Дано, ё, 1)); // - накопление частей даты
Ошибка = Ошибка ИЛИ Найти("dMyHhms", Сред(ФорматДаты, ё, 1)) И НЕ Найти("0123456789", Сред(Дано, ё, 1)) // - необязательная проверка на цифры
КонецЦикла;
Ч["y"] = Ч["y"] + ?(Ч["y"] < 50, 2000, ?(Ч["y"] < 100, 1900, 0)); // - дополнение двух цифр года до четырех
Попытка
Возврат Дата(Ч["y"], Ч["M"], Ч["d"], Ч["H"] + Ч["h"], Ч["m"], Ч["s"])
Исключение
Ошибка = Истина;
Возврат '00010101'
КонецПопытки
КонецФункции

Моя функция:

Функция ПолучитьДатуИзТекста(Текст,ФорматнаяСтрока) Экспорт
Перем Значение;

ПустаяДата = '00010101';
Год = 1; Месяц=1; День = 1; час = 0; Мин=0; Сек=0;
тмпТекст = Текст;
ЗначащиеСимволы = "dMyHhms";
СтрокаПараметра = "";
ФорматнаяСтрока = СокрЛП(ФорматнаяСтрока)+" ";
ПредСимв = Лев(ФорматнаяСтрока,1);
Для к=1 по СтрДлина(ФорматнаяСтрока) Цикл
Симв = Сред(ФорматнаяСтрока,к,1);
Если ПредСимв<>Симв Тогда
Если Найти(ЗначащиеСимволы,ПредСимв)>0 Тогда
//ЭтоПараметр
Если СтрДлина(СтрокаПараметра)=2 Тогда
Попытка
Значение = Число(Лев(тмпТекст,2));
Исключение
#Если Клиент Тогда
Предупреждение("Не удалось выполнить преобразование!");
#КонецЕсли
Возврат ПустаяДата;
КонецПопытки;

тмпТекст = Сред(тмпТекст,3);
ИначеЕсли СтрокаПараметра="yyyy" Тогда
Попытка
Значение = Число(Лев(тмпТекст,4));
Исключение
#Если Клиент Тогда
Предупреждение("Не удалось выполнить преобразование!");
#КонецЕсли
Возврат ПустаяДата;
КонецПопытки;
тмпТекст = Сред(тмпТекст,5);
ИначеЕсли СтрДлина(СтрокаПараметра)=1 Тогда
дл = "";
Попытка
Значение = Число(Лев(тмпТекст,2));
Исключение
Попытка
Значение = Число(Лев(тмпТекст,1));
дл=1;
Исключение
#Если Клиент Тогда
Предупреждение("Не удалось выполнить преобразование!");
#КонецЕсли
Возврат ПустаяДата;
КонецПопытки;
КонецПопытки;

Если дл="" Тогда
Если (СтрокаПараметра = "d" и Значение>31)ИЛИ(СтрокаПараметра = "M" и Значение>12)ИЛИ(СтрокаПараметра = "H" и Значение>23)
ИЛИ(СтрокаПараметра = "h" и Значение>12)ИЛИ(СтрокаПараметра = "m" и Значение>59)ИЛИ(СтрокаПараметра = "s" и Значение>59) Тогда
Попытка
Значение = Число(Лев(тмпТекст,2));
дл=2;
Исключение
#Если Клиент Тогда
Предупреждение("Не удалось выполнить преобразование!");
#КонецЕсли
Возврат ПустаяДата;
КонецПопытки;
Иначе
Попытка
Значение = Число(Лев(тмпТекст,1));
дл=1;
Исключение
#Если Клиент Тогда
Предупреждение("Не удалось выполнить преобразование!");
#КонецЕсли
Возврат ПустаяДата;
КонецПопытки;
КонецЕсли;
КонецЕсли;

тмпТекст = Сред(тмпТекст,дл+1);
ИначеЕсли СтрокаПараметра="MMM" или СтрокаПараметра="MMMM" Тогда
Значение = 0;
Для м=1 по 12 Цикл
ТекстМесяца = Сред(Формат(Дата(2000,м,1),"ДФ=d."+СтрокаПараметра),3);
Если Найти(тмпТекст,ТекстМесяца)>0 Тогда
Значение = м;
Прервать;
КонецЕсли;
КонецЦикла;
Если Значение = 0 Тогда
#Если Клиент Тогда
Предупреждение("Не удалось выполнить преобразование!");
#КонецЕсли
Возврат ПустаяДата;
КонецЕсли;
тмпТекст = Сред(тмпТекст,СтрДлина(ТекстМесяца)+1);
Иначе
#Если Клиент Тогда
Предупреждение("Не верный формат даты или форматной строки!");
#КонецЕсли
Возврат ПустаяДата;
КонецЕсли;

//Установим параметры
Если ПредСимв = "d" Тогда
День = Значение;
ИначеЕсли ПредСимв = "M" Тогда
Месяц = Значение;
ИначеЕсли ПредСимв = "y" Тогда
Если СтрокаПараметра = "yy" Тогда
ТекВек = 100*Цел(Год(ТекущаяДата())/100);
год = ?(Значение>=Год(ТекущаяДата())-текВек+50,ТекВек-100,ТекВек)+Значение;
Иначе
Год = Значение;
КонецЕсли;
ИначеЕсли ПредСимв = "H" Тогда
час = Значение;
ИначеЕсли ПредСимв = "h" Тогда
час = Значение;
#Если Клиент Тогда
Сообщить("Вычисление часа не гарантировано.");
#КонецЕсли
ИначеЕсли ПредСимв = "m" Тогда
Мин = Значение;
ИначеЕсли ПредСимв = "s" Тогда
Сек = Значение;
КонецЕсли;

Иначе
//Это Разделитель
тмпТекст = Сред(тмпТекст,СтрДлина(СтрокаПараметра)+1);
КонецЕсли;
СтрокаПараметра = Симв;
Иначе
СтрокаПараметра=СтрокаПараметра+Симв;
КонецЕсли;
ПредСимв = Симв;
КонецЦикла;
Возврат Дата(Год,Месяц,День,час,Мин,Сек);
КонецФункции

Related Posts

25 Comments

  1. Поручик

    (0) Вместо Предупреждение() лучше использовать Сообщить().

    Reply ↓
  2. kapustinag

    (0) Вот в этом месте нужно более интеллектуально:

    Если СтрокаПараметра = «yy» Тогда

    Год = 2000+Значение;

    Если Значение=»99″, то год должен быть 1999, а если =»13″, то год 2013. Часто применяют сравнение с 50. Если значение меньше 50, то считаем нынешний век, а если больше — двадцатый век. Впрочем, это уже зависит от смысла ожидаемых данных. Может быть, на Ваших данных именно Ваше условие правильное.

    Reply ↓
  3. ildarovich

    В статье Выразить строку как число и строку как дату в запросе показано, как тоже самое можно сделать в запросе. Ну а данное решение нужно сократить раз в десять — объем кода не соответствует сложности решаемой задачи.

    Reply ↓
  4. spetzpozh

    Сообщить(), если учитывать рекомендации 1С, использовать не стоит вообще никогда 🙂 СообщениеПользователю есть.

    Reply ↓
  5. diver.sun
    Reply ↓
  6. Crazy Professor

    (2) kapustinag,

    Кстати да, но я не знаю по какому принципу 1с сама это дело конвертирует у меня переключает на прошлый век с 30 включительно, но я не уверен, что это как-то зависит от текущей даты.

    Сделал так:

    ТекВек = 100*Цел(Год(ТекущаяДата())/100);
год = ?(Значение>=Год(ТекущаяДата())-текВек+50,ТекВек-100,ТекВек)+Значение;
    Reply ↓
  7. Crazy Professor

    (3) ildarovich,

    Предложите готовое решение, пожалуйста — я с радостью его применю для своих целей.

    Статья занятная, но не уверен, что универсальное решение будет менее громоздким чем обычный код. Однако, для больших объемов данных применение запроса может увеличить производительность.

    Reply ↓
  8. Crazy Professor

    (5) diver.sun,

    Чего-то я не понял как эта обработка должна отрабатывать при изменении порядка элементов форматной строки или вообще при исчезновении некоторых (например такой «yyMMdd», из данных с которыми я работаю). Но идея занятная — от обратного. В упрощенном варианте можно было перебирать все значения с точностью до секунды от -50 до +50 лет от текущей даты и искать подходящее через запрос :).

    Reply ↓
  9. diver.sun

    Тогда она не находит позиции старта стопа изменяемого значения.

    Reply ↓
  10. Crazy Professor

    (9) diver.sun, твой метод дал идею по распознаванию месяцев строкового формата.

    Reply ↓
  11. ildarovich

    (7) Вот готовое решение

    //
Функция СтрокаВДату(Знач ФорматДаты, Знач Дано, Ошибка = Ложь) Экспорт
Попытка
ё = Формат(‘00010101’, «ДФ=» + ФорматДаты) // — необязательная проверка первого правильности параметра
Исключение
Ошибка = Истина;
Возврат ‘00010101’
КонецПопытки;
Ч = Новый Соответствие;
Для ё = 1 По СтрДлина(ФорматДаты) + 7 Цикл
Ч[Сред(ФорматДаты + «dMyHhms», ё, 1)] = 0 // — инициализация частей даты
КонецЦикла;
Для ё = 1 По 12 Цикл
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), «ДФ=MMММ»), Формат(ё, «ЧЦ=4; ЧВН=»)); // — замена названий месяцев числами
Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), «ДФ=MMМ» ), Формат(ё, «ЧЦ=3; ЧВН=»))
КонецЦикла;
Для ё = 1 По СтрДлина(ФорматДаты) Цикл
Ч[Сред(ФорматДаты, ё, 1)] = 10 * Ч[Сред(ФорматДаты, ё, 1)] + Найти(«123456789», Сред(Дано, ё, 1)); // — накопление частей даты
Ошибка = Ошибка ИЛИ Найти(«dMyHhms», Сред(ФорматДаты, ё, 1)) И НЕ Найти(«0123456789», Сред(Дано, ё, 1)) // — необязательная проверка на цифры
КонецЦикла;
Ч[«y»] = Ч[«y»] + ?(Ч[«y»] < 50, 2000, ?(Ч[«y»] < 100, 1900, 0)); // — дополнение двух цифр года до четырех
Попытка
Возврат Дата(Ч[«y»], Ч[«M»], Ч[«d»], Ч[«H»] + Ч[«h»], Ч[«m»], Ч[«s»])
Исключение
Ошибка = Истина;
Возврат ‘00010101’
КонецПопытки
КонецФункции
//

    Показать

    Reply ↓
  12. Crazy Professor

    (11) ildarovich,

    Ну да, я ламмер, очень изящно — преклоняю колено.

    Reply ↓
  13. Crazy Professor

    (11) ildarovich,

    Можно вынести в шапку с указанием авторства? Вдруг кому нужно будет.

    Reply ↓
  14. ildarovich

    (13) Да, конечно, пожалуйста. Только просьба стандартные отступы восстановить (они пропали при вставке кода в комментарий).

    Reply ↓
  15. kuzyara

    (12) код (11) с ошибками.

    Январь прописью не проходит, зачем-то «h» парсит и т.д.

    Reply ↓
  16. Xershi

    Кому интересно повозиться сервер вернул дату формата: «Tue, 10 Oct 2017 15:25:00 +0300».

    Форматная строка выходит «Л=en; ДФ=’ddd, dd MMM yyyy HH:mm:ss'» плюс часовой пояс.

    Reply ↓
  17. smaharbA

    (16)

    «Tue, 10 Oct 2017 15:25:00 +0300»
    Пока СтрНайти(Стр,»  «)>0 Цикл
Стр=СтрЗаменить(Стр,»  «,»»);
КонецЦикла;
МассивДаты=СтрРазделить(Стр,» «);
Для ч=1 По 12 Цикл
Стр=Прав(«0″+ч,2);
Если ВРег(МассивДаты[2])=ВРег(Формат(Дата(«2018″+Стр+»01000000″),»Л=en; ДФ=’MMM'»)) Тогда
Сообщить(Дата(МассивДаты[3]+Стр+МассивДаты[1]+СтрЗаменить(МассивДаты[4],»:»,»»))+(60*60*5));
Возврат;
КонецЕсли;
КонецЦикла;

    Показать

    Reply ↓
  18. spacecraft

    (17)

    Пока СтрНайти(Стр,» «)>0 Цикл

    Стр=СтрЗаменить(Стр,» «,»»);

    КонецЦикла;

    МассивДаты=СтрРазделить(Стр,» «);

    Вот это можно описать одной строкой:

    МассивДаты=СтрРазделить(Стр,» «, Ложь);
    Reply ↓
  19. smaharbA

    Можно, но лучче заменять все двойные пробелы на один.

    Reply ↓
  20. spacecraft

    (19) чем лучше?

    Reply ↓
  21. dobrynin.i.s

    функцию привожу из https://infostart.ru/public/886103/

    Функция ПолучитьДатуВремяИзСтроки(ДатаВремя) Экспорт

Результат = Неопределено;
ДатаВремя = СтрЗаменить(ДатаВремя, «-«, «»);
ДатаВремя = СтрЗаменить(ДатаВремя, «:», «»);
Если СтрДлина(ДатаВремя) — Найти(ДатаВремя, » «) = 5 Тогда // время в формате Ч:ММ:СС
ДатаВремя = СтрЗаменить(ДатаВремя, » «, «0»);
ИначеЕсли Найти(ДатаВремя, «T») > 0 Тогда //время в формате ГГГГММДДTЧЧММСС
ДатаВремя = СтрЗаменить(ДатаВремя, «T», «»);
Иначе // время в формате ЧЧ:ММ:СС
ДатаВремя = СтрЗаменить(ДатаВремя, » «, «»);
КонецЕсли;

ОписаниеТипа = Новый ОписаниеТипов(«Дата»);
Результат = ОписаниеТипа.ПривестиЗначение(ДатаВремя);  // дата и время в виде «ГГГГММДДЧЧММСС»
Если Не ЗначениеЗаполнено(Результат) Тогда
Результат = ОписаниеТипа.ПривестиЗначение(Лев(ДатаВремя, 8));  // только дата «ГГГГММДД»
КонецЕсли;

Возврат Результат;

КонецФункции

    Показать

    Reply ↓
  22. user1040271

    (21)

    Что-то не уверен, что эта функция универсальна, поскольку не задается ожидаемый формат.

    Как он интерпретирует 11.11.11? Или 11.11 или 11?

    Думаю, что она работает только с фиксированными форматами, используемыми в конкретно той задаче для работы с http

    Reply ↓
  23. dobrynin.i.s

    (22)

    в коде есть пояснения

    11.11 или 11 — это вообще не даты.

    11.11 ещё можно догадатся что 11.11.2018 — текущий год (2018), а

    11 — что такое год , месяц, день или секунда

    Reply ↓
  24. user1040271

    (23)

    Об этом и речь — только по данным не всегда можно точно определить формат, особенно по единичному элементу этих данных.

    Если есть ограниченный набор вариантов — то тут, конечно, не проблема: в коде отработать исключения (убрать «Т», например). Уверен, что большинство тут решало такие задачи в ходе своей практики.

    Но универсальные методы на то и универсальные, что бы не привязываться к конкретным случаям.

    Reply ↓
  25. rise

    (11) Круто, но к сожалению некорректно обрабатывает форматы «d» и «M», когда число знаков переменное. d.M.yyyy дает 12.7.2019

    И в этой строке кажется надо в формат числа добавить ЧГ=0

    Дано = СтрЗаменить(Дано, Формат(Дата(1, ё, 1), «ДФ=MMММ»), Формат(ё, «ЧЦ=4; ЧВН=»));

    Reply ↓

Leave a Comment

Ваш адрес email не будет опубликован. Обязательные поля помечены *