Этюды по программированию: Штрихкодирование серий номенклатуры

Штрихкодирование серий номенклатуры.

Есть проект на 1c:ERP.  В рамках проекта надо организовать  учет материалов по сериям с помощью штрихкодов.  Нужно подключить сканеры штрихкодов,  разработать систему штрихкодирования с учетом серий, разработать  печать этикеток для  штрихкодов на листах А4 и принтерах этикеток, создать рабочее место для  учета израсходованных материалов.  Пишу, в том  числе и для себя, пригодится на других проектах.

Подключение сканера

В начале, программируем сканер на эмуляцию клавиатуры, 8 бит  данных, 1 стоп-бит, скорость 9600, префикс – нет, Суффикс  -13 <CR>.  Сканер программируется с помощью специальных штрихкодов, которые есть в  руководстве по эксплуатации. Руководство всегда можно скачать с сайта производителя.

Подключаем сканер  в  Администрирование->РМК и оборудование.

С такими настройками сканер будет прекрасно работать через терминальное соединение, что позволит работать с ним даже с планшетов.

Система штрихкодирования с  учетом по сериям номенклатуры

К сожалению, в стандартной поставке ERP нет возможности учитывать в штрихкоде серию номенклатуры. Нам нужно доработать  стандартный код с минимальными изменениями, чтоб система по прежнему была обновляемой.

В качестве формата штрихкода взят CODE39, который позволяет хранить штрихкод неограниченный длины с цифрами и буквами. Качество считывания штрихкода обратно пропорцинально его длине,  поэтому прибегаем к ухищрениям: убираем не значащие нули в нумераторах номенлатуры и серии, и для  чисел с дробями смещаем штриход  на три знака.

Этот фрагмент из обработки печати этикеток поможет понять формирование штрихкода:

 КодНом=ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(НоваяСтрока.Номенклатура.код, Ложь, Ложь);

КодСер=ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(НоваяСтрока.Серия.Номер, Ложь, Ложь);

Если Цел(СтрокаТЧ.Количество)= СтрокаТЧ.Количество Тогда

Кол=ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(Формат(СтрокаТЧ.Количество,"ЧГ=0"), Ложь, Ложь);

СимволРазд="Q";

Иначе

Кол=ПрефиксацияОбъектовКлиентСервер.ПолучитьНомерНаПечать(Формат(СтрокаТЧ.Количество*1000,"ЧГ=0"), Ложь, Ложь);

СимволРазд="W";

КонецЕсли;

НоваяСтрока.Штрихкод             = "N"+КодНом+"S"+КодСер+СимволРазд+Кол;

Обработка печати этикеток.  

Для своего проекта Вы можете взять любую из обработок печати этикеток и модифицировать ее под свои нужды.  Недостатки  этого решения очевидны: Фиксированный  формат этикеток приведет к тому, что Вас будут дергать каждый раз, как руководство надумает поменять формат этикеток, а на этапе внедрения это будет не однажды.  Я прошел другим путем: Вырезал редактор этикеток из стандартного решения, добавил возможность печати на А4 и других форматах, добавил в выбираемые поля (которые будут печататься на этикетках)  любые данные из поставщика, серии, документа поступления. После переработки в расширение, я выложу результат отдельной статьей. Переработка достаточно сложная, очень много кода, активное использование схем СКД.

Доработка  стандартного штрикодирования

Если позволяет режим совместимости, переопределим в расширении функцию общего модуля “ШтрикодированиеНоменклатурыСервер”, так чтоб  наша функция вызывалась  вместо  стандартной функции: ОбработатьШтрихкоды(Форма, Объект, СтруктураПараметров, КэшированныеЗначения)  .  Далее в расширение или отдельный модуль переносится весь код функции и подчиненные функций. 

Переносим в  модуль процедуру РегистрыСведений.ШтрихкодыНоменклатуры.ПолучитьДанныеПоШтрихкодам(КэшированныеЗначения, НеЗакешированныеРанееШтрихкоды) и меняем вызов на локальный

В конце процедуры добавляем код: 

Для Каждого ШтрикходИзМассива из  МассивШтрихкодов Цикл
СтрДанныхШтрихкодаПоСериям=ПреобразоватьШтрихкодССериейКоличество(Штрихкод);
Если СтрДанныхШтрихкодаПоСериям<>Неопределено тогда

