Почему Вы не обслуживаете итоги?

И снова об итогах

Вы сотрудник франчайзи "1С"? Может быть, Вы даже обновляете клиентов и следите за работоспособностью их информационных баз? Или Вы работаете в штате компании и работоспособность систем на базе платформы "1С" лежит на Ваших плечах? Если ответа "ДА" хотя бы на один вопрос, то эта статья для Вас!

Сегодня мы рассмотрим, с одной стороны, очень простой вопрос обслуживания итогов в регистрах. Но с другой стороны — вопрос простой, но настраивать подобающее обслуживание итогов часто никто не торопится.

Не могу точно сказать для кого эта статья — для новичков или опытных программистов. Или администраторов? Думаю, что решать только Вам!

Как они работают

Платформа "1С" использует механизм итогов для оптимизации получения данных в запросах за большой период. Механизм итогов доступен в регистрах накопления, бухгалтерии и сведений. Именно благодаря ему мы можем формировать отчеты достаточно быстро за большой период времени. Не всегда, конечно, но это уже другая история :).

Но, прежде чем говорить об обслуживании итогов, давайте поверхностно рассмотрим их работу для каждого вида регистра. Мы не будем погружаться в особенности их работы на стороне СУБД, аспекты блокировок и другие связанные темы. Только принцип работы, только суть!

Регистры сведений

Начнем с простого — итогов регистров сведений. С некоторого момента, платформа поддерживает итоги среза первых / последних записей. Например, в последних типовых конфигурациях для регистра "Курсы валют" включены итоги среза последних. Под спойлером Вы найдете пример как данные в регистре отражаются на итогах этого регистра.

Все логично — срез последних записей хранит последние по периоду записи в разрезе измерений регистра. При этом в итогах хранятся данные как измерений, так и ресурсов, и реквизитов.

По такому же принципу работают итоги среза первых, только хранят они, внезапно, срез первых записей.

Регистры накопления

Итоги регистров накопления уже интересней, чем у регистров сведений. О внутренних механизмах платформы и принципа работы с итогами Вы можете узнать здесь и вот тут, а также на сайте ИТС. А сейчас рассмотрим лишь основное. Во-первых, регистры накопления бывают двух видов: оборотов и остатков. От вида регистра также зависит принцип построения и использования итогов.

Регистр оборотов

Для примера возьмем регистр накопления "Реализация услуг" из типовой конфигурации "Бухгалтерия предприятия 3.0". Под спойлером пример данных в регистре и полученные итоги.

Таким образом, итоги оборотного регистра накопления содержат сгруппированные данные по измерениям на каждый месяц. Позволяют получать данные за период наиболее оптимальным способом, ведь записей читать придется меньше, иногда значительно меньше.

Регистр остатков

В качестве примера остаточного регистра возьмем "НДС предъявленный". Пример снова под спойлером.

Итоги по остаткам используются очень часто и позволяют эффективно получать информацию о текущем состоянии каких-либо показателей (остатки номенклатуры, состояние взаиморасчетов и другое).

Регистры бухгалтерии

Не менее интересным объектом с поддержкой хранения итогов является регистр бухгалтерии. Это настоящий рекордсмен по количеству таблиц с итогами. Возьмем для рассмотрения типовой регистр "Хозрасчетный" в той же "Бухгалтерии предприятия 3.0". Всего в регистре можно насчитать 5 таблиц с итогами:

• Итоги между счетами — для хранения итогов оборотов между корреспондирующими счетами

• Итоги по счетам — для хранения итогов по счету в целом
• Итоги по счетам с субконто 1 — итоги по счетам с 1 субконто
• Итоги по счетам с субконто 2 — итоги по счетам с 2 субконто
• Итоги по счетам с субконто 3 — итоги по счетам с 3 субконто

Чтобы не углубляться сейчас во внутренние механизмы регистра, отметим лишь, что в таблице итогов между счетами хранятся итоги только по оборотам. В остальных таблицах итогов хранятся итоги и по оборотам, и по остаткам. Также регистр бухгалтерии поддерживает текущие итоги, которые работают практически также, как и в регистре накопления.

Теперь Вы знаете на сколько большим по размеру и тяжелым по использованию может быть регистр бухгалтерии. Ведь при формировании проводок платформе требуется поддерживать большое количество таблиц с итогами. А представьте что бы было, если план счетов поддерживал не три, а пять субконто!

Более подробную информацию об особенностях работы итогов регистра бухгалтерии Вы можете прочитать здесь.

Что же с обслуживанием

И так, мы быстрым шагом прошлись по механизму хранения итогов платформы, рассмотрели какие итоги бывают и у каких объектов. Что же здесь может такое случиться, что потребует обслуживания?

Самым "самообслуживаемым" объектом в части итогов является регистр сведений. Включили итоги по срезу последних и забыли. Ничего настраивать и обслуживать не нужно.

С регистром накопления и бухгалтерии дело обстоит иначе. Для остаточных регистров накопления и любого регистра бухгалтерии обязательно в начале каждого месяца необходимо устанавливать период рассчитанных итогов. Если этого не сделать, то итоги по остаткам просто не будут рассчитаны. Соответственно, и использоваться они не будут.

Во всех типовых конфигурациях имеется регламентное задание "Установка периода рассчитанных итогов" с расписанием на запуск каждое 5 число месяца в 01:00. Вот алгоритм обновления периода рассчитанных итогов.

// Рассчитывает итоги всех регистров бухгалтерии и накопления, у которых они включены.
Процедура РассчитатьИтоги() Экспорт

