XDTO для чайников

30.05.2019 37 Comments

Обмен через XML, Разработка, Системная интеграция

Пример использования XDTO пакетов для выгрузки документа с табличной частью.

По пакетам XDTO уже существует достаточно много статей, прочитав которые я потратил еще достаточно много времени чтобы разобраться как написать обмен, используя эту технологию. Сейчас я уверенно могу сказать, что все достаточно просто и покажу это на примере.

В примере мы выгрузим из демо базы БП 3 документ «Реализация (акты, накладные)» в самописную конфигурацию.

Конфигурация, в которую будем загружать данные будет состоять из следующих объектов:
Справочники: Номенклатура, Контрагенты. Перечисления: СтавкиНДС. Документы: РеализацияТоваровУслуг.

Оказывается, в демо базе БП 3 есть расширение «ФормированиеТестовыхДанных», значит им и воспользуемся, не будем создавать собственное.

Добавим пакет XDTO. Имя: ВыгрузкаРеализаций. URI пространство имен: infostart.

В пакете добавим тип объекта «ДокументРеализация».

В объект добавим свойства: Ссылка, Дата, Номер, Контрагент.

Пакет 1

Создадим обработку «Выгрузка реализаций»

Выгрузка реализаций

Код команды выгрузки:

&НаСервере
Функция КомандаВыгрузитьНаСервере()
// Вставить содержимое обработчика.
ЗаписьXML = Новый ЗаписьXML();
ЗаписьXML.УстановитьСтроку();

РеализацияXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "ДокументРеализация"));
РеализацияXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Ссылка);
РеализацияXDTO.Дата = выбРеализация.Дата;
РеализацияXDTO.Номер = выбРеализация.Номер;
РеализацияXDTO.Контрагент = выбРеализация.Контрагент.Наименование;

ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, РеализацияXDTO);

Возврат ЗаписьXML.Закрыть();

КонецФункции

&НаКлиенте
Процедура КомандаВыгрузить(Команда)
ОбъектXDTO = КомандаВыгрузитьНаСервере();

ЗаписьXML = Новый ЗаписьXML();
ЗаписьXML.ОткрытьФайл(выбФайл);
ЗаписьXML.ЗаписатьОбъявлениеXML();
ЗаписьXML.ЗаписатьБезОбработки(ОбъектXDTO);

ЗаписьXML.Закрыть();

КонецПроцедуры

Результат 

<?xml version="1.0" encoding="UTF-8"?>
<ДокументРеализация xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns="infostart">
<Ссылка xsi:type="xs:string">63d07913-1e98-11e6-a31d-14dae9b19a48</Ссылка>
<Дата xsi:type="xs:dateTime">2024-12-29T12:00:00</Дата>
<Номер xsi:type="xs:string">0000-000603</Номер>
<Контрагент xsi:type="xs:string">Внуковский комбинат бортового питания</Контрагент>
</ДокументРеализация>

Изменим форму представления для свойств объекта XDTO

Результат

<?xml version="1.0" encoding="UTF-8"?>
<ДокументРеализация Контрагент="Внуковский комбинат бортового питания" Номер="0000-000603" Дата="2024-12-29T12:00:00" Ссылка="63d07913-1e98-11e6-a31d-14dae9b19a48" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns="infostart"/>

Переходим к загрузке данных. Создадим обработку загрузки.

Код 

&НаСервереБезКонтекста
Функция ПолучитьСсылкуПоУИ(УникальныйИдентификатор, МенеджерОбъекта)
УИДСсылки = СериализаторXDTO.XMLЗначение(Тип("УникальныйИдентификатор"), УникальныйИдентификатор);
Возврат МенеджерОбъекта.ПолучитьСсылку(УИДСсылки);
КонецФункции

&НаСервереБезКонтекста
Процедура ЗагрузитьРеализации(ТекстФайла)
ЧтениеXML = Новый ЧтениеXML();
ЧтениеXML.УстановитьСтроку(ТекстФайла);

РеализацияXDTO = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML, ФабрикаXDTO.Тип("infostart", "ДокументРеализация"));


сРеализацияТоваров = ПолучитьСсылкуПоУИ(РеализацияXDTO.Ссылка, Документы.РеализацияТоваровУслуг);