ИнформацияПоШтрихкодам = ОбработкаТабличнойЧастиКлиентСервер.СтуктураКешируемойИнформацииПоШтрихкоду();
ИнформацияПоШтрихкодам.Штрихкод = Штрихкод;


ИнформацияПоШтрихкодам.Вставить("Номенклатура",  СтрДанныхШтрихкодаПоСериям.Номенклатура);
ИнформацияПоШтрихкодам.Вставить("ТипНоменклатуры",  СтрДанныхШтрихкодаПоСериям.Номенклатура.ТипНоменклатуры);
ИнформацияПоШтрихкодам.Вставить("Характеристика",  Справочники.ХарактеристикиНоменклатуры.ПустаяСсылка());
ИнформацияПоШтрихкодам.Вставить("Упаковка",  Неопределено);
ИнформацияПоШтрихкодам.Вставить("КоличествоУпаковок",  1);
ИнформацияПоШтрихкодам.Вставить("ПодакцизныйТовар",  Ложь);
ИнформацияПоШтрихкодам.Вставить("МаркируемаяАлкогольнаяПродукция",  Ложь);
ИнформацияПоШтрихкодам.Вставить("ХарактеристикиИспользуются",  Ложь);
ИнформацияПоШтрихкодам.Вставить("Коэффициент",  1);
ИнформацияПоШтрихкодам.Вставить("ЕдиницаИзмерения",  СтрДанныхШтрихкодаПоСериям.Номенклатура.ЕдиницаИзмерения);
ИнформацияПоШтрихкодам.Вставить("ЕдиничнаяУпаковка",  Неопределено);
ИнформацияПоШтрихкодам.Вставить("НесколькоЕдиничныхУпаковок",  Ложь);
ИнформацияПоШтрихкодам.Вставить("НеизвестныйШтрихкод",  Ложь);
ИнформацияПоШтрихкодам.Вставить("ВариантРасчетаЦеныНабора",  Неопределено);
ИнформацияПоШтрихкодам.Вставить("Серия", СтрДанныхШтрихкодаПоСериям.Серия);
ИнформацияПоШтрихкодам.Вставить("КоличествоПоШтрихкоду", СтрДанныхШтрихкодаПоСериям.Количество);

КэшированныеЗначения.Штрихкоды.Вставить(Штрихкод, ИнформацияПоШтрихкодам);
КонецЕсли;
КонецЦикла;

Текст функции:”ПреобразоватьШтрихкодССериейКоличество”

Функция ПреобразоватьШтрихкодАвантКоличество(Штрихкод) Экспорт
СтруктураДанныхШтрихкода= Новый Структура("Номенклатура,Серия,Количество");

Если Лев(Штрихкод, 1) = "N"  Тогда// Внутренний штрихкод
ПозS=СтрНайти(Штрихкод,"S");
ПозQ=СтрНайти(Штрихкод,"Q");
ПозW=СтрНайти(Штрихкод,"W");
Если ПозS>0 И (ПозQ>0 ИЛИ ПозW>0) Тогда // Найден префикс весового товара

КодНом= Сред(Штрихкод, 2, ПозS-2);
СтруктураДанныхШтрихкода.Номенклатура=Справочники.Номенклатура.НайтиПоРеквизиту("КодДляПоиска",КодНом);
Если СтруктураДанныхШтрихкода.Номенклатура=Неопределено Тогда
Возврат Неопределено;
КонецЕсли;
ПозицияКоличества=Макс(ПозQ,ПозW);
НомерСерии=  Сред(Штрихкод, ПозS+1, ПозицияКоличества-ПозS-1);
НомерСерии0=ДобавитьНули(НомерСерии, 8);
Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ ПЕРВЫЕ 1
| СерииНоменклатуры.Ссылка
|ИЗ
| Справочник.СерииНоменклатуры КАК СерииНоменклатуры
|ГДЕ
| СерииНоменклатуры.ВидНоменклатуры = &ВидНоменклатуры
| И СерииНоменклатуры.Номер = &Номер";

Запрос.УстановитьПараметр("ВидНоменклатуры", СтруктураДанныхШтрихкода.Номенклатура.ВидНоменклатуры);
Запрос.УстановитьПараметр("Номер", НомерСерии0);

РезультатЗапроса = Запрос.Выполнить();

ВыборкаДетальныеЗаписи = РезультатЗапроса.Выбрать();

