Получение информации об экспортных свойствах и методах объектов 1С через COM.

Заложенная еще в 7-й версии 1С:Предприятие возможность использования COM-объектов и подключения внешних компонент, выполненных на языках программирования, поддерживающих работу с COM, несомненно, выводила возможности платформы на качественно новый уровень. Еще бы: и без того богатые возможности 1С расширялись до необозримых пределов. После знакомства с этой возможностью даже создавалось впечатление, что в 1С можно сделать практически все.
Выход системы 1С:Предприятие версии 8.х несколько снизил значимость внешних компонент, так как основные функции уже были реализованы на уровне платформы, например, работа с XML, HTTP, ZIP, электронной почтой и т.д. Но и сама 1С уже перестала быть просто бухгалтерской программой, а значит и далее разработчики будут посредством внешних компонент расширять ее уже и так огромные возможности. Также достаточно часто встречаются схемы подключения к самой 1С по технологии COM со стороны программ, разработанных на C/C++, Delphi и т.д., то есть на языках, поддерживающих работу с COM.

И в том, и в другом случае 1С выступает в качестве OLE сервера, а значит OLE клиент зачастую испытывает необходимость в получении от сервера информации о предоставляемых для использования клиентом свойствах и методах. Частично данная проблема может быть решена посредством использования метаданных, но как же получить список, например, экспортных методов общего модуля? Или вы написали COM объект, который при вызове своих методов принимает от 1С параметры агрегатного типа, и Вам в теле своего объекта нужно определить, что же это Вам при вызове метода такое передали. Список поддерживаемых свойств и методов тоже был бы весьма кстати.

Для начала немного ликбеза. С COM объектами 1С работает через интерфейс IDispatch. Этот интерфейс, в свою очередь, поддерживается всеми объектами агрегатного типа системы 1С:Предприятие и позволяет, помимо прочего, получать подробную информацию о методах объекта (свойства, методы, параметры методов и их типы, типы возвращаемых значений и т.д.). Вот сигнатура его методов (здесь и далее на примере Delphi):

  IDispatch = interface(IUnknown)
    ['{00020400-0000-0000-C000-000000000046}']
    function GetTypeInfoCount(out Count: Integer): HResult; stdcall;
    function GetTypeInfo(Index, LocaleID: Integer; out TypeInfo): HResult; stdcall;
    function GetIDsOfNames(const IID: TGUID; Names: Pointer;
      NameCount, LocaleID: Integer; DispIDs: Pointer): HResult; stdcall;
    function Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer;
      Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult; stdcall;
  end;

Чтобы проверить существование какого-либо единичного метода или свойства у COM-объекта, нужно воспользоваться методом GetIDsOfNames, и сделать это примерно вот так:

function MethodExists(const Obj: IDispatch;
  const MethodName: WideString): Boolean;
  function GetDispID: integer;
  begin
    Obj.GetIDsOfNames(GUID_NULL, @MethodName, 1, LOCALE_SYSTEM_DEFAULT,
      @Result);
  end;
begin
  Result := GetDispID <> DISPID_UNKNOWN;
end;

Для того, чтобы COM объект (далее «сервер») мог «рассказать» вызывающей стороне (далее «клиент») о своих методах, необходимо, чтобы при вызове метода GetTypeInfo он возвращал указатель на реализованный интерфейс ITypeInfo, через который клиент и получает эту информацию. Отметим, что это не является обязательным. В этом случае каждый раз при вызове клиентом метода сервера по имени сначала вызывается метод GetIDsOfNames, который, в случае наличия нужного метода, возвращает его DispID. После этого осуществляется вызов метода Invoke с полученным DispID. В случае с поддержкой ITypeInfo информация о доступных методах и свойствах запрашивается единожды при инициализации объекта, и затем методы вызываются уже сразу по DispID.

Для получения информации о свойствах и методах, используя ITypeInfo, нужно выполнить примерно такой код:

procedure ShowMethods(const Obj: IDispatch);
var
  TypeInfoCount: integer;
  TypeInfo: ITypeInfo;
  TypeAttr: PTypeAttr;
  FuncDesc: PFuncDesc;
  pName: WideString;
  i: integer;