оРеализацияТоваров = сРеализацияТоваров.ПолучитьОбъект();
Если оРеализацияТоваров = Неопределено Тогда
оРеализацияТоваров = Документы.РеализацияТоваровУслуг.СоздатьДокумент();
оРеализацияТоваров.УстановитьСсылкуНового(сРеализацияТоваров);
КонецЕсли;

оРеализацияТоваров.Дата = РеализацияXDTO.Дата;
оРеализацияТоваров.Номер = РеализацияXDTO.Номер;

оРеализацияТоваров.Записать(РежимЗаписиДокумента.Запись);

КонецПроцедуры

&НаКлиенте
Процедура КомандаЗагрузить(Команда)
// Вставить содержимое обработчика.
ЧтениеТекста = Новый ЧтениеТекста(выбФайл);
ТекстФайла = ЧтениеТекста.Прочитать();
ЗагрузитьРеализации(ТекстФайла);
КонецПроцедуры

Проверяем загрузку. Выполнение прерывается ошибкой. Через отладку можно увидеть, что значения свойств объекта РеализацияXDTO имеют строковый тип, конкретно дата в таком виде преобразуется к пустому значению.

В пакете XDTO укажем свойству "Дата" тип

Проверим еще раз загрузку, все должно было пройти успешно.

Отдельно обращу внимание на эту строчку кода

РеализацияXDTO = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML, ФабрикаXDTO.Тип("infostart", "ДокументРеализация"));

При чтение объекта XDTO я принудительно указал его тип, хотя параметр не является обязательным. И сделал я это не просто так, для корневого элемента тип объекта не выгружается, это хорошо видно в xml файле, где все свойства выгружали в форме элементов. Для объекта ДокументРеализация не указан атрибут xsi:type.

<?xml version="1.0" encoding="UTF-8"?>
<ДокументРеализация xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns="infostart">
<Ссылка xsi:type="xs:string">63d07913-1e98-11e6-a31d-14dae9b19a48</Ссылка>
<Дата xsi:type="xs:dateTime">2024-12-29T12:00:00</Дата>
<Номер xsi:type="xs:string">0000-000603</Номер>
<Контрагент xsi:type="xs:string">Внуковский комбинат бортового питания</Контрагент>
</ДокументРеализация>

В свойство "контрагент" мы помещали наименование контрагента. Добавим новый тип объекта в пакет XDTO "СправочникКонтрагенты" со свойствами: Ссылка, Код, Наименование, НаименованиеПолное. Для свойства "Контрагент" в типе объекта "ДокументРеализация" укажем форму хранения в виде элемента. Внесем изменения в код выгрузки.

&НаСервере
Функция КомандаВыгрузитьНаСервере()
// Вставить содержимое обработчика.
ЗаписьXML = Новый ЗаписьXML();
ЗаписьXML.УстановитьСтроку();

КонтрагентXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "СправочникКонтрагенты"));
КонтрагентXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Контрагент.Ссылка);
КонтрагентXDTO.Код = выбРеализация.Контрагент.Код;
КонтрагентXDTO.Наименование = выбРеализация.Контрагент.Наименование;
КонтрагентXDTO.НаименованиеПолное = выбРеализация.Контрагент.НаименованиеПолное;

РеализацияXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "ДокументРеализация"));
РеализацияXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Ссылка);
РеализацияXDTO.Дата = выбРеализация.Дата;
РеализацияXDTO.Номер = выбРеализация.Номер;
РеализацияXDTO.Контрагент = КонтрагентXDTO;

ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, РеализацияXDTO);

Возврат ЗаписьXML.Закрыть();

КонецФункции

Думаю, здесь все понятно.

Дольше всего я не мог разобраться, как выгружать табличные части.

Создадим тип объекта "ТабличнаяЧасть" со свойством "Строки".

Максимальное количество -1, означает неограниченное количество элементов.

Создадим объект.

ТоварыXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "ТабличнаяЧасть"));

И посмотрим его свойства в отладчике.

Дальше, думаю, уже все понятно. Изменения в коде обработки выгрузки.

&НаСервере
Функция КомандаВыгрузитьНаСервере()
// Вставить содержимое обработчика.
ЗаписьXML = Новый ЗаписьXML();
ЗаписьXML.УстановитьСтроку();

КонтрагентXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "СправочникКонтрагенты"));
КонтрагентXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Контрагент.Ссылка);
КонтрагентXDTO.Код = выбРеализация.Контрагент.Код;
КонтрагентXDTO.Наименование = выбРеализация.Контрагент.Наименование;
КонтрагентXDTO.НаименованиеПолное = выбРеализация.Контрагент.НаименованиеПолное;

РеализацияXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "ДокументРеализация"));
РеализацияXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Ссылка);
РеализацияXDTO.Дата = выбРеализация.Дата;
РеализацияXDTO.Номер = выбРеализация.Номер;
РеализацияXDTO.Контрагент = КонтрагентXDTO;

ТоварыXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "ТабличнаяЧасть"));

Для Каждого сТовары Из выбРеализация.Товары Цикл
НоменклатураXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "СправочникНоменклатура"));
НоменклатураXDTO.Ссылка = СериализаторXDTO.XMLСтрока(сТовары.Номенклатура);
НоменклатураXDTO.Код = сТовары.Номенклатура.Код;
НоменклатураXDTO.Наименование = сТовары.Номенклатура.Наименование;
НоменклатураXDTO.НаименованиеПолное = сТовары.Номенклатура.НаименованиеПолное;

сТоварыXDTO = ФабрикаXDTO.Создать(ФабрикаXDTO.Тип("infostart", "ДокументРеализацияТовары"));
сТоварыXDTO.Номенклатура = НоменклатураXDTO;
сТоварыXDTO.Количество = сТовары.Количество;
сТоварыXDTO.Цена = сТовары.Цена;
сТоварыXDTO.Сумма = сТовары.Сумма;
сТоварыXDTO.СтавкаНДС = XMLСтрока(сТовары.СтавкаНДС);
сТоварыXDTO.СуммаНДС = сТовары.СуммаНДС;

ТоварыXDTO.Строки.Добавить(сТоварыXDTO);
КонецЦикла;

РеализацияXDTO.тчТовары = ТоварыXDTO;

ФабрикаXDTO.ЗаписатьXML(ЗаписьXML, РеализацияXDTO);

Возврат ЗаписьXML.Закрыть();

КонецФункции

Код загрузки

&НаСервереБезКонтекста
Процедура ЗагрузитьРеализации(ТекстФайла)
ЧтениеXML = Новый ЧтениеXML();
ЧтениеXML.УстановитьСтроку(ТекстФайла);

РеализацияXDTO = ФабрикаXDTO.ПрочитатьXML(ЧтениеXML, ФабрикаXDTO.Тип("infostart", "ДокументРеализация"));


сРеализацияТоваров = ПолучитьСсылкуПоУИ(РеализацияXDTO.Ссылка, Документы.РеализацияТоваровУслуг);

оРеализацияТоваров = сРеализацияТоваров.ПолучитьОбъект();
Если оРеализацияТоваров = Неопределено Тогда
оРеализацияТоваров = Документы.РеализацияТоваровУслуг.СоздатьДокумент();
оРеализацияТоваров.УстановитьСсылкуНового(сРеализацияТоваров);
КонецЕсли;

оРеализацияТоваров.Дата = РеализацияXDTO.Дата;
оРеализацияТоваров.Номер = РеализацияXDTO.Номер;

КонтрагентXDTO = РеализацияXDTO.Контрагент;
сКонтрагент = ПолучитьСсылкуПоУИ(КонтрагентXDTO.Ссылка, Справочники.Контрагенты);
оКонтрагент = сКонтрагент.ПолучитьОбъект();
Если оКонтрагент = Неопределено Тогда
оКонтрагент = Справочники.Контрагенты.СоздатьЭлемент();
оКонтрагент.УстановитьСсылкуНового(сКонтрагент);
КонецЕсли;

оКонтрагент.Код = КонтрагентXDTO.Код;
оКонтрагент.Наименование = КонтрагентXDTO.Наименование;
оКонтрагент.НаименованиеПолное = КонтрагентXDTO.НаименованиеПолное;
оКонтрагент.Записать();