Пока ВыборкаДетальныеЗаписи.Следующий() Цикл
СтруктураДанныхШтрихкода.Серия=ВыборкаДетальныеЗаписи.Ссылка;
КонецЦикла;
Если СтруктураДанныхШтрихкода.Серия=Неопределено Тогда
Возврат Неопределено;
КонецЕсли;
КоличествоТекст=Сред(Штрихкод,ПозицияКоличества+1);
СтруктураДанныхШтрихкода.Количество=Число(КоличествоТекст)/?(ПозW>ПозQ,1000,1);
Возврат СтруктураДанныхШтрихкода;

КонецЕсли;
КонецЕсли;
Возврат Неопределено;
КонецФункции

Функция ДобавитьНули(Значение, НужнаяДлинаЗначения)

Значение = СтрЗаменить(Формат(Значение, "ЧГ="), " ", "");
НадоНулей = НужнаяДлинаЗначения - СтрДлина(Значение);
ВедущиеНули = Формат(0,"ЧЦ="+НадоНулей+";ЧН=; ЧВН=; ЧГ=0");
Возврат ВедущиеНули + Значение;

КонецФункции

Создание собственного рабочего места с подбором штрихкодов

Итак, теперь в любом стандартном документе, где предусмотрена работа со сканером возможен подбор а в табличную часть номенклатуры, серии  и количества одним кликом сканера. Для многих целей этого уже достаточно.

Но у нас предусмотрено еще одна часть марлезонского  балета: Создание собственного документа для списания материалов в производство или собственного рабочего места.

Необходимость  в таком документе или рабочем месте  возникает  по многим причинам. Самая основная, что работа напрямую с  этапом производства требует гораздо большей квалификации, чем предполагает работа простого рабочего. Например, необходимо отвязывать,  излишки от обеспечения по заказу на производство (разбивать на две строки при перепроизводстве по заданию).

Также рабочий  должен указывать начало и  конец операции, причины простоя и т.д.

Создаем свой документ, назовем его “Отчет о выработке”.  Создадим с нуля или скопируем в него табличную часть из документа ЭтапПроизводства  “Расход материалов и работ”. Незабудьте скопировать скрытые реквизиты “Характеристики используются”,”Артикул”, “Тип номенклатуры”, которые есть только на форме. Они нужны для правильного отображения серий и номенклатуры.

Также нужно скопировать следующие реквизиты которые нужны для работы сканера  и условного оформления:

Теперь озаботимся правильным отображением  серий и характеристик. За это отвечает условное оформление формы.

Оформление формы устанавливается первично при создании формы:

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
// СтандартныеПодсистемы.Печать
УправлениеПечатью.ПриСозданииНаСервере(ЭтаФорма, Элементы.ПодменюПечать);
// Конец СтандартныеПодсистемы.Печать
УстановитьУсловноеОформление();
Если Не ЗначениеЗаполнено(Объект.Ссылка) Тогда

ПриЧтенииСозданииНаСервере();

НоменклатураСервер.ЗаполнитьСтатусыУказанияСерий(Объект,ПараметрыУказанияСерий);

КонецЕсли;
ОбщегоНазначенияУТ.НастроитьПодключаемоеОборудование(ЭтаФорма, "РасходМатериаловИРабот_");


КонецПроцедуры

&НаСервере
Процедура ПриЧтенииСозданииНаСервере()

ПараметрыУказанияСерий = Новый ФиксированнаяСтруктура(НоменклатураСервер.ПараметрыУказанияСерий(Объект, Документы.мо_ОтчетОВыработке));
УстановитьВидимостьЭлементовСерий();

КонецПроцедуры
&НаСервере
Процедура УстановитьВидимостьЭлементовСерий()
Элементы.РасходМатериаловИРаботСерия.Видимость = ПараметрыУказанияСерий.ИспользоватьСерииНоменклатуры;

КонецПроцедуры

&НаСервере
Процедура УстановитьУсловноеОформлениеРасходМатериаловИРабот()

НоменклатураСервер.УстановитьУсловноеОформлениеСерийНоменклатуры(
ЭтаФорма,
"СерииВсегдаВТЧТовары",
"РасходМатериаловИРаботСерия",
"Объект.РасходМатериаловИРабот.СтатусУказанияСерий",
"Объект.РасходМатериаловИРабот.ТипНоменклатуры");

