Несколько документов на основании одного

1) В обработке заполнения создаваемого документа проверяем некоторое условие, в примере: "В табличной части документа-основания несколько различных складов?".

2) Если "Да", то делаем две копии объекта-основания с пустыми табличными частями.

3) Заполняем табличные части копий по некоторому алгоритму, в этом примере – по складу. В первую копию отбираем строки с одним складом, в табличную часть второй копии помещаем оставшиеся строки с другими складами.

4) Создаем еще один документ РасходТовара и вызываем для него обработку заполнения, куда в качестве данных заполнения передаем вторую копию объекта-основания с оставшимися складами.

5) Созданный документ помещаем во временное хранилище, адрес записываем в реквизит АдресЕщеОдногоДокумента.

6) Заменяем ДанныеЗаполнения текущего документа на заполненную нами первую копию документа-основания с одним складом в строках табличной части.

7) В процедуре ПриОткрытии модуля формы текущего создаваемого документа проверяем реквизит АдресЕщеОдногоДокумента. Если он заполнен и это адрес, то получаем пустую форму следующего создаваемого документа, заполняем его данными полученного из хранилища объекта и открываем.

   Если в табличной части объекта-основания для следующего документа (т.е. в ДанныеЗаполнения) несколько различных складов, то алгоритм повторяется.

Процедура ОбработкаЗаполнения(ДанныеЗаполнения, СтандартнаяОбработка)

Если ТипЗнч(ДанныеЗаполнения) = Тип("ДокументСсылка.Заказ")
// Добавляем еще одно условие, так при создании следующего документа
// будем передавать не ссылку (которой у нас не будет), а объект.
ИЛИ ТипЗнч(ДанныеЗаполнения) = Тип("ДокументОбъект.Заказ") Тогда

СоздатьЕщеОдинДокументПриНеобходимости(ДанныеЗаполнения);

// Ниже "штатный" код обработки заполнения.
// В данном  примере код просто создан конструктором
Валюта = ДанныеЗаполнения.Валюта;
ВидЦен = ДанныеЗаполнения.ВидЦен;
Организация = ДанныеЗаполнения.Организация;
Покупатель = ДанныеЗаполнения.Покупатель;
Для Каждого ТекСтрокаТовары Из ДанныеЗаполнения.Товары Цикл
НоваяСтрока = Товары.Добавить();
НоваяСтрока.Количество = ТекСтрокаТовары.Количество;
НоваяСтрока.Склад = ТекСтрокаТовары.Склад;
НоваяСтрока.Сумма = ТекСтрокаТовары.Сумма;
НоваяСтрока.Товар = ТекСтрокаТовары.Товар;
НоваяСтрока.Цена = ТекСтрокаТовары.Цена;
КонецЦикла;
КонецЕсли;

КонецПроцедуры

// Создает еще один документ РасходТовара, если в строках ТЧ есть несколько различных складов.
// Здесь реализуем некоторый алгоритм отбора строк табличной части в создаваемые документы.
// В представленном примере в текущий документ отбираем строки с первым по порядку складом,
// остальные помещаем в следующий документ, для которого вызываем обработку заполнения.
// И так пока в данных заполнения не останутся строки с одним складом.
//
Процедура СоздатьЕщеОдинДокументПриНеобходимости(ДанныеЗаполнения)

СкладыЗаказа = СвернутьМассив(ДанныеЗаполнения.Товары.ВыгрузитьКолонку("Склад"));

// Проверяем, есть ли в ТЧ основания разные склады
Если СкладыЗаказа.Количество() > 1 Тогда

Если ТипЗнч(ДанныеЗаполнения) = Тип("ДокументСсылка.Заказ") Тогда
ЗаказОбъект = ДанныеЗаполнения.ПолучитьОбъект();
ИначеЕсли ТипЗнч(ДанныеЗаполнения) = Тип("ДокументОбъект.Заказ") Тогда
ЗаказОбъект = ДанныеЗаполнения;
КонецЕсли;

// Делаем две копии объекта-основания
ЗаказКопия = ЗаказОбъект.Скопировать();
ЗаказКопияОставшиеся = ЗаказОбъект.Скопировать();

ТоварыЗаказа = ЗаказОбъект.Товары.Выгрузить();

ЗаказКопия.Товары.Очистить();
ЗаказКопияОставшиеся.Товары.Очистить();

// Заполняем табличные части копий по некоторому алгоритму,
// в этом примере - по складу.
Для каждого Стр Из ТоварыЗаказа Цикл
Если Стр.Склад = СкладыЗаказа[0] Тогда
НоваяСтрока = ЗаказКопия.Товары.Добавить();
ЗаполнитьЗначенияСвойств(НоваяСтрока, Стр);
Иначе
НоваяСтрока = ЗаказКопияОставшиеся.Товары.Добавить();
ЗаполнитьЗначенияСвойств(НоваяСтрока, Стр);
КонецЕсли;
КонецЦикла;

// Создаем объект еще одного документа РасходТовара
ЕщеОдинРасходТовара = Документы.РасходТовара.СоздатьДокумент();

// Вызываем обработку заполнения следующего документа.
ЕщеОдинРасходТовара.Заполнить(ЗаказКопияОставшиеся);