оРеализацияТоваров.Контрагент = оКонтрагент.Ссылка;
оРеализацияТоваров.Товары.Очистить();
Для Каждого сТоварыXDTO Из РеализацияXDTO.тчТовары.Строки Цикл
сТовары = оРеализацияТоваров.Товары.Добавить();
ЗаполнитьЗначенияСвойств(сТовары, сТоварыXDTO,,"СтавкаНДС,Номенклатура");
сТовары.СтавкаНДС = Перечисления.СтавкиНДС[сТоварыXDTO.СтавкаНДС];

НоменклатураXDTO = сТоварыXDTO.Номенклатура;
сНоменклатура = ПолучитьСсылкуПоУИ(НоменклатураXDTO.Ссылка, Справочники.Номенклатура);
оНоменклатура = сНоменклатура.ПолучитьОбъект();
Если оНоменклатура = Неопределено Тогда
оНоменклатура = Справочники.Номенклатура.СоздатьЭлемент();
оНоменклатура.УстановитьСсылкуНового(сНоменклатура);
КонецЕсли;

оНоменклатура.Код = НоменклатураXDTO.Код;
оНоменклатура.Наименование = НоменклатураXDTO.Наименование;
оНоменклатура.НаименованиеПолное = НоменклатураXDTO.НаименованиеПолное;
оНоменклатура.Записать();

сТовары.Номенклатура = оНоменклатура.Ссылка;
КонецЦикла;


оРеализацияТоваров.Записать(РежимЗаписиДокумента.Запись);

КонецПроцедуры

Для создания примера использовались программные файлы 1С:Предприятие 8.3 (8.3.14.1694).

Related Posts