//Статья калькуляции
СписокСтатусов = Новый СписокЗначений;
СписокСтатусов.Добавить(Перечисления.СтатусыЭтаповПроизводства2_2.Начат);
СписокСтатусов.Добавить(Перечисления.СтатусыЭтаповПроизводства2_2.Завершен);

ЭлементУсловногоОформления = УсловноеОформление.Элементы.Добавить();

ПолеЭлемента = ЭлементУсловногоОформления.Поля.Элементы.Добавить();
ПолеЭлемента.Поле = Новый ПолеКомпоновкиДанных(Элементы.РасходМатериаловИРаботСтатьяКалькуляции.Имя);

ОтборЭлемента = ЭлементУсловногоОформления.Отбор.Элементы.Добавить(Тип("ЭлементОтбораКомпоновкиДанных"));
ОтборЭлемента.ЛевоеЗначение = Новый ПолеКомпоновкиДанных("Объект.Статус");
ОтборЭлемента.ВидСравнения = ВидСравненияКомпоновкиДанных.НеВСписке;
ОтборЭлемента.ПравоеЗначение = СписокСтатусов;

ЭлементУсловногоОформления.Оформление.УстановитьЗначениеПараметра("ОтметкаНезаполненного", Ложь);

НоменклатураСервер.УстановитьУсловноеОформлениеХарактеристикНоменклатуры(ЭтаФорма,
"РасходМатериаловИРаботХарактеристика",
"Объект.РасходМатериаловИРабот.ХарактеристикиИспользуются");

НоменклатураСервер.УстановитьУсловноеОформлениеЕдиницИзмерения(ЭтаФорма,
"РасходМатериаловИРаботНоменклатураЕдиницаИзмерения",
"Объект.РасходМатериаловИРабот.Упаковка");

КонецПроцедуры
&НаСервере
Процедура УстановитьУсловноеОформление()

УсловноеОформление.Элементы.Очистить();

УстановитьУсловноеОформлениеРасходМатериаловИРабот();

КонецПроцедуры

 Но это не все! В менеджере нам необходим следующий код:

// Возвращает параметры указания серий для товаров, указанных в документе
//
// Параметры:
//  Объект  - Структура - структура значений реквизитов объекта, необходимых для заполнения параметров указания серий
//
// Возвращаемое значение:
//  Структура - Состав полей задается в функции НоменклатураКлиентСервер.ПараметрыУказанияСерий.
//
Функция ПараметрыУказанияСерий(Объект) Экспорт
ПараметрыСерийПодразделение = СкладыСервер.ИспользованиеСерийВПодразделении(Объект.Склад);

ПараметрыУказанияСерийТЧ = Новый Структура;
#Область РасходМатериаловИРабот
ПараметрыУказанияСерийТЧ = НоменклатураКлиентСервер.ПараметрыУказанияСерий();
ПараметрыУказанияСерийТЧ.ПолноеИмяОбъекта = "Документ.мо_ОтчетОВыработке";

ПараметрыУказанияСерийТЧ.ИмяПоляСклад = "Склад";
ПараметрыУказанияСерийТЧ.ИмяТЧТовары = "РасходМатериаловИРабот";
ПараметрыУказанияСерийТЧ.ИмяТЧСерии  = "РасходМатериаловИРабот";

ПараметрыУказанияСерийТЧ.УчитыватьСебестоимостьПоСериям = Истина;

ПараметрыУказанияСерийТЧ.ИспользоватьСерииНоменклатуры = Истина;

ПараметрыУказанияСерийТЧ.СкладскиеОперации.Добавить(Перечисления.СкладскиеОперации.ПотреблениеМатериаловПриПроизводстве);

ПараметрыУказанияСерийТЧ.ПараметрыЗапроса.Вставить("Склад", Объект.Склад);

ПараметрыУказанияСерийТЧ.ЭтоНакладная = Истина;
ПараметрыУказанияСерийТЧ.РегистрироватьСерии = Истина; // всегда используется форма регистрации серий (в ней можно также выбрать из остатков)

ПараметрыУказанияСерийТЧ.ПланированиеОтгрузки = Истина;
ПараметрыУказанияСерийТЧ.ПланированиеОтбора   = Истина;
ПараметрыУказанияСерийТЧ.ФактОтбора           = Истина;

ПараметрыУказанияСерийТЧ.Дата = Объект.Дата;

#КонецОбласти

Возврат ПараметрыУказанияСерийТЧ;


КонецФункции