ДатаСеанса = ТекущаяДатаСеанса();
РегистрНакопленияПериод  = КонецМесяца(ДобавитьМесяц(ДатаСеанса, -1)); // Конец прошлого месяца.
РегистрБухгалтерииПериод = КонецМесяца(ДатаСеанса); // Конец текущего месяца.

Кэш = КэшПроверкиРазделения();

// Расчет итогов для регистров накопления.
ВидОстатки = Метаданные.СвойстваОбъектов.ВидРегистраНакопления.Остатки;
Для Каждого РегистрМетаданные Из Метаданные.РегистрыНакопления Цикл
Если РегистрМетаданные.ВидРегистра <> ВидОстатки Тогда
Продолжить;
КонецЕсли;
Если Не ОбъектМетаданныхДоступенПоРазделению(Кэш, РегистрМетаданные) Тогда
Продолжить;
КонецЕсли;
РегистрНакопленияМенеджер = РегистрыНакопления[РегистрМетаданные.Имя];
Если РегистрНакопленияМенеджер.ПолучитьМаксимальныйПериодРассчитанныхИтогов() >= РегистрНакопленияПериод Тогда
Продолжить;
КонецЕсли;
РегистрНакопленияМенеджер.УстановитьМаксимальныйПериодРассчитанныхИтогов(РегистрНакопленияПериод);
Если Не РегистрНакопленияМенеджер.ПолучитьИспользованиеИтогов()
Или Не РегистрНакопленияМенеджер.ПолучитьИспользованиеТекущихИтогов() Тогда
Продолжить;
КонецЕсли;
РегистрНакопленияМенеджер.ПересчитатьТекущиеИтоги();
КонецЦикла;

// Расчет итогов для регистров бухгалтерии.
Для Каждого РегистрМетаданные Из Метаданные.РегистрыБухгалтерии Цикл
Если Не ОбъектМетаданныхДоступенПоРазделению(Кэш, РегистрМетаданные) Тогда
Продолжить;
КонецЕсли;
РегистрБухгалтерииМенеджер = РегистрыБухгалтерии[РегистрМетаданные.Имя];
Если РегистрБухгалтерииМенеджер.ПолучитьМаксимальныйПериодРассчитанныхИтогов() >= РегистрБухгалтерииПериод Тогда
Продолжить;
КонецЕсли;
РегистрБухгалтерииМенеджер.УстановитьМаксимальныйПериодРассчитанныхИтогов(РегистрБухгалтерииПериод);
Если Не РегистрБухгалтерииМенеджер.ПолучитьИспользованиеИтогов()
Или Не РегистрБухгалтерииМенеджер.ПолучитьИспользованиеТекущихИтогов() Тогда
Продолжить;
КонецЕсли;
РегистрБухгалтерииМенеджер.ПересчитатьТекущиеИтоги();
КонецЦикла;

// Регистрация даты.
Если РежимРаботыЛокальныйФайловый() Тогда
ПараметрыИтогов = ПараметрыИтоговИАгрегатов();
ПараметрыИтогов.ДатаРасчетаИтогов = НачалоМесяца(ДатаСеанса);
ЗаписатьПараметрыИтоговИАгрегатов(ПараметрыИтогов);
КонецЕсли;
КонецПроцедуры

Как проверить, что у Вас установлен актуальный период рассчитанных итогов? Самый простой способ — зайти в обработку "Управление итогами" через "Все функции -> Стандартные -> Управление итогами". Там выбрать полные возможности и в показанной таблице проверить дату в колонке "Период итогов".

Для регистров бухгалтерии это должен быть конец текущего месяца, а для остаточных регистров накопления — конец предыдущего месяца. Если даты обновлены, то все отлично. Если нет — значит либо еще не наступило 5 число месяца, либо регламентное задание по установке периода рассчитанных итогов у Вас не работает.

Но и это еще не все! Есть еще как минимум две операции, которые необходимо планировать для итогов:

• Пересчет итогов — помогает не только исправить "странные" возникающие ошибки в отчетах (хоть это и очень редко), но и исправить возможные проблемы с производительностью. Периодичность работ нужно выбирать по ситуации, но можно для начала запланировать их выполнение раз в квартал.
• Двигать минимальный период хранимых итогов. Здесь речь идет о настройке минимального периода хранимых итогов, который позволяет задать точный период "От" и "До", за который итоги будут рассчитаны.

Зачем их устанавливать? Если в базе хранятся данные за 10 лет, то вряд ли они все используются. Целесообразно проанализировать какие данные действительно используются и за какой период (например, только последние 5 лет) и ограничить период хранения итогов нужным значением. Данный подход похож на метод скользящего окна, который упрощает сопровождение больших объемов данных.

Вот и все основные операции обслуживания.

Заключение

Мы быстро пробежались по принципу работы механизма итогов платформы "1С" и рассмотрели основные направления работ по обслуживанию итогов. Список получился коротким:

• Ежемесячное обновление периода рассчитанных итогов для регистра бухгалтерии и остаточных регистров накопления.
• Пересчет итогов для поддержки корректности данных и предотвращения проблем с производительностью.
• Актуализация периода хранения итогов, чтобы итоги хранились за действительно необходимый период времени.

Мы не коснулись таких вопросов как:

• Обслуживание индексов и статистик базы данных для таблиц итогов
• Влияние этого механизма на производительность
• Особые настройки таблиц итогов
• И другое.

Но цели такой и не ставилось.

Проверьте свои итоги! Улучшите производительность отчетов!

Другие ссылки

• Зачем в 1С нужно периодически пересчитывать итоги по регистрам?

• Оптимизация 1С – Режим разделения итогов

• Устройство регистра накопления

• Особенности хранения итогов регистра бухгалтерии