Добавить к дате рабочие дни в запросе

Был отчет, в котором к неким датам прибавлялось 15 дней функцией ДобавитьКДате(). Но вот понадобилось добавлять к дате не все дни, а только рабочие. Сделал запрос, может быть кому понадобится

Собственно запрос получился такой:

ВЫБРАТЬ Даты.Дата,

 КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК КоличествоРабочихДней,
МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК ДатаКалендаря,
РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря КАК ДатаКалендаряДляГруппировки
ИЗ
РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Даты
ПО (Даты.Дата <= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
И (ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
ПО РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
ГДЕ
(РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный)
ИЛИ РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))

СГРУППИРОВАТЬ ПО
РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря,
Даты.Дата

ИМЕЮЩИЕ
МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря

Таблица «Даты» может содержать любые данные с датой в виде отдельного поля или в виде реквизита документа. Параметр «ГлубинаДней» определяет, как глубоко вперёд просматривать даты относительно входящих дат.

Вот пример работы для одной даты 28.11.2012


Дата	КоличествоРабочихДней	ДатаКалендаря	ДатаКалендаряДляГруппировки
28.11.2012	1	28.11.2012	28.11.2012
28.11.2012	2	29.11.2012	29.11.2012
28.11.2012	3	30.11.2012	30.11.2012
28.11.2012	4	03.12.2012	03.12.2012
28.11.2012	5	04.12.2012	04.12.2012
28.11.2012	6	05.12.2012	05.12.2012
28.11.2012	7	06.12.2012	06.12.2012
28.11.2012	8	07.12.2012	07.12.2012
28.11.2012	9	10.12.2012	10.12.2012
28.11.2012	10	11.12.2012	11.12.2012
28.11.2012	11	12.12.2012	12.12.2012
28.11.2012	12	13.12.2012	13.12.2012
28.11.2012	13	14.12.2012	14.12.2012
28.11.2012	14	17.12.2012	17.12.2012
28.11.2012	15	18.12.2012	18.12.2012
28.11.2012	16	19.12.2012	19.12.2012
28.11.2012	17	20.12.2012	20.12.2012
28.11.2012	18	21.12.2012	21.12.2012
28.11.2012	19	24.12.2012	24.12.2012
28.11.2012	20	25.12.2012	25.12.2012
28.11.2012	21	26.12.2012	26.12.2012
28.11.2012	22	27.12.2012	27.12.2012

В конец запроса осталось добавить условие

И КОЛИЧЕСТВО(РАЗЛИЧНЫЕРегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = &РабочихДней

и отобрать данные по нужному количеству рабочих дней в параметре «РабочихДней»

Ну и в конце полная верия запроса, если захочется опробовать в консоли запросов

ВЫБРАТЬ
РегламентированныйПроизводственныйКалендарь.ДатаКалендаря КАК Дата
ПОМЕСТИТЬ Даты
ИЗ
РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ГДЕ
РегламентированныйПроизводственныйКалендарь.ДатаКалендаря В(&ВходящиеДаты)
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Даты.Дата,
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК КоличествоРабочихДней,
МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) КАК ДатаКалендаря,
РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря КАК ДатаКалендаряДляГруппировки
ИЗ
РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь
ВНУТРЕННЕЕ СОЕДИНЕНИЕ Даты КАК Даты
ПО (Даты.Дата <= РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
И (ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь.ДатаКалендаря)
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1
ПО РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
ГДЕ
(РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный)
ИЛИ РегламентированныйПроизводственныйКалендарь.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))

СГРУППИРОВАТЬ ПО
РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря,
Даты.Дата

ИМЕЮЩИЕ
МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря
И КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = &РабочихДней

32 Comments

anig99 17.12.2012 at 11:05

И в чём новизна? И здесь, и на других форумах тема широко обсуждалась… Данное решение — самое банальное.

Reply ↓
INTECH1 17.12.2012 at 11:10

На новизну не претендовал, просто не нашел решение, когда понадобилось. Можно ссылку на обсуждение?

Reply ↓
anig99 18.12.2012 at 14:23

http://devtrainingforum.v8.1c.ru/forum/thread.jsp?id=584685

http://devtrainingforum.v8.1c.ru/forum/thread.jsp?id=550392

типа так и вариации

Reply ↓
Zas1402 20.12.2012 at 17:16

На новизну не претендовал, просто не нашел решение, когда понадобилось.

Полезная тема.

Reply ↓
Aesh 26.12.2012 at 15:40

В том-то и оно, что обсуждалось, типа «Кури …». Тут парень конкретно написал. Я помню раньше еще писал, но потом какое-то время не работал с 1С, сейчас на свое взглянул (а там еще с планом счетов связано), аж паника продернула, вспоминал бы дня два! Спасибо, ооочень выручил, так бы все писали, а не «Кури…»

Reply ↓
Азбука Морзе 25.04.2013 at 17:18

Идея добавить к дате рабочие дни очень помогла при разработке отчетов, связанных с банковскими днями. Спасибо.

Reply ↓
popro 20.06.2013 at 16:59

как правильно определить глубину дней чтобы не было слишком много или недостаточно?

Reply ↓
INTECH1 20.06.2013 at 17:08

Ну здесь дело в праздниках, если взять, например, какое-нибудь 21.12.2012, то глубина 15 дней не достаточна из-за долгих январских праздников — вот только исходя из таких нюансов. Поэтому Глубина = 15 дней + Максимум количества праздников, вот как-то так

Reply ↓
Yimaida 19.08.2013 at 18:56

Reply ↓
NAKIS 18.12.2013 at 17:23

новое решение или старое — но мне помогло. Автору спасибо огромное))))

Reply ↓
ilonnaa 12.02.2014 at 10:45

Автору +, жаль для бух 3.0 не подходит)

Reply ↓
INTECH1 12.02.2014 at 11:58

(11) ilonnaa, а что там не так, регистр календаря что-ли по-другому называется?

Reply ↓
ilonnaa 12.02.2014 at 21:17

(12) Там регистр по другому называется, + производственный календарь это справочник) ну все получилось, чуть запрос переписав, выложить не могу сервер выключился что-то( завтра если не забуду.

Reply ↓

qwertor 06.08.2014 at 13:28

оставлю для коллекции вариант для Бух.3

Функция  ОтсчитатьРабочиеДни(ДатаОтсчета,Отсрочка)

Запрос = Новый Запрос;
Запрос.Текст = «Select
| ДанныеПроизводственногоКалендаря.ПроизводственныйКалендарь,
| ДанныеПроизводственногоКалендаря.Дата,
| ДанныеПроизводственногоКалендаря.Год,
| ДанныеПроизводственногоКалендаря.ВидДня,
| ДанныеПроизводственногоКалендаря.ДатаПереноса
|
|into
| cal
|from
| РегистрСведений.ДанныеПроизводственногоКалендаря КАК ДанныеПроизводственногоКалендаря
|where
|   ДанныеПроизводственногоКалендаря.Дата between &ДатаОтсчета
|  and DateAdd(&ДатаОтсчета, день, &Отсрочка*2 + 12)
|;
|
|Select
|min(дата) датаОтсрочки
|from(
|Select
|
|c1.дата дата,
|
|count(*) -1 РабочихДней
|
|from cal c1
|left join   cal c2
|on (c2.ВидДня = value(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный) or c2.ВидДня = value(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий))
|and c1.дата>=c2.дата
|group by c1.дата
|having count(*)= &Отсрочка+1
|) tt
|group by  РабочихДней»;
попытка
Запрос.УстановитьПараметр(«ДатаОтсчета», ДатаОтсчета);
Запрос.УстановитьПараметр(«Отсрочка», Отсрочка);
Результат = Запрос.Выполнить().Выгрузить();
Возврат Результат[0].датаОтсрочки;
исключение
конецпопытки;

конецФункции

Показать

Reply ↓

Obvious 06.08.2014 at 13:46

Идея ок. Но задачка редко стоит просто отсечь празники. Рекомендую брать с графиков работы. Так как бух вряд ли полезет править произв календарь (он заходит правит в графике. а произв календарь виржин) ИМХО

Reply ↓
nik-boss 28.05.2015 at 09:43

Спасибо Вам большое! Очень помогло быстро сделать необходимый отчет!

Reply ↓
Nikola1147 12.02.2016 at 11:21

ко второму соединению

полезно будет добавить условие типа (отмечено жирным)

ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.РегламентированныйПроизводственныйКалендарь КАК РегламентированныйПроизводственныйКалендарь1

ПО РегламентированныйПроизводственныйКалендарь.ДатаКалендаря <= РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря

И (ДОБАВИТЬКДАТЕ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря, ДЕНЬ, &ГлубинаДней) > РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря)

иначе много доп сведений (дат) добавляется, которые не очень-то нужны,

разница в скорострельности ощутима на 3-х значениях В (&ВходящиеДаты)

Автору спасибо, очень помогло

Reply ↓
AvalonE2008 10.01.2017 at 12:10

Решение действительно простое, но подойти с этой стороны не догадался.Спасибо

Reply ↓
alexvbard 16.02.2017 at 16:19

Мне одному кажется что не совсем верно считается добавление количество рабочих дней?

Если по запросу установить входящую дату 22.02.2017 и попросить добавить к дате 2 рабочих дня то запрос выдает 27.02.2017.

Ну а должен наверно 28.02.2017

Reply ↓
whoo 16.02.2017 at 16:34

(19) почему 28 то? 22 февраля 2017 (это среда) + два рабочих дня (четверг, пятница) = 22,23,24 февраля. 25 и 26 — выходные дни. Соответственно ближайший день 27 февраля выпадает. Откуда 28 должно быть?

Reply ↓
alexvbard 18.02.2017 at 14:07

23,24,25,26 февраля — это выходные дни… Соответственно ближайшие два рабочих дня это 27 и 28 число. Тогда даже не 28 а 1 марта….

(20)

Reply ↓
whoo 20.02.2017 at 10:02

да(21) Точно..

Reply ↓
INTECH1 20.02.2017 at 12:33

(21) в статье есть табличка как пример работы, в ней видно, что сама входящая дата (если это рабочий день) тоже входит в количество добавляемых рабочих дней.

Reply ↓
alexvbard 20.02.2017 at 20:27

(23)

Понятно. В общем нужно поиграться чтобы получить нужный результат.

Reply ↓
script 15.05.2017 at 12:35

В общем работает что-то нет так

08.02.2015 + 7 дней получаю 13.02.2015 хотя явно должно быть 16.02.2015 (это если учитывать начальную дату 08.02.2015)

но эта дата является выходным днем, поэтому учитывать ее нельзя, а в этом случае результатом должен быть 17.02.2015

но ни как не 13.02.2015.

Короче не работает.

Reply ↓

sml 09.06.2017 at 10:08

а так будет оптимальнее (работает в 10 раз быстрее)

ВЫБРАТЬ
ПК.Дата КАК Дата,
ПК.ВидДня КАК ВидДня
ПОМЕСТИТЬ Рабочие
ИЗ
РегистрСведений.ДанныеПроизводственногоКалендаря КАК ПК
ГДЕ
ПК.Дата МЕЖДУ ДОБАВИТЬКДАТЕ(&тДата, МЕСЯЦ, -2) И ДОБАВИТЬКДАТЕ(&тДата, ДЕНЬ, 15)
И ПК.ВидДня В (ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий), ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный))
;
ВЫБРАТЬ
Даты.Дата,
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.Дата)-1 КАК КоличествоРабочихДней,
МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.Дата) КАК ДатаКалендаря,
РегламентированныйПроизводственныйКалендарь1.Дата КАК ДатаКалендаряДляГруппировки
ИЗ
РегистрСведений.ДанныеПроизводственногоКалендаря КАК РегламентированныйПроизводственныйКалендарь
ВНУТРЕННЕЕ СОЕДИНЕНИЕ Рабочие КАК Даты
ПО (РегламентированныйПроизводственныйКалендарь.Дата Между Даты.Дата И ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, 20))
ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ДанныеПроизводственногоКалендаря КАК РегламентированныйПроизводственныйКалендарь1
ПО РегламентированныйПроизводственныйКалендарь.Дата <= РегламентированныйПроизводственныйКалендарь1.Дата
И ДОБАВИТЬКДАТЕ(Даты.Дата, ДЕНЬ, 20) > РегламентированныйПроизводственныйКалендарь1.Дата
ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.апкОбщиеНастройки КАК ЧасыОплатыЗаявки
ПО (ЧасыОплатыЗаявки.Настройка = ЗНАЧЕНИЕ(ПланВидовХарактеристик.апкОбщиеНастройки.ЧасовОтСозданияЗаявкиДСДоВыполненияЗаказаРассылка))
ГДЕ
РегламентированныйПроизводственныйКалендарь.ВидДня В (ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий), ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный))

СГРУППИРОВАТЬ ПО
РегламентированныйПроизводственныйКалендарь1.Дата,
Даты.Дата,
ЧасыОплатыЗаявки.Значение

ИМЕЮЩИЕ
МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.Дата) = РегламентированныйПроизводственныйКалендарь1.Дата
И КОЛИЧЕСТВО(РАЗЛИЧНЫЕ РегламентированныйПроизводственныйКалендарь.Дата)-1 = ВЫРАЗИТЬ(ВЫРАЗИТЬ(ЧасыОплатыЗаявки.Значение КАК ЧИСЛО(10, 0))/24 КАК ЧИСЛО(10, 0))

Показать

добавил условие на соединение РегламентированныйПроизводственныйКалендарь1

Reply ↓

smok1986 20.06.2018 at 13:02

Вот простое и рабочее решение:

ВЫБРАТЬ
&ДатаККоторойНужноДобавитьДни КАК Дата,
&КоличествоДней КАК КоличествоДней
ПОМЕСТИТЬ втДаты
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ДанныеКалендаря.Дата
ПОМЕСТИТЬ втДанныеКалендаря
ИЗ
РегистрСведений.ДанныеПроизводственногоКалендаря КАК ДанныеКалендаря
ГДЕ
ДанныеКалендаря.ПроизводственныйКалендарь.Код = «РФ»
И (ДанныеКалендаря.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Рабочий)
ИЛИ ДанныеКалендаря.ВидДня = ЗНАЧЕНИЕ(Перечисление.ВидыДнейПроизводственногоКалендаря.Предпраздничный))
И ДанныеКалендаря.Дата >= &ДатаДляКалендаря
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ДанныеКалендаря1.Дата,
КОЛИЧЕСТВО(РАЗЛИЧНЫЕ ДанныеКалендаря2.Дата) КАК Индекс
ПОМЕСТИТЬ втДанныеКалендаряСИндексами
ИЗ
втДанныеКалендаря КАК ДанныеКалендаря1
ВНУТРЕННЕЕ СОЕДИНЕНИЕ втДанныеКалендаря КАК ДанныеКалендаря2
ПО ДанныеКалендаря1.Дата >= ДанныеКалендаря2.Дата

СГРУППИРОВАТЬ ПО
ДанныеКалендаря1.Дата

ИНДЕКСИРОВАТЬ ПО
Индекс
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
ВТ.Дата,
ВТ.КоличествоДней,
ДанныеКалендаря.Индекс КАК Индекс
ПОМЕСТИТЬ втДатыСИндексами
ИЗ
втДаты КАК ВТ
ЛЕВОЕ СОЕДИНЕНИЕ втДанныеКалендаряСИндексами КАК ДанныеКалендаря
ПО ВТ.Дата = ДанныеКалендаря.Дата
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
Даты.Дата,
ДанныеКалендаря.Дата КАК ДатаПослеДобавленияДней
ИЗ
втДатыСИндексами КАК Даты
ЛЕВОЕ СОЕДИНЕНИЕ втДанныеКалендаряСИндексами КАК ДанныеКалендаря
ПО (ДанныеКалендаря.Индекс — Даты.Индекс = Даты.КоличествоДней)

Показать

Reply ↓

olbu 03.08.2018 at 15:53

(27)

&ДатаДляКалендаря

А в параметр «&ДатаДляКалендаря» — что, за дату нужно поместить?

Reply ↓
Prad2002 21.09.2018 at 18:34

(27) Не работает, если ДатаККоторойНужноДобавитьДни — выходной или праздничный лень

Reply ↓
smok1986 24.09.2018 at 07:01

(29) Верно. Допилить не сложно для выходных и праздников.

Reply ↓
digital_element 30.10.2018 at 14:48

Спасибо. Очень полезная статья!

Reply ↓
1Cynep4eJIoBek 26.09.2019 at 12:40

всё отлично работает пока не переносишь в СКД консоль, там валится с ошибкой

{ВнешняяОбработка.ирОбщий.МодульОбъекта(22178)}: Ошибка при вызове метода контекста (Инициализировать)

ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновкиДанных, ВнешниеНаборыДанных, ДанныеРасшифровки, Истина);

по причине:

Ошибка компоновки данных

по причине:

Ошибка инициализации

по причине:

Ошибка создания набора данных «НаборДанных1»

по причине:

Ошибка при исполнении запроса набора данных

по причине:

{(53, 72)}: Поле не входит в группу «РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря»

МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = <<?>>РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря И

Показать

поправил вот так МАКСИМУМ(РегламентированныйПроизводственныйКалендарь.ДатаКалендаря) = МАКСИМУМ(РегламентированныйПроизводственныйКалендарь1.ДатаКалендаря) И

т.к. ДатаКалендаря совпадает с ДатаКалендаряДляГруппировки в последующем СКД использую ДатаКалендаряДляГруппировки

а вообще автор красавчик сэкономил мне кучу времени и нервов

Reply ↓

Добавить к дате рабочие дни в запросе

Related Posts

32 Comments

Leave a Comment Отменить ответ