//Имена реквизитов, от значений которых зависят параметры указания серий
//
// Возвращаемое значение:
//  Строка - имена реквизитов, перечисленные через запятую
//
Функция ИменаРеквизитовДляЗаполненияПараметровУказанияСерий() Экспорт
ИменаРеквизитов = "Склад,Дата";

Возврат ИменаРеквизитов;
КонецФункции

Функция ТекстЗапросаЗаполненияСтатусовУказанияСерий(ПараметрыУказанияСерий)  Экспорт

ТекстЗапроса =
"ВЫБРАТЬ
| Товары.Номенклатура,
| Товары.Серия,
| Товары.СтатусУказанияСерий,
| Товары.НомерСтроки
|ПОМЕСТИТЬ Товары
|ИЗ
| &Товары КАК Товары
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| Товары.НомерСтроки КАК НомерСтроки,
| Товары.СтатусУказанияСерий КАК СтарыйСтатусУказанияСерий,
| ВЫБОР
|  КОГДА ПолитикиУчетаСерий.ПолитикаУчетаСерий ЕСТЬ NULL
|   ТОГДА 0
|  КОГДА ПолитикиУчетаСерий.ПолитикаУчетаСерий.УчитыватьСебестоимостьПоСериям
|   ТОГДА ВЫБОР
|     КОГДА Товары.Серия <> ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
|      ТОГДА 14
|     ИНАЧЕ  15
|    КОНЕЦ
|  КОГДА ПолитикиУчетаСерий.ПолитикаУчетаСерий.УказыватьПриПланированииОтгрузки
|   ТОГДА ВЫБОР
|     КОГДА Товары.Серия <> ЗНАЧЕНИЕ(Справочник.СерииНоменклатуры.ПустаяСсылка)
|      ТОГДА 10
|     ИНАЧЕ 11
|    КОНЕЦ
|  ИНАЧЕ 0
| КОНЕЦ КАК СтатусУказанияСерий
|ПОМЕСТИТЬ Статусы
|ИЗ
| Товары КАК Товары
|  ЛЕВОЕ СОЕДИНЕНИЕ Справочник.ВидыНоменклатуры.ПолитикиУчетаСерий КАК ПолитикиУчетаСерий
|  ПО (ПолитикиУчетаСерий.Склад = &Склад)
|   И (ВЫРАЗИТЬ(Товары.Номенклатура КАК Справочник.Номенклатура).ВидНоменклатуры = ПолитикиУчетаСерий.Ссылка)
|;
|
|////////////////////////////////////////////////////////////////////////////////
|ВЫБРАТЬ
| Статусы.НомерСтроки,
| Статусы.СтатусУказанияСерий
|ИЗ
| Статусы КАК Статусы
|ГДЕ
| Статусы.СтатусУказанияСерий <> Статусы.СтарыйСтатусУказанияСерий
|
|УПОРЯДОЧИТЬ ПО
| Статусы.НомерСтроки";
Возврат ТекстЗапроса;

КонецФункции

Ура, теперь серии и характеристики номенклатуры отображаются корректно.

Теперь подключим обработку сканера.

При создании на сервере мы уже вызывали     ОбщегоНазначенияУТ.НастроитьПодключаемоеОборудование(ЭтаФорма, "РасходМатериаловИРабот_");

Вставим в модуль формы код:

&НаКлиенте
Перем КэшированныеЗначения;
&НаКлиенте
Перем ТекущиеДанныеИдентификатор;

#Область ШтрихкодыИТорговоеОборудование

&НаКлиенте
Процедура ПоискПоШтрихкоду(ИмяТЧ)

ОчиститьСообщения();
Оповещение = Новый ОписаниеОповещения("ПоискПоШтрихкодуЗавершение", ЭтотОбъект, ИмяТЧ);
ШтрихкодированиеНоменклатурыКлиент.ПоказатьВводШтрихкода(Оповещение);

КонецПроцедуры

&НаКлиенте
Процедура ПоискПоШтрихкодуЗавершение(ДанныхШтрихкода, ИмяТЧ) Экспорт

ОбработатьШтрихкоды(ДанныхШтрихкода, ИмяТЧ);

КонецПроцедуры

&НаКлиенте
Процедура ОбработатьШтрихкоды(ДанныеШтрихкодов, ИмяТЧ)