37 Comments

  1. androidT1C

    О! Спасибо.

    Одна вещь перечеркивает всю нужность XDTO в 1С: при изменении структуры данных для обмена (например, добавить всего одно новое поле) придется изменять конфигурацию. Это никуда не годится.

    Reply ↓
  2. acanta

    (1) может есть возможность сделать такой макет в обработке?

    Reply ↓
  3. fenixnow

    (1) Считаем, что структура выгрузки определяется пакете ХДТО и все прекрасно 🙂

    Reply ↓
  4. HAMMER_59

    (1) Как-то очень не внимательно даже начало статьи прочитали — в примере для демо базы я храню пакет в расширении.

    Также пакет XDTO можно прекрасно хранить в файле.

    Кроме того в статье далеко не полный обзор возможностей применения XDTO, всего лишь простенький пример с которого можно начать знакомство с технологией.

    Пора уже завести правило на Инфостарт.

    Не согласен — критикуй, критикуешь — предлагай, предлагаешь — делай, делаешь — отвечай!

    Reply ↓
  5. fr13

    Ок, если это пример для чайников, то зачем сразу учить неправильно? Выгружаете ссылочные объекты, но не используете гуиды или хотя бы инн у того же контрагента, зато есть СериализаторXDTO для номенклатуры.

    Я бы на Вашем месте повнимательнее изучил метариалы по этой теме.

    Reply ↓
  6. HAMMER_59

    (5)

    И что по вашему эти строчки выгружают?

    КонтрагентXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Контрагент.Ссылка);

    РеализацияXDTO.Ссылка = СериализаторXDTO.XMLСтрока(выбРеализация.Ссылка);

    НоменклатураXDTO.Ссылка = СериализаторXDTO.XMLСтрока(сТовары.Номенклатура);

    А что делает эта строчка кода?

    сНоменклатура = ПолучитьСсылкуПоУИ(НоменклатураXDTO.Ссылка, Справочники.Номенклатура);

    Код функции ПолучитьСсылкуПоУИ, я действительно, забыл выложить, но как по Вашему что она делает?

    Не использует ли случаем Справочники.Номенклатура.ПолучитьСсылку()? И что же эта функция интересно делает, не по уникальному идентификатору, случаем, получает ссылку на объект?

    Reply ↓
  7. fr13

    (6) хорошо, допустим гуиды все таки есть, но они появляются уже в коде ближе к окончанию публикации без всяких объяснений почему вдруг наименование стало не пригодным и как нужно связать реализацию и контрагента в пакете (форма хранения — элемент, которую указываете Вы, не счиатется).

    Далее, у Вас везде используется разименование (обращение к реквизитам через точку). Плюс ко всему название переменных (я про префиксы) — Вы для себя что ли пишите или для людей?

    Reply ↓
  8. zqzq
    В примере мы выгрузим из демо базы БП 3 документ «Реализация (акты, накладные)» в самописную конфигурацию.

    Такое впечатление, что данный пример сильно проще было бы сделать с помощью Конвертации данных 2. И поддержка + доработка/расширение проще, чем в этой низкоуровневой XDTO. Но может пример неудачный, и в обмене с не-1С системами XDTO засияет?

    Reply ↓
  9. HAMMER_59

    (7) Я так понимаю в вашей голове летает мысль, что синхронизацию баз лучше делать, используя планы обмена, в таком случае не нужно каждый раз выгружать данные по подчиненным объектам.

    Цель какая статьи? Показать технологию XDTO. Вам не понятно зачем остальной код написан максимально упрощенно?

    Может вам стоит задуматься прежде всего над собой, а не других критиковать?

    Reply ↓
  10. HAMMER_59

    (8) Т.е. я тебе должен бы ещё описать как и где использовать технологию XDTO?

    Тебе кажется что использование XDTO для синхронизации баз — не комильфо?

    Конвертация данных лучше?

    Прекрасно, напиши статью, очень будет интересно посмотреть на изящность реализации синхронизации баз, используя КД.

    Reply ↓
  11. fr13

    (9) Вы где про планы обмена в моих сообщениях прочитали?

    Если делаете что-то, то делайте это хорошо. Вот и все.

    На этом прекращаю общение с Вами. Успехов.

    Reply ↓
  12. androidT1C

    (4)

    Также пакет XDTO можно прекрасно хранить в файле.

    Можно пример? Меня от XDTO, в самом деле, удерживает необходимость внесения изменений в конфигурацию.

    Reply ↓
  13. GreenDragon

    (11) Бугурт вообще не по теме. Уважаемый, вы действительно глупо выглядите

    Reply ↓
  15. HAMMER_59

    (7)

    Плюс ко всему название переменных (я про префиксы) — Вы для себя что ли пишите или для людей?

    Странно такое слышать от человека, который выкладывает статьи с кодом на английском языке. У вас то код, конечно, кошерный, суффиксы, префиксы, а главное не для себя, а для людей, всем же крайне понятно на английском. Крайне странно, статьи у вас такие, что не каждый осилит прочитать и осознать, а тут код проще некуда, но разобраться не смогли.

    Ну, и конечно, в ваших статьях все данные из базы извлекаются оптимальным запросом, ах да, у вас просто абстрактный код, т.к. запросы слишком громоздко выглядят, да и нет смысла их включать в статью.

    Reply ↓
  16. prosto_tak

    (13)

    Экспортируете пакет в .xsd, текст из .xsd копируете в макет. Далее все просто:

    ЧтениеХМЛ = Новый ЧтениеXML();
ЧтениеХМЛ.УстановитьСтроку(ПолучитьМакет(«МакетС_XSD»).ПолучитьТекст());
ПостроительDOM = Новый ПостроительDOM();
Документ = ПостроительDOM.Прочитать(ЧтениеХМЛ);
ПостроительСхем = Новый ПостроительСхемXML();
Схема = ПостроительСхем.СоздатьСхемуXML(Документ.ЭлементДокумента);
НаборСхем = Новый НаборСхемXML();
НаборСхем.Добавить(Схема);