ЕщеОдинРасходТовара.Дата = НачалоДня(ТекущаяДатаСеанса());

//Во временное хранилище могут быть помещены только сериализуемые объекты.
// Для ДокументОбъект сериализация не поддерживается,
// однако поддерживается XDTO-сериализация и XML-сериализация.
// Поэтому сериализуем объект в XML
ЕщеОдинРасходТовараXML = Сериализовать(ЕщеОдинРасходТовара);
// и помещаем его во временное хранилище
// (АдресЕщеОдногоДокумента - реквизит этого документа)
АдресЕщеОдногоДокумента = ПоместитьВоВременноеХранилище(ЕщеОдинРасходТовараXML, Новый УникальныйИдентификатор);

// Заменяем ДанныеЗаполнения текущего документа
ДанныеЗаполнения = ЗаказКопия;

КонецЕсли;

КонецПроцедуры

Процедура ПриЗаписи(Отказ)

// Штатный код обработчика ПриЗаписи
// ...

// Очищаем временное хранилище и реквизит документа,
// которые нужны только при открытии формы нового документа,
// создаваемого на основании
Если ЗначениеЗаполнено(АдресЕщеОдногоДокумента)
И ЭтоАдресВременногоХранилища(АдресЕщеОдногоДокумента) Тогда

УдалитьИзВременногоХранилища(АдресЕщеОдногоДокумента);
ЭтотОбъект.АдресЕщеОдногоДокумента = "";

КонецЕсли;

КонецПроцедуры

#Область СлужебныеПроцедурыИФункции

Функция СвернутьМассив(ИсходныйМассив)

СвернутыйМассив = Новый Массив;
Соответствие = Новый Соответствие;

Для каждого ЭлементМассива Из ИсходныйМассив Цикл
Соответствие.Вставить(ЭлементМассива);
КонецЦикла;

Для каждого КлючИЗначение Из Соответствие Цикл
СвернутыйМассив.Добавить(КлючИЗначение.Ключ);
КонецЦикла;

Возврат СвернутыйМассив;

КонецФункции

Функция Сериализовать(ОбъектСериализации)

ОбъектXDTO = СериализаторXDTO.ЗаписатьXDTO(ОбъектСериализации);
МойXML = Новый ЗаписьXML;
МойXML.УстановитьСтроку();
ФабрикаXDTO.ЗаписатьXML(МойXML, ОбъектXDTO);

Возврат МойXML.Закрыть();

КонецФункции

#КонецОбласти

&НаКлиенте
Процедура ПриОткрытии(Отказ)

// Штатный код
// ...

ОткрытьФормуЕщеОдногоДокументаПриНеобходимости();

КонецПроцедуры

&НаКлиенте
Процедура ОткрытьФормуЕщеОдногоДокументаПриНеобходимости()

Если ЗначениеЗаполнено(Объект.АдресЕщеОдногоДокумента)
И ЭтоАдресВременногоХранилища(Объект.АдресЕщеОдногоДокумента) Тогда

// Получаем пустую форму создаваемого на основании документа
ФормаЕщеОдногоДокумента = ПолучитьФорму("Документ.РасходТовара.ФормаОбъекта");

// Получаем ДанныеФормы - тип ДанныеФормыСтруктура
ДанныеФормы = ФормаЕщеОдногоДокумента.Объект;

// и отправляем на сервер для заполнения данными из временного хранилища.
ЗаполнитьДанныеФормыЕщеОдногоДокумента(ДанныеФормы, Объект.АдресЕщеОдногоДокумента);

// Копируем заполненные на сервере ДанныеФормы в объект формы
// и, если все хорошо, открываем форму
Если КопироватьДанныеФормы(ДанныеФормы, ФормаЕщеОдногоДокумента.Объект) Тогда
ФормаЕщеОдногоДокумента.Открыть();
КонецЕсли;

КонецЕсли;

КонецПроцедуры

// Получаем из временного хранилища XML-строку объекта следующего документа,
// помещенную туда в обработке заполнения текущего докуметнта.
// Заполняем переданные ДанныеФормы следующего документа
// Параметры:
//  ДанныеФормы  - ДанныеФормыСтруктура - заполняемые данные формы
//  Адрес     - Строка - адрес во временном хранилище
//
&НаСервереБезКонтекста
Процедура ЗаполнитьДанныеФормыЕщеОдногоДокумента(ДанныеФормы, Адрес)

ЕщеОдинДокументXML = ПолучитьИзВременногоХранилища(Адрес);

ЕщеОдинДокумент = Десериализовать(ЕщеОдинДокументXML);

ЗначениеВДанныеФормы(ЕщеОдинДокумент, ДанныеФормы);

КонецПроцедуры

&НаСервереБезКонтекста
Функция Десериализовать(XMLСтруктураСериализованногоОбъекта)

ЧтениеXMLДанных = Новый ЧтениеXML;
ЧтениеXMLДанных.УстановитьСтроку(XMLСтруктураСериализованногоОбъекта);
ОбъектЗначение = СериализаторXDTO.ПрочитатьXML(ЧтениеXMLДанных);
ЧтениеXMLДанных.Закрыть();

Возврат ОбъектЗначение;

КонецФункции