СтруктураДействийСДобавленнымиСтроками = Новый Структура;
СтруктураДействийСДобавленнымиСтроками.Вставить("ЗаполнитьПризнакАртикул", Новый Структура("Номенклатура", "Артикул"));
СтруктураДействийСДобавленнымиСтроками.Вставить("ЗаполнитьПризнакТипНоменклатуры", Новый Структура("Номенклатура", "ТипНоменклатуры"));

ДобавитьВСтруктуруДействияПриИзмененииНоменклатуры(
Неопределено,
ИмяТЧ,
ЭтаФорма,
СтруктураДействийСДобавленнымиСтроками);

УправлениеПроизводствомКлиентСервер.ДобавитьВСтруктуруДействияПриИзмененииКоличестваУпаковок(
Неопределено,
ИмяТЧ,
СтруктураДействийСДобавленнымиСтроками);

СтруктураДействийСДобавленнымиСтроками.Вставить("ЗаполнитьПризнакАртикул", Новый Структура("Номенклатура", "Артикул"));

СтруктураДействийСИзмененнымиСтроками = Новый Структура;
УправлениеПроизводствомКлиентСервер.ДобавитьВСтруктуруДействияПриИзмененииКоличестваУпаковок(
Неопределено,
ИмяТЧ,
СтруктураДействийСИзмененнымиСтроками);

СтруктураДействий = ШтрихкодированиеНоменклатурыКлиент.ПараметрыОбработкиШтрихкодов();

СтруктураДействий.Штрихкоды                              = ДанныеШтрихкодов;
СтруктураДействий.СтруктураДействийСДобавленнымиСтроками = СтруктураДействийСДобавленнымиСтроками;
СтруктураДействий.СтруктураДействийСИзмененнымиСтроками  = СтруктураДействийСИзмененнымиСтроками;
СтруктураДействий.ПараметрыУказанияСерий                 = ПараметрыУказанияСерий;
СтруктураДействий.ИзменятьКоличество                     = Истина;
СтруктураДействий.ТолькоТовары                           = Истина;
СтруктураДействий.ИмяТЧ                                  = ИмяТЧ;

ОбработатьШтрихкодыСервер(СтруктураДействий, КэшированныеЗначения);
ШтрихкодированиеНоменклатурыКлиент.ОбработатьНеизвестныеШтрихкоды(СтруктураДействий,КэшированныеЗначения,ЭтаФорма);

Если ШтрихкодированиеНоменклатурыКлиент.НужноОткрытьФормуУказанияСерийПослеОбработкиШтрихкодов(СтруктураДействий) Тогда

ТекущиеДанныеИдентификатор = СтруктураДействий.МассивСтрокССериями[0];

ПодключитьОбработчикОжидания("Подключаемый_ОткрытьПодборСерийПриСканированииШтрихкодаНоменклатуры_" + ИмяТЧ, 0.1, Истина);

КонецЕсли;

Если СтруктураДействий.ТекущаяСтрока <> Неопределено Тогда
Элементы[ИмяТЧ].ТекущаяСтрока = СтруктураДействий.ТекущаяСтрока;
КонецЕсли;

КонецПроцедуры

&НаСервере
Процедура ОбработатьШтрихкодыСервер(СтруктураПараметровДействия, КэшированныеЗначения)
ШтрихкодированиеНоменклатурыСервер.ОбработатьШтрихкоды(ЭтаФорма, Объект, СтруктураПараметровДействия, КэшированныеЗначения);
КонецПроцедуры

&НаКлиенте
Процедура ЗагрузитьДанныеИзТСД(ИмяТЧ)

ОчиститьСообщения();

МенеджерОборудованияКлиент.НачатьЗагрузкуДанныеИзТСД(
Новый ОписаниеОповещения("ЗагрузитьИзТСДЗавершение", ЭтотОбъект, ИмяТЧ),
УникальныйИдентификатор);

КонецПроцедуры

&НаКлиенте
Процедура ЗагрузитьИзТСДЗавершение(Результат, ИмяТЧ) Экспорт

Если Результат.Результат Тогда
ОбработатьШтрихкоды(Результат.ТаблицаТоваров, ИмяТЧ);
Иначе
МенеджерОборудованияКлиентПереопределяемый.СообщитьОбОшибке(Результат);
КонецЕсли;

КонецПроцедуры



#КонецОбласти

&НаКлиенте
Процедура ПриОткрытии(Отказ)
МенеджерОборудованияКлиентПереопределяемый.НачатьПодключениеОборудованиеПриОткрытииФормы(ЭтаФорма, "СканерШтрихкода");
//..
КонецПроцедуры

&НаКлиенте
Процедура РасходМатериаловИРаботСерияПриИзменении(Элемент)

ТекущиеДанные = Элементы.РасходМатериаловИРабот.ТекущиеДанные;

ВыбранноеЗначение = НоменклатураКлиентСервер.ВыбраннаяСерия();

ВыбранноеЗначение.Значение               = ТекущиеДанные.Серия;
ВыбранноеЗначение.ИдентификаторТекущейСтроки = ТекущиеДанные.ПолучитьИдентификатор();

НоменклатураКлиент.ОбработатьУказаниеСерии(ЭтаФорма, ПараметрыУказанияСерий, ВыбранноеЗначение);

КонецПроцедуры

&НаКлиенте
Процедура РасходМатериаловИРаботСерияНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
СтандартнаяОбработка = Ложь;
ОткрытьПодборСерий("РасходМатериаловИРабот", Элемент.ТекстРедактирования);

КонецПроцедуры


&НаКлиенте
Процедура ОткрытьПодборСерий(ИмяТЧ, Текст = "", ТекущиеДанные = Неопределено)

НуженСерверныйВызов = НоменклатураКлиент.ДляУказанияСерийНуженСерверныйВызов(
ЭтаФорма,
ПараметрыУказанияСерий,
Текст,
ТекущиеДанные);

Если НуженСерверныйВызов Тогда

Если ТекущиеДанные = Неопределено Тогда
ТекущиеДанныеИдентификатор = Элементы[ИмяТЧ].ТекущиеДанные.ПолучитьИдентификатор();
Иначе
ТекущиеДанныеИдентификатор = ТекущиеДанные.ПолучитьИдентификатор();
КонецЕсли;

ПараметрыФормыУказанияСерий = ПараметрыФормыУказанияСерий(ТекущиеДанныеИдентификатор, ИмяТЧ);
ДополнительныеПараметры = Новый Структура("ПараметрыУказанияСерий,ПараметрыФормыУказанияСерий",
ПараметрыУказанияСерий, ПараметрыФормыУказанияСерий);
ОписаниеОповещения = Новый ОписаниеОповещения("ОткрытьПодборСерийЗавершение", ЭтотОбъект, ДополнительныеПараметры);

ОткрытьФорму(ПараметрыФормыУказанияСерий.ИмяФормы,
ПараметрыФормыУказанияСерий,
ЭтаФорма,,,,
ОписаниеОповещения);

КонецЕсли;

КонецПроцедуры

&НаКлиенте
Процедура ОткрытьПодборСерийЗавершение(РезультатЗакрытия, ДополнительныеПараметры) Экспорт

Если РезультатЗакрытия <> Неопределено Тогда
ОбработатьУказаниеСерийСервер(
ДополнительныеПараметры.ПараметрыУказанияСерий,
ДополнительныеПараметры.ПараметрыФормыУказанияСерий);
КонецЕсли;

КонецПроцедуры

&НаСервере
Процедура ОбработатьУказаниеСерийСервер(Знач ПараметрыУказанияСерий, Знач ПараметрыФормыУказанияСерий)

Если ПараметрыУказанияСерий.ИмяТЧТовары = "ВыходныеИзделия"
ИЛИ ПараметрыУказанияСерий.ИмяТЧТовары = "ПобочныеИзделия"
ИЛИ ПараметрыУказанияСерий.ИмяТЧТовары = "ЭкономияМатериалов" Тогда
СтруктураДействий = Новый Структура;
СтруктураДействий.Вставить("ОбновлятьКоличествоТоваровПриРегистрацииСерий", Истина);
УправлениеПроизводствомКлиентСервер.ДобавитьВСтруктуруДействияПриИзмененииКоличестваУпаковок(
Неопределено,
ПараметрыУказанияСерий.ИмяТЧТовары,
СтруктураДействий);
Иначе
СтруктураДействий = Неопределено;
КонецЕсли;

НоменклатураСервер.ОбработатьУказаниеСерий(
Объект,
ПараметрыУказанияСерий,
ПараметрыФормыУказанияСерий,
СтруктураДействий);

КонецПроцедуры

&НаСервере
Функция ПараметрыФормыУказанияСерий(ТекущиеДанныеИдентификатор, ИмяТЧ)

Возврат НоменклатураСервер.ПараметрыФормыУказанияСерий(
Объект,
ПараметрыУказанияСерий,
ТекущиеДанныеИдентификатор,
ЭтаФорма);

КонецФункции

&НаКлиенте
Процедура ОбработкаОповещения(ИмяСобытия, Параметр, Источник)
// ПодключаемоеОборудование
Если Источник = "ПодключаемоеОборудование" И ВводДоступен() Тогда
Если ИмяСобытия = "ScanData" И МенеджерОборудованияКлиентПереопределяемый.ЕстьНеобработанноеСобытие() Тогда
ОбработатьШтрихкоды(МенеджерОборудованияКлиент.ПреобразоватьДанныеСоСканераВМассив(Параметр),"РасходМатериаловИРабот");
КонецЕсли;
КонецЕсли;
// Конец ПодключаемоеОборудование

// Неизвестные штрихкоды
Если Источник = "ПодключаемоеОборудование"
И ИмяСобытия = "НеизвестныеШтрихкоды"
И Параметр.ФормаВладелец = УникальныйИдентификатор Тогда

КэшированныеЗначения.Штрихкоды.Очистить();
ДанныеШтрихкодов = Новый Массив;
Для Каждого ПолученныйШтрихкод Из Параметр.ПолученыНовыеШтрихкоды Цикл
ДанныеШтрихкодов.Добавить(ПолученныйШтрихкод);
КонецЦикла;
Для Каждого ПолученныйШтрихкод Из Параметр.ЗарегистрированныеШтрихкоды Цикл
ДанныеШтрихкодов.Добавить(ПолученныйШтрихкод);
КонецЦикла;

ОбработатьШтрихкоды(ДанныеШтрихкодов,"РасходМатериаловИРабот");

КонецЕсли;
СобытияФормКлиент.ОбработкаОповещения(ЭтотОбъект, ИмяСобытия, Параметр, Источник);

КонецПроцедуры
&НаКлиенте
Процедура ДобавитьВСтруктуруДействияПриИзмененииНоменклатуры(ТекущаяСтрока, ИмяТЧ, Форма, СтруктураДействий)

Если НЕ СтруктураДействий.Свойство("ПроверитьСериюРассчитатьСтатус")
И (ИмяТЧ = "РасходМатериаловИРабот") Тогда

ПараметрыПроверкиСерий = Новый Структура("Склад, ПараметрыУказанияСерий");
ПараметрыПроверкиСерий.ПараметрыУказанияСерий = Форма.ПараметрыУказанияСерий;
ПараметрыПроверкиСерий.Склад = Объект.Склад ;
СтруктураДействий.Вставить("ПроверитьСериюРассчитатьСтатус", ПараметрыПроверкиСерий);

КонецЕсли;

УправлениеПроизводствомКлиентСервер.ДобавитьВСтруктуруДействияПриИзмененииНоменклатуры(
ТекущаяСтрока,
ИмяТЧ,
Форма,
СтруктураДействий);

КонецПроцедуры
&НаСервере
Процедура ЗаполнитьСтатусыУказанияСерийПриОкончанииРедактированияСтрокиТЧ(ИмяТЧ, ТекущаяСтрокаИдентификатор, КэшированныеЗначения)

НоменклатураСервер.ЗаполнитьСтатусыУказанияСерийПриОкончанииРедактированияСтрокиТЧ(Объект,
ПараметрыУказанияСерий, ТекущаяСтрокаИдентификатор, КэшированныеЗначения);

КонецПроцедуры


&НаКлиенте
Процедура ПриЗакрытии(ЗавершениеРаботы)
МенеджерОборудованияКлиентПереопределяемый.НачатьОтключениеОборудованиеПриЗакрытииФормы(ЭтаФорма);
КонецПроцедуры


&НаСервере
Процедура ПриЧтенииНаСервере(ТекущийОбъект)
ПриЧтенииСозданииНаСервере();
КонецПроцедуры


&НаКлиенте
Процедура СкладПриИзменении(Элемент)
УстановитьУсловноеОформлениеРасходМатериаловИРабот();
КонецПроцедуры

Не забыть подключить события формы к соответствующему коду.

p> 

Акция! Вы можете  скачать архив всех моих разработок, которые я предлагаю за StartMone, по Специальной  цене:  //infostart.ru/public/960899/#archive

.

Молочников Олег Spb. 2024.