НоваяФабрикаХДТО = Новый ФабрикаXDTO(НаборСхем);

    Показать

    Reply ↓
  17. bulpi

    Статья вроде полезная, но мелкие огрехи не дают поставить плюс.

    1)Автор, ну что это за «выбРеализация.Ссылка» ? А нельзя без «.Ссылка» ? Раздражает.

    2)В выгрузке зачем использовать ЗаписьXml 2 раза ?

    3)Получить ссылку по УИ можно гораздо короче

    и т.д.

    Reply ↓
  18. HAMMER_59

    (17)

    1. Взял куски кода из реальной синхронизации, в ней переменная содержит объект полученный из плана обмена. В конкретном случае ни на что не влияет, т.к. дальше идет обращение к другим реквизитам объекта.

    2. Действительно можно было воспользоваться другим объектом для записи текста в файл. Сильно бы изменился результат? Или вы предлагаете использовать поток? Тогда пришлось бы усложнять код. А может вы просто не заметили передачу данных с сервера на клиент, а затем с клиента в файл?

    3. Очень интересно как можно проще. Сейчас в коде 2 строчки. Первая — десериализация УИД из XML. Вторая получение ссылки через менеджер.

    Перед собой я ставил цель — показать на простом примере, как начать работать с XDTO.

    Пример простой?

    По работе с XDTO есть какие-то претензии?

    Слышали такую фразу: «Лучшее, враг хорошего»?

    Reply ↓
  19. rudnitskij

    По-моему, передавать данные с помощью универсального обмена в формате XML неизмеримо проще, XDTO для такой задачи кажется слишком громоздким

    Reply ↓
  20. bulpi

    (18)

    1.Когда я вижу конструкцию вида «Ссылка.Ссылка», я думаю, что автор — неквалифицированный новичок, и перестаю дальше читать (как правило). В данном случае это не так. Получается когнитивный диссонанс 🙂

    2.Возражение снимаю. Действительно, гонять файл туда-сюда не проще.

    3.сРеализацияТоваров =XmlЗначение(Тип(«ДокументСсылка.РеализацияТоваровУслуг»),РеализацияXDTO.Ссылка);

    4)Пример простой, да

    5)По работе с XDTO претензий нет.

    6)В данном случае лучшее — не враг хорошего. Вы пишете методическую статью, почти главу учебника. Сейчас сотня новичков скопирует себе это как образец для подражания. А потом я, грязно матерясь 🙂 , буду за ними исправлять конструкции типа Ссылка.Ссылка

    Reply ↓
  21. HAMMER_59

    (20)

    сРеализацияТоваров =XmlЗначение(Тип(«ДокументСсылка.РеализацияТоваровУслуг»),РеализацияXDTO.Ссылка);

    Не знал что так можно, спасибо, за интересный вариант.

    Reply ↓
  22. starik-2005

    Сколько страсти! А есть еще такой объект, как сериализатор XDTO — там схема не нужна, т.к. используется схема метаданных.

    А по поводу XDTO, то это, фактически, xsd-схема, описанная в «терминах» объекта «ПакетXDTO» от 1С, который сам по себе поддерживает только малую часть «стандарта» — https://www.w3.org/TR/xmlschema11-1/

    С помощью такой схемы вполне реально сделать обмен через веб-сервисы (SOAP), но нет особого смысла делать это для HTTP-сервисов (REST), т.к. тот же JSON занимает меньше места.

    Reply ↓
  23. Region102

    (22) XDTO применяется при обмене между разнородными системами, если объекты в базах идентичны, то серилизатор значительно удобнее. А для JSON тоже надо писать функции серилизации и десериализации, так что при обмене именно 1С — 1С мне кажется лучше XDTO, тем более пакет отлично ложится в сообщения плана обмена. Да и скорость обработки тоже надо измерять, но мне кажется, что XDTO быстрее формирует xml чем обычные механизмы.

    Reply ↓
  24. starik-2005

    (23)

    для JSON тоже надо писать функции серилизации и десериализации

    В действительности не надо — достаточно структуры с именованными полями, в которых также может находиться структура. И все это через ЗаписьJSON (как, собственно, и через СериализаорХДТО) вполне себе работает, т.е. не нужно мутить бесполезную схему, достаточно просто написать что-то типа «Новый Структура(«Поле1, Поле2, …»);» или вообще взять ключи структуры из метаданных. Я твк делал обмен из четырех баз в одну — заняло день, а это даже на конвертации больше времени занимает, при том отлаживать проще — вот у тебя сериализованная структура в хоть XML, хоть в JSON, хоть вообще через «значениеВСтрокуВнутр()» — пофиг.

    Reply ↓
  25. HAMMER_59

    (24) Написать подобный обмен недолго и не сложно, проблема поддерживать такой обмен. Нужно со временем внести изменения в структуру, и это становится серьезной проблемой. При обмене между 8-кой и 7-кой при помощи XML, в итоге пришел к тому, что начал все документировать, иначе просто невозможно потом вспомнить что же там за структура. Естественно, объектов у меня там было не 2 и не 3 а на порядок больше.

    Reply ↓
  26. Trotter_NN

    Как у Вас записались данные в файл на этом моменте ?

    РеализацияXDTO.Контрагент = КонтрагентXDTO;

    КонтрагентXDTO — у меня равен ОбъектXDTO и в xml ничего не добавляется.

    Reply ↓
  27. HAMMER_59

    (26) А какой тип вы ждете при работе с XDTO?

    Не считая примитивных типов там всего два типа ОбъектXDTO и СписокXDTO, которые в последствии сериализуются в XML.

    У ОбъектXDTO есть метод Тип(), посмотрите какого типа у Вас ОбъектXDTO, дальше уже нужно смотреть что там в пакете XDTO.

    Reply ↓
  28. Yashazz

    (10) Такие статьи были, и были на ИС; ищи лучше. И среди них была пара действительно изящных решений.

    Reply ↓
  29. Yashazz

    (21) а вы, батенька, слушайте, а не начинайте сразу возбухать. Вы ещё мнооого чего не знаете, уж поверьте)

    ладно у bulpi было время вас просветить, так оно не у всех есть)

    Reply ↓
  30. Yashazz

    (23)

    XDTO быстрее формирует xml

    Не совсем так. До определённого предела да, более выигрышно и быстро, но если вложенные структуры типов достаточно сложны, или не в рамках одного пакета, или там зависимости кривые/сложные, или записей более определённого количества, то хдто начинают проигрывать, причём достаточно сильно. Опять же зависит, какой фабрикой пользоваться — синглтоном или конкретно созданной. У меня бывали случаи, когда хдто в разы проигрывал другим инструментам, да и сериализаторы падали от «несъедобного» объёма.

    Это тема отдельной большой статьи, ващета.

    Reply ↓
  31. HAMMER_59

    (33) А остальные статьи на инфостарте Вам нравятся? Статей подобной этой на тему: «Как сделать?» не так много, а вот развлекательные статьи ежедневно да не по одной размещают, и у этих авторов рэйтинги куда выше.

    Критиковать каждый дурак может. Я вроде, так и написал, что не знаю где нормальную документацию можно найти, Видимо Вы знаете, ну так напишите, что лучше бы я почитал и далее по списку, и я бы обязательно почитал, хорошие курсы также приветствуются.

    Reply ↓
  32. Yashazz

    (34) Да вообще-то я сразу и написал, только вот модераторам не нравится якобы, что картиночка не отображается) не хотят пропускать публикацию)))

    Reply ↓
  33. alekshihanov

    (4)

    Не согласен — критикуй, критикуешь — предлагай, предлагаешь — делай, делаешь — отвечай!

    Получится: Не согласен — отвечай.

    Reply ↓
  34. Franchiser

    На скрине у свойства Дату указано что это атрибут, а далее приведен текст выгрузки где Дата это элемент.

    Reply ↓
  35. HAMMER_59

    (37) Можно поконкретнее по какой части кода вы определили что Дата это элемент, а не атрибут.

    Reply ↓
  36. Franchiser

    (38) по приведенному вами тексту в xml

    Результат

    <?xml version=»1.0″ encoding=»UTF-8″?>

    <ДокументРеализация xmlns:xsi=»http://www.w3.org/2001/XMLSchema-instance» xmlns:xs=»http://www.w3.org/2001/XMLSchema» xmlns=»infostart»>

    <Ссылка xsi:type=»xs:string»>63d07913-1e98-11e6-a31d-14dae9b19a48</Ссылка>

    <Дата xsi:type=»xs:dateTime»>2016-12-29T12:00:00</Дата>

    <Номер xsi:type=»xs:string»>0000-000603</Номер>

    <Контрагент xsi:type=»xs:string»>Внуковский комбинат бортового питания</Контрагент>

    </ДокументРеализация>

    Reply ↓
  37. Franchiser

    (38) спасибо за статью, очень понравилась.

    Понял, вы текст выгрузки привели далее что дата это атрибут, а не элемент.

    Статья помогла разобраться в моей проблеме : начиная с 8.3.8 нужно указывать «квалифицированная форма элемента » = истина иначе совсем не так выглядит выгрузка.

    Reply ↓

Leave a Comment

Ваш адрес email не будет опубликован. Обязательные поля помечены *