begin
  OleCheck(Obj.GetTypeInfoCount(TypeInfoCount));
  if TypeInfoCount = 0 then
    raise Exception.Create('ITypeInfo не поддерживается!');
  OleCheck(Obj.GetTypeInfo(0, LOCALE_SYSTEM_DEFAULT, TypeInfo));
  OleCheck(TypeInfo.GetTypeAttr(TypeAttr));
  try
    for i := 0 to TypeAttr#k8SjZc9Dxk.cFuncs - 1 do
    begin
      OleCheck(TypeInfo.GetFuncDesc(i, FuncDesc));
      try
        OleCheck(TypeInfo.GetDocumentation(FuncDesc#k8SjZc9Dxk.memid, @pName, nil,
          nil, nil));
        // код обработки и вывода списка свойств и методов
        // ...
      finally
        TypeInfo.ReleaseFuncDesc(FuncDesc);
      end;
    end;
  finally
    TypeInfo.ReleaseTypeAttr(TypeAttr);
  end;
end;

Анализ объектов системы 1С:Предприятие версии 8.х показывает, что далеко не для всех объектов поддерживается получение интерфейса ITypeInfo. В частности, получить его можно для объектов типа «СправочникОбъект», «ДокументОбъект», «ОбработкаОбъект» (но не «ВнешняяОбработкаОбъект»), «РегистрХХХХХХХХХНаборЗаписей» и некоторые другие.

Выход в данной ситуации есть, и он заключается в том, что для своих объектов 1С реализовала поддержку интерфейса IDispatchEx, который также позволяет получать информацию о свойствах и методах. Вот его описание:

  IDispatchEx = interface(IDispatch)
    ['{A6EF9860-C720-11D0-9337-00A0C90DCAA9}']
    function GetDispID(const bstrName: TBSTR; const grfdex: DWORD;
       out id: TDispID): HResult; stdcall;
    function InvokeEx(const id: TDispID; const lcid: LCID; const wflags:
       WORD; const pdp: PDispParams; out varRes: OleVariant; out pei:
       TExcepInfo; const pspCaller: PServiceProvider): HResult; stdcall;
    function DeleteMemberByName(const bstr: TBSTR; 
       const grfdex: DWORD): HResult; stdcall;
    function DeleteMemberByDispID(const id: TDispID): HResult; stdcall;
    function GetMemberProperties(const id: TDispID; const grfdexFetch:
       DWORD; out grfdex: DWORD): HResult; stdcall;
    function GetMemberName(const id: TDispID; out bstrName: TBSTR):
       HResult; stdcall;
    function GetNextDispID(const grfdex: DWORD; const id: TDispID;
       out nid: TDispID): HResult; stdcall;
    function GetNameSpaceParent(out unk: IUnknown): HResult; stdcall;
  end;

Предоставляемая данным интерфейсом информация о методах объекта не такая подробная, как при использовании ITypeInfo, но для нашей цели ее вполне достаточно. Более того: реализация ITypeInfo в объектах системы 1С:Предприятие не позволяет отличить процедуру от функции, а при использовании IDispatchEx это возможно. И главное: IDispatchEx реализован для всех агрегатных объектов (кроме, к сожалению, корневого).

Таким образом, чтобы получить список свойств и методов, используя интерфейс IDispatchEx, необходимо выполнить примерно такой код:

procedure ShowMethods(const Obj: IDispatch);
var
  pDispEx: IDispatchEx;
  iDispID: integer;
  pName: PWideChar;
  Flags: LongWord;
begin

  OleCheck(Obj.QueryInterface(IDispatchEx, pDispEx));
  iDispID := DISPID_UNKNOWN;
  while (pDispEx.GetNextDispID(fdexEnumAll, iDispID, iDispID) = S_OK) do
  begin
    if pDispEx.GetMemberName(iDispID, pName) = S_OK then
    begin
      try
        if pDispEx.GetMemberProperties(iDispID, fdexPropCanAll, Flags)
          = S_OK then
        begin
          // код обработки и вывода списка свойств и методов
          // ...
        end;
      finally
        SysFreeString(pName);
      end;
    end;
  end;
end;

На практике такой подход может быть полезен, например, в случае, если вы написали какой-то COM-объект, принимающий в качестве параметров одинэсовские объекты агрегатного типа. В моей практике был метод, принимающий в качестве параметра или объект типа «Картинка», или «ДвоичныеДанные», и лучшего способа для того, чтобы отличить в теле COM-объекта одно от другого я не нашел.

Для демонстрации метода предлагается для скачивания небольшая утилита, реализующая оба метода получения информации о свойствах и методах объектов (исполняемый файл + исходный код (Delphi XE)).