Интеграция решений на 1С и сервиса обмена данными RabbitMQ через Web REST API

WARNING

Описание:
В этой статье описан способ реализации интеграции с брокером сообщений RabbitMQ через веб интерфейс REST API.
На данный момент вендор не рекомендует использование веб-интерфейса в качестве основного протокола обмена, следующее сообщение можно встретить в мануалах по RabbitMQ:

Please note that the get path in the HTTP API is intended for diagnostics etc — it does not implement reliable delivery and so should be treated as a sysadmin’s tool rather than a general API for messaging.

Исходя из того, что вариантов для подключения и обмена данными с RMQ не так уж и много, а если вдруг у нас платформа на Linux — то вообще нет, считаю, что это выход. Также это единственный способ отправки сообщений предоставляющий возможность использовать маршрутизацию по "заголовкам".

Немного теории:

Сам по себе сервер RabbitMQ обычно не устанавливают. Почти всегда в дополнение ставят еще и модуль веб администрирования всего сервиса. Именно модуль администрирования имеет встроенное REST API, выступающее прослойкой между сервером AMQP и миром WEB.

Подробное описание REST API https://bulldog.rmq.cloudamqp.com/api/index.html

Итак, начнем:

Для тестирования API сделал обработку с одной командой — выполнить тестирование:

Здесь указаны настройки подключения к серверу:

Краткое описание работы:

1. Создание подключения к веб серверу администрирования RabbitMQ;
2. Создание базовой структуры параметров сообщения для отправки, исходя из REST API;
3. Сериализация параметров в JSON;
4. Отправка JSON в POST запросе на север RabbitMQ;
5. Проверка удачной отправки сообщения;
6. Подготовка параметров запроса для получения сообщения;
7. Сериализация параметров запроса в JSON;
8. Отправка JSON в POST запросе на сервер RabbitMQ;
9. Обработка ответа сервера.

Код команды:

&НаСервере
Процедура ВыполнитьТестНаСервере()

// Cодать новое соединение с веб-сервером RabbitMQ
ИнтернетПрокси = Новый ИнтернетПрокси();
ЗащищенноеСоединениеOpenSSL = Новый ЗащищенноеСоединениеOpenSSL();
HTTPСоеинение = Новый HTTPСоединение(АдресСервера, Порт, ИмяПользователя, Пароль, ИнтернетПрокси, 360, ЗащищенноеСоединениеOpenSSL, Ложь);

////
//  Подготовим и отправим сообщение в RabbitMQ
////****************************************************//

// новое соответствие заголовков
// если обмен поддерживает адресацию по заголовкам то заполняем
// заполнять имя маршрута в таком случае не нужно
ЗаголовкиСообщения = Новый Соответствие;
Для Каждого СтрокаЗаголовок Из Заголовки Цикл
ЗаголовкиСообщения.Вставить(СтрокаЗаголовок.Ключ, СтрокаЗаголовок.Значение);
КонецЦикла;

// новые параметры сообщения
ПараметрыСообщения = Новый Структура("app_id, correlation_id, delivery_mode, content_type, headers");
ПараметрыСообщения.headers = ЗаголовкиСообщения;
ПараметрыСообщения.app_id = Метаданные.Синоним;  // кто отправил
ПараметрыСообщения.correlation_id = Строка(Новый УникальныйИдентификатор()); // уникальный идентификатор сообщения
ПараметрыСообщения.delivery_mode = 2; // где будет храниться сообщение 1 - оператива, 2 - диск
ПараметрыСообщения.content_type = "text/plain"; // тип содержимого

// структура отправки
СтурктураСообщения = Новый Структура("properties, routing_key, payload, payload_encoding");
СтурктураСообщения.properties = ПараметрыСообщения;
СтурктураСообщения.payload_encoding = "string"; // тип содержимого, по умолчанию строка
СтурктураСообщения.payload = Сообщение; // содержимое
СтурктураСообщения.routing_key = ИмяМаршрута;  // имя маршрута, пустое если заполнены заголовки сообщения

// сериализовать все параметры запроса в json
ЗаписьJSON = Новый ЗаписьJSON;
ЗаписьJSON.УстановитьСтроку();
ЗаписатьJSON(ЗаписьJSON, СтурктураСообщения);
СтрокаЗапроса = ЗаписьJSON.Закрыть();

// новый запрос REST API для RABBITMQ
ЗаголовкиЗапроса = Новый Соответствие;
ЗаголовкиЗапроса.Вставить("Content-Type", "application/json"); // тип содержимого - json
HTTPЗапрос = Новый HTTPЗапрос(СтрШаблон("/api/exchanges/%1/%2/publish", Хост, ИмяОбмена), ЗаголовкиЗапроса);
HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаЗапроса);

// отправить сообщение в RabbitMQ POST запросом
HTTPОтвет = HTTPСоеинение.ОтправитьДляОбработки(HTTPЗапрос);

// если ошибка сообщим результат
Если HTTPОтвет.КодСостояния <> 200 Тогда
Сообщить(СтрШаблон("Код ответа: %1", HTTPОтвет.КодСостояния));
Сообщить(HTTPОтвет.ПолучитьТелоКакСтроку());
Возврат;
КонецЕсли;

////
//  Получим сообщение из RabbitMQ
////****************************************************//

// новая структура запроса сообщений из rabbitmq
СтурктураЗапроса = Новый Структура("count, ackmode, encoding, truncate");
СтурктураЗапроса.truncate = 10000000; // выгружать сообщения не превышающие этот размер в байтах
СтурктураЗапроса.encoding = "auto"; // содержимое какого типа мы хотим получить
СтурктураЗапроса.ackmode = "ack_requeue_false"; // удалить полученные сообщения
СтурктураЗапроса.count = 1;  // количество запрошеных сообщений

// сериализовать все параметры запроса в json
ЗаписьJSON = Новый ЗаписьJSON;
ЗаписьJSON.УстановитьСтроку();
ЗаписатьJSON(ЗаписьJSON, СтурктураЗапроса);
СтрокаЗапроса = ЗаписьJSON.Закрыть();

// новый запрос REST API для RABBITMQ
ЗаголовкиЗапроса = Новый Соответствие;
ЗаголовкиЗапроса.Вставить("Content-Type", "application/json"); // тип содержимого - json
HTTPЗапрос = Новый HTTPЗапрос(СтрШаблон("/api/queues/%1/%2/get", Хост, ИмяОчереди), ЗаголовкиЗапроса);
HTTPЗапрос.УстановитьТелоИзСтроки(СтрокаЗапроса);

// Получить сообщения из RabbitMQ ответом на POST запрос
HTTPОтвет = HTTPСоеинение.ОтправитьДляОбработки(HTTPЗапрос);

// если ошибка сообщим результат
Если HTTPОтвет.КодСостояния <> 200 Тогда
Сообщить(СтрШаблон("Код ответа: %1", HTTPОтвет.КодСостояния));
Сообщить(HTTPОтвет.ПолучитьТелоКакСтроку());
Возврат;
КонецЕсли;

// Прочитаем ответ сервера
ЧтениеJSON = Новый ЧтениеJSON;
ЧтениеJSON.УстановитьСтроку(HTTPОтвет.ПолучитьТелоКакСтроку());
СтурктураHTTPОтвета = ПрочитатьJSON(ЧтениеJSON);
ЧтениеJSON.Закрыть();

// выделим содержимое сообщения
Ответ = СтурктураHTTPОтвета[0].payload;

КонецПроцедуры

Производительность решения:

Вывод: это самый простой способ обмениваться сообщениями с RabbitMQ, используя исключительно встроенные возможности 1С Предприятие, которые доступны во всех версиях